Làm thế nào để đạt được hành động song song động với một đường ống khai báo?

Hiện tại, tôi sẽ cần một triển khai phải tìm tất cả các tệp trong một thư mục và bắt đầu một tác vụ song song cho mọi tệp được tìm thấy.

Có thể đạt được điều này bằng cách sử dụng các đường ống khai báo?

pipeline {
    agent any
    stages {
        stage("test") {
            steps {
                dir ("file_path") {
                    // find all files with complete path
                    parallel (
                        // execute parallel tasks for each file found.
                        // this must be dynamic
                        }
                    }
                }
            }
        }
    }
}

Quản lý để giải quyết nó với mã sau đây:

pipeline {
    agent { label "master"}
    stages {
        stage('1') {
            steps {
                script {
                    def tests = [:]
                    for (f in findFiles(glob: '**/html/*.html')) {
                        tests["${f}"] = {
                            node {
                                stage("${f}") {
                                    echo '${f}'
                                }
                            }
                        }
                    }
                    parallel tests
                }
            }
        }       
    }
}

Điều này cũng hoạt động, nếu bạn muốn ở trong Declarative Pipelinekhông gian

// declare our vars outside the pipeline
def tests = [:]
def files

pipeline {
    agent any
    stages {
        stage('1') {
            steps {
                script {
                    // we've declared the variable, now we give it the values
                    files = findFiles(glob: '**/html/*.html')
                    // Loop through them
                    files.each { f ->
                        // add each object from the 'files' loop to the 'tests' array
                        tests[f] = {
                            // we're already in the script{} block, so do our advanced stuff here
                            echo f.toString()
                        }
                    }
                    // Still within the 'Script' block, run the parallel array object
                    parallel tests
                }
            }
        }       
    }
}

Sử dụng Pipelines theo kịch bản dễ dàng hơn nhiều để làm điều này vì bạn có thể sử dụng Groovy tùy ý, nhưng bạn vẫn có thể làm điều này với Pipelines khai báo bằng findFilesbước này.

Xin lưu ý rằng các bước xây dựng động có thể gây ra một số vấn đề trong một số bước xây dựng, ví dụ như khi bạn gọi một công việc khác:

pipeline {
    stages {
        stage('Test') {
            steps {
                script {
                    def tests = [:]
                    for (f in findFiles(glob: '**/html/*.html')) {
                        // Create temp variable, otherwise the name will be the last value of the for loop
                        def name = f
                        tests["${name}"] = {
                            build job: "${name}"
                        }
                    }
                    parallel tests
                }
            }
        }       
    }
}