Làm thế nào để có được pid process riêng từ dấu nhắc lệnh trong windows

Tôi đang cố gắng tìm cách để có được PID của riêng mình từ một dấu nhắc lệnh (để sử dụng sau này trong tập lệnh bat) cho đến nay cách hữu ích duy nhất tôi tìm thấy là sử dụng getpids.exe từ đây: http://www.scheibli.com/ dự án / getpids / index.html nhưng tôi đang tìm kiếm một lệnh "tích hợp" cho windows

chỉnh sửa: tôi đang tìm kiếm một cách "chống đạn" - không có giả định nào về quy trình của tôi là cmd.exe duy nhất hoặc bất cứ điều gì

Vì không có giải pháp nào khác có khả năng chống đạn và tích hợp sẵn, tôi cho rằng tôi sẽ cung cấp giải pháp sau đây, nhưng lưu ý rằng bạn sẽ cần phân tích / lưu kết quả bằng cách nào đó:

title mycmd
tasklist /v /fo csv | findstr /i "mycmd"

Tôi tin rằng những điều sau đây là chống đạn, miễn là người dùng có quyền truy cập vào các điểm WMIC và TEMP đến một đường dẫn hợp lệ nơi người dùng có đặc quyền ghi. Đây là kết quả cuối cùng của một số công việc hợp tác tại http://www.dostips.com/forum/viewtopic.php?f=3&t=6133 .

@echo off

:getPID  [RtnVar]
::
:: Store the Process ID (PID) of the currently running script in environment variable RtnVar.
:: If called without any argument, then simply write the PID to stdout.
::
setlocal disableDelayedExpansion
:getLock
set "lock=%temp%\%~nx0.%time::=.%.lock"
set "uid=%lock:\=:b%"
set "uid=%uid:,=:c%"
set "uid=%uid:'=:q%"
set "uid=%uid:_=:u%"
setlocal enableDelayedExpansion
set "uid=!uid:%%=:p!"
endlocal & set "uid=%uid%"
2>nul ( 9>"%lock%" (
  for /f "skip=1" %%A in (
    'wmic process where "name='cmd.exe' and CommandLine like '%%<%uid%>%%'" get ParentProcessID'
  ) do for %%B in (%%A) do set "PID=%%B"
  (call )
))||goto :getLock
del "%lock%" 2>nul
endlocal & if "%~1" equ "" (echo(%PID%) else set "%~1=%PID%"
exit /b

Kịch bản thiết lập một khóa độc quyền trên một tệp tạm thời kết hợp thời gian hiện tại vào tên. Chỉ có thể có xung đột nếu hai quá trình giống như được đặt tên cố gắng để có được PID trong cùng khoảng thời gian 0,01 giây, trong trường hợp đó chỉ có một quá trình sẽ thành công.

Bất kỳ quá trình nào không thành công sẽ lặp lại nhiều lần và thử lại với đường dẫn tệp khóa mới cho đến khi thành công.

Đường dẫn đầy đủ đến tệp khóa được chuyển thành ID duy nhất có thể được sử dụng trong truy vấn WMIC. WMIC được chạy trong lệnh FOR / F, có nghĩa là nó đang chạy trong tiến trình cmd.exe con. Đó là lý do tại sao ParentProcessID của quá trình cmd.exe được truy xuất.

Mở rộng theo câu trả lời của Tony Roth:

title uniqueTitle
for /f "tokens=2 USEBACKQ" %f IN (`tasklist /NH /FI "WINDOWTITLE eq uniqueTitle*"`) Do echo %f

Sử dụng bộ lọc WINDOWTITLE để tránh đường ống để bạn có thể đặt nó vào một vòng lặp for và gán nó cho một biến với SET nếu bạn muốn:

title uniqueTitle
for /f "tokens=2 USEBACKQ" %f IN (`tasklist /NH /FI "WINDOWTITLE eq uniqueTitle*"`) Do set ourPID=%f

Loại bỏ /vlàm cho nó nhanh hơn và /NHthoát khỏi dòng tiêu đề. Bạn cần ký tự đại diện sau "uniqueTitle"vì tiêu đề cửa sổ thực sự chứa lệnh hiện tại (do đó nó sẽ tiếp tục và tiếp tục nếu bạn cố gắng khớp hoàn toàn với nó).

Sử dụng PowerShell + WMI:

powershell (Get-WmiObject Win32_Process -Filter ProcessId=$PID).ParentProcessId

1. Trình quản lý tác vụ Windows, bạn sẽ cần vào Xem -> Chọn Cột .. và chọn PID.
2. "tasklist / v" để nhận thông tin tác vụ dài dòng trong dấu nhắc lệnh.
3. Process Explorer từ live.sysiternals.com .

nếu bạn biết chỉ có một cmd.exe đang chạy, bạn có thể nhận được PID theo cách này:

for /F "tokens=1,2" %%i in ('tasklist /FI "IMAGENAME eq cmd.exe" /fo table /nh') do set pid=%%j

echo %pid%

Cái này cần phải dùng mẹo:

nhiệm vụ / v

Nếu bạn muốn tìm PID của tên hình ảnh "notepad.exe", thì đoạn mã sau sẽ hoạt động cho bạn:

for /F "tokens=1,2" %i in ('tasklist') do (
 if "%i" equ "notepad.exe" (set x=%j)
)
echo %x%

Nếu bạn đã có bộ tài nguyên Windows 2003, hãy đẩy nó qua qgrep để có được dòng bạn muốn. Sau đó, bạn có thể trích xuất pid từ đây (điều này giả sử bạn chỉ có một cmd chạy mỗi lần),

tasklist /v | qgrep cmd

cmd.exe 2040 RDP-Tcp#447 0 1,804 K Running MACHINE\Administrator  0:00:00 Command Prompt

Hãy xem thủ thuật lô nhỏ này . Nó đặt tiêu đề của cmd thành một giá trị đặc biệt sau đó sử dụng danh sách tác vụ để tìm nó. Sáng tạo

\ Greg

ĐÂY LÀ CÁCH NGẮN HẠN ĐỂ NHẬN ID QUY TRÌNH CHO MỞ CMD

tasklist /v /fi "imagename EQ cmd.exe" /FO LIST | FIND "PID:"

Câu trả lời này sẽ cung cấp cho bạn CHỈ ID quy trình và không có nội dung bổ sung nào mà câu trả lời hàng đầu bao gồm.

title mycmd
tasklist /v /fo csv | findstr /i "mycmd" > PIDinfo.txt

set /p PIDinfo=<PIDinfo.txt
set PID1=%PIDinfo:~11,5%
set PID2=%PIDinfo:~11,4%

if %PID2% gtr 8100 (
    set PID=%PID2%
) else (
    set PID=%PID1%
)

echo %PID%

Giải trình:

-có thể sẽ không phải là một PID cho cmd.exe lớn hơn 18100, vì vậy hãy kiểm tra xem PID2 có lớn hơn 8100 không để chúng tôi biết đó là số có 4 chữ số hay 5 chữ số

trường hợp 1: một PID gồm 5 chữ số như 17504 có giá trị PID1 là 17504 và giá trị PID2 là 1750, vì vậy chúng tôi sử dụng PID1

trường hợp 2: một PID gồm 4 chữ số như 8205 có giá trị PID1 là 8205 "và giá trị PID2 là 8205, vì vậy chúng tôi sử dụng PID2

trường hợp 3: một PID gồm 4 chữ số như 4352 có giá trị PID1 là 4352 "và giá trị PID2 là 4352, vì vậy chúng tôi sử dụng PID2