Cách thêm hàng loạt thư mục vào Tác vụ thư mục

Tôi chủ động quản lý một thư mục chứa các thư mục chứa hình ảnh được sắp xếp theo ngày sửa đổi. Do đó, tôi đã thực hiện một hành động nhanh chóng sử dụng một applescript và bash để giúp tôi đảm bảo rằng các tệp mới được thêm vào có ngày sửa đổi phù hợp.

Điều này rất tốn thời gian và cuối cùng tôi đã học được rằng tôi có thể thiết lập Tác vụ thư mục có thể tự động thực hiện công việc đó cho tôi. Tôi đã làm như vậy và bây giờ tôi phải đối mặt với cuộc đấu tranh để thêm nhiều (rất nhiều) thư mục vào cửa sổ Cài đặt Tác vụ Thư mục.

Với tinh thần tự động hóa mọi thứ, có cách nào để thêm Thư mục vào cửa sổ Cài đặt Tác vụ Thư mục và tất cả các thư mục đã thêm để bật hành động thư mục của tôi không? Không biết chắc nên bắt đầu từ đâu!

Có một ứng dụng được tạo ra cho điều này, thật không may, liên kết tải xuống không còn hoạt động và nhà phát triển đã xóa nó khỏi trang dự án của mình.

Mã AppleScript sau đây sẽ yêu cầu bạn chọn tệp tập lệnh để đính kèm, sau đó chúng tôi sẽ cung cấp cho bạn hai tùy chọn riêng để thêm nhiều thư mục để đính kèm tệp tập lệnh đó vào

Điều này hoạt động với tôi bằng cách sử dụng phiên bản mới nhất của MacOS Mojave.

property pathToFolderActions : ((path to workflows folder as text) & "Applications:Folder Actions:")

tell application "Finder"
    set resourceName to (choose file with prompt ¬
        "Choose The Script File To Attach")
    set resourceName2 to name of resourceName
    set folderActionScript to (container of resourceName as text) & resourceName as string
    try
        duplicate resourceName to folder pathToFolderActions with replacing
    end try
end tell

activate
set theFolders to (choose folder with prompt ¬
    "Choose Folders" default location (path to desktop) ¬
    invisibles false ¬
    with multiple selections allowed)

activate
set chooseAgain to button returned of (display dialog ¬
    "Would You Like To Choose  Additional Folders?" buttons {"NO", "YES"} ¬
    default button "YES" with title ¬
    "Would You Like To Choose  Additional Folders?" with icon 1)

if chooseAgain is "YES" then
    activate
    set moreFolders to (choose folder with prompt ¬
        "Choose Folders" default location (path to desktop) ¬
        invisibles false ¬
        with multiple selections allowed)
    set theFolders to theFolders & moreFolders
end if

repeat with i from 1 to count of theFolders
    set thisItem to item i of theFolders
    tell application "Finder"
        set nameOfTriggerFolder to name of folder thisItem
        set attachFolderActionTo to (container of thisItem as text) & nameOfTriggerFolder
    end tell

    tell application "Folder Actions Setup"
        activate
        try
            set addedFolderAction to make new folder action with properties {name:nameOfTriggerFolder, path:attachFolderActionTo}
        end try
        try
            delay 0.5
            tell addedFolderAction to make new script with properties {name:resourceName2, path:(pathToFolderActions & resourceName2)}
        end try
        if not folder actions enabled then
            set folder actions enabled to true
        end if
    end tell
end repeat

delay 5
tell application "Folder Actions Setup" to quit