Lệnh trì hoãn AppleScript không hoạt động kể từ khi chuyển sang Yosemite

Lưu ý: Sự delaycố với đã được khắc phục trong OS X 10.11 El Capitan.

Kể từ khi tôi nâng cấp lên Yosemite, các bản Apples sử dụng độ trễ đã ngừng hoạt động. Làm thế nào tôi có thể sửa lỗi này?

Đây là Applescript đơn giản nhất thế giới, vì một ví dụ dễ hiểu:

set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0

Điều đó sẽ mất 30 giây để hoàn thành. Nếu tôi chạy nó trong Script Editor (trước đây là Applescript Editor) thì mất 30 giây để hoàn thành. Nhưng nếu tôi lưu tập lệnh này dưới dạng một ứng dụng, khi tôi khởi chạy ứng dụng, sự chậm trễ sẽ bị bỏ qua và ứng dụng mất một phần giây để hoàn thành.

Làm cách nào tôi có thể buộc Applescript trì hoãn trong một khoảng thời gian xác định trước khi chuyển sang bước tiếp theo? Đây có phải là một trục trặc Yosemite? Có một cách giải quyết đáng tin cậy?

Lưu ý: Sự delaycố với đã được khắc phục trong OS X 10.11 El Capitan.

@ 2oh1, bạn có ý tưởng cơ bản đúng trong câu trả lời của mình, nhưng đây là câu trả lời đầy đủ và chính xác:

Cách hợp lý duy nhất để giải quyết vấn đề này là gọi "độ trễ" trong vòng lặp để đảm bảo thời lượng mong muốn trôi qua trước khi tiếp tục. Cách tốt nhất để làm điều này là ghi đè "độ trễ" bằng trình xử lý tùy chỉnh:

on delay duration
  set endTime to (current date) + duration
  repeat while (current date) is less than endTime
    tell AppleScript to delay endTime - (current date)
  end repeat
end delay

Điều này cho phép bạn giữ nguyên phần còn lại của tập lệnh và bạn có thể sử dụng "độ trễ" bình thường, ví dụ:

delay 5
display alert "I like cake!"

[LƯU Ý: Thông thường, trình xử lý tùy chỉnh sẽ sử dụng "thời gian trì hoãn tiếp tục" để gọi "độ trễ" tích hợp, nhưng tôi thấy rằng, mặc dù điều này hoạt động trong Script Editor, nó trả về lỗi khi được sử dụng trong một applet (có thể ' t tiếp tục trì hoãn. (-1708). Tôi đã khắc phục vấn đề đó bằng cách trực tiếp yêu cầu AppleScript xử lý lệnh trì hoãn thay vì sử dụng "tiếp tục" để đến đó.]

Vấn đề là delayxử lý đầu vào của người dùng trong khi tạm dừng tập lệnh, do đó bạn vẫn có thể nhấp vào các menu hoặc cửa sổ được hiển thị bởi một applet và có một lỗi (được sửa trong 10.11) trong đó đầu vào của người dùng delaykhông chờ toàn bộ thời gian trước khi tiếp tục thực thi tập lệnh . Nếu bạn không tương tác với applet, hãy delayhoạt động chính xác.

Trong khi chiến đấu với cùng một vấn đề, tôi đã gặp câu trả lời này cho một câu hỏi không liên quan và quyết định thử nó và nó dường như có hiệu quả với tôi.

Đơn giản chỉ cần thay thế delay 5bằng do shell script "/bin/sleep 5"và nhận được kết quả tương tự.

Tôi không nói đây là giải pháp tốt nhất, nhưng dường như nó đã giải quyết được vấn đề của tôi. Thay vì sử dụng một độ trễ đơn giản, bị bỏ qua vì những lý do tôi không hiểu, tôi đã chuyển sang lấy thời gian và lặp cho đến khi đạt được thời gian mới (nó vẫn sử dụng độ trễ, nhưng nó không thành vấn đề nếu nó bỏ qua độ trễ do tập lệnh không tiếp tục cho đến khi đạt được thời gian).

# Pause for five minutes
set GetTheTime to current date
set NewTime to GetTheTime + (5 * minutes)
repeat while (current date) is less than NewTime
    delay 60
end repeat

Tôi vẫn đang muốn biết tại sao sự chậm trễ lại bị phớt lờ (hoặc tăng tốc đột ngột ?! ??), nhưng điều này đã hoàn thành công việc, vụng về như nó vốn có.

Tôi tìm thấy một công việc xung quanh trong một bài viết diễn đàn Đức . Thêm các dòng này vào đầu tập lệnh của bạn:

use framework "Foundation"
use scripting additions
current application's NSThread's sleepForTimeInterval:1

carzyj đã có những gì tôi cho là câu trả lời hay nhất, nhưng khi kết hợp với phương pháp của Chris Page, bạn sẽ nhận được:

on delay duration
  do shell script "/bin/sleep " & duration
end delay

Bạn có thể nhận xét "về độ trễ" thông qua "độ trễ kết thúc" để trở lại độ trễ ban đầu.

đây là một sửa đổi cho giải pháp @ chris-page

Nó dường như là một sự cân bằng giữa khả năng đáp ứng và nắm bắt chính xác độ trễ.

on delay duration
    set endTime to (current date) + duration
    repeat while (current date) is less than endTime
        set delta to duration / 100
        if duration < 0.2 then
            set delta to 0.2
        end if
        tell AppleScript to delay delta
    end repeat
end delay

Nhưng thay vì bảo Applescript trì hoãn trong thời gian tổng thể, chúng tôi chỉ bảo nó trì hoãn trong một khoảng thời gian nhỏ. nếu khoảng thời gian nhỏ hơn mức táo cho phép (1/60 giây), thì hãy đặt nó vào đồng bằng đó. Rằng chúng ta có thể giữ một số phản hồi, nhưng vẫn chính xác. sự nghi ngờ là đôi khi độ trễ không hoạt động nên vòng lặp while sẽ giữ luồng bị khóa, nhưng trong các kịch bản thành công, chúng tôi muốn độ trễ delta bị ngắn để quá trình vẫn có thể bị gián đoạn

Vì vậy, để kết hợp tất cả lại, tôi tin rằng Chris có nghĩa là:

on delay duration
   set endTime to (current date) + duration
   repeat while (current date) is less than endTime
      tell AppleScript to delay endTime - (current date)
   end repeat
end delay