Cách tạo tập lệnh apple chuyển tiếp email bị gắn cờ

Tôi muốn tạo một tập lệnh apple sẽ chuyển tiếp email được gắn cờ tới x@mail.asana.com

Tôi đã thử kịch bản này:

on run

 tell application "Mail"
    repeat with _acct in imap accounts
        --Look For Flagged Messages in the INBOX
        set _acct_name to name of _acct
        set _inbox to _acct's mailbox "INBOX"

        set _msgs_to_capture to (a reference to ¬
            (every message of _inbox ¬
                whose flagged status is true))

        repeat with eachMessage in _msgs_to_capture
            set theStart to missing value
            set theDue to missing value
            set theOmniTask to missing value

            set theTitle to the subject of eachMessage
            set theNotes to the content of eachMessage

            set theCombinedBody to "message://%3c" & message id of eachMessage & "%3e" & return & return & theNotes

            tell application "OmniFocus"
                tell default document
                    set newTaskProps to {name:theTitle}
                    if theStart is not missing value then set newTaskProps to newTaskProps & {start date:theStart}
                    if theDue is not missing value then set newTaskProps to newTaskProps & {due date:theDue}
                    if theCombinedBody is not missing value then set newTaskProps to newTaskProps & {note:theCombinedBody}

                    set newTask to make new inbox task with properties newTaskProps
                end tell
            end tell

            set flagged status of eachMessage to false

        end repeat

    end repeat
end tell

end run

Tuy nhiên, tập lệnh này mở OmniF Focus thay vì chỉ gửi email.

Làm cách nào để tôi thay đổi tập lệnh này hoặc bắt đầu với tập lệnh mới để nó sẽ tự động chuyển tiếp email được gắn cờ đến x@mail.asana.com?

Đây là một số mã, không có tham chiếu đến ứng dụng OmniF Focus của bạn, mà chuyển tiếp tất cả các tin nhắn được gắn cờ đến một địa chỉ được đặt. Điều chỉnh theo ý thích của bạn ....

Hoạt động như một bùa mê trên macbook Snow Leopard của tôi.

set toAddress to "userx@mail.asana.com"
set toName to "User X"

tell application "Mail"
    repeat with _acct in imap accounts
        --Look For Flagged Messages in the INBOX
        set _acct_name to name of _acct
        set _inbox to _acct's mailbox "INBOX"
        set _msgs_to_capture to (a reference to ¬
            (every message of _inbox ¬
                whose flagged status is true))

        repeat with _msg in _msgs_to_capture
            set _fwdmsg to forward _msg with opening window

            tell _fwdmsg
                make new to recipient at end of ¬
                    to recipients with properties {name:toName, address:toAddress}
            end tell

            activate

            send _fwdmsg
        end repeat
    end repeat
end tell