Có thể liên kết Mac OSX Dictionary.app của tôi với Google Dịch không?

Ứng dụng Dictionary có trải nghiệm rất tuyệt trên MacOSX. Nhưng tôi phải cài đặt từ điển để sử dụng. Có thể liên kết nó với Google Dịch không?

Cảm ơn!

Thật không may, nó dường như không thể, hoặc ít nhất là đơn giản. Thay vào đó, bạn có thể muốn xem xét việc tạo Dịch vụ OS X mở Google Dịch trong cửa sổ trình duyệt, cho bất kỳ từ hoặc cụm từ được tô sáng nào bạn đã chọn.

Nếu điều này nghe có vẻ phù hợp, hãy làm theo quy trình dưới đây:

Tạo một dịch vụ dịch thuật

• Mở Automatorứng dụng từ Applicationsthư mục của bạn
• Chọn Servicelàm loại tài liệu và nhấpChoose
• Trong cửa sổ xuất hiện, nhấp vào trường tìm kiếm và nhập 'AppleScript'
• Kéo và thả Run AppleScripthành động từ danh sách bên trái vào khu vực có nhãn 'Kéo hành động hoặc tệp ở đây để xây dựng quy trình công việc của bạn'

Sao chép tập lệnh bên dưới và dán nó vào Run Applescripthành động:

on run {input, parameters}
    set phrase to input as string
    set phrase to quoted form of phrase

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "zh-CN"

    do shell script "open 'https://translate.google.com/?hl='" & ui_lang & "'&sl='" & from_lang & "'&tl='" & to_lang & "'&text='" & phrase
end run

Cửa sổ của bạn sẽ trông như sau:

Có ba giá trị mà bạn có thể muốn thay đổi trong tập lệnh trên:

• ui_lang - ngôn ngữ được sử dụng cho giao diện trang
• from_lang - ngôn ngữ nguồn
• to_lang - ngôn ngữ đích

Thay đổi một hoặc nhiều trong số này để đạt được bản dịch mong muốn. Để tìm các tham số ngôn ngữ chính xác, hãy tham khảo Tài liệu tham khảo ngôn ngữ . Trong ví dụ trên enđề cập đến Englishvà zh-CNtiếng Trung Quốc (Đơn giản hóa).

Sau khi thực hiện các thay đổi của bạn, nhấp File> Save...và trong bảng điều khiển xuất hiện, nhập tên phù hợp (ví dụ Translate English to Chinese).

Sử dụng dịch vụ dịch thuật

Sau khi lưu quy trình công việc của bạn ở trên, bạn có thể sử dụng dịch vụ dịch thuật của mình bằng một trong hai phương pháp sau:

1. Phương pháp Menu dịch vụ

• Đánh dấu một từ hoặc cụm từ trong bất kỳ ứng dụng nào
• Nhấp vào Menu Ứng dụng ở bên phải biểu tượng Apple (), sau đó nhấp Servicesvà Translate English to Chinese(hoặc tên bạn đã đặt Dịch vụ của mình khi lưu nó):

2. Phương pháp Menu ngữ cảnh

• Đánh dấu một từ hoặc cụm từ trong bất kỳ ứng dụng nào
• Nhấp chuột phải vào văn bản và chọn Servicessau đó Translate English to Chinese(hoặc Dịch vụ có tên tùy chỉnh của bạn):

Dù bạn sử dụng phương pháp nào, một cửa sổ trình duyệt sẽ xuất hiện cùng với văn bản dịch của bạn:

Cái này thực hiện mọi thứ như câu trả lời của souldding nhưng nếu url của người dịch đã có sẵn - tải bản dịch mới trong cùng một tab

on run {input, parameters}
    set phrase to input as string

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "ru"

    set theBaseUrl to "https://translate.google.com/"
    set theUrl to theBaseUrl & "?hl=" & ui_lang & "&sl=" & from_lang & "&tl=" & to_lang & "&text=" & phrase

    tell application "Google Chrome"
        activate

        if (count every window) = 0 then
            make new window
        end if

        set found to false
        set theTabIndex to -1
        repeat with theWindow in every window
            set theTabIndex to 0
            repeat with theTab in every tab of theWindow
                set theTabIndex to theTabIndex + 1
                if theTab's URL starts with theBaseUrl then
                    set found to true
                    exit repeat
                end if
            end repeat

            if found then
                exit repeat
            end if
        end repeat

        if found then
            set URL of theTab to theUrl
            set theWindow's active tab index to theTabIndex
            set index of theWindow to 1
        else
            tell window 1 to make new tab with properties {URL:theUrl}
        end if
    end tell

end run