Các tệp bó Windows có cấu trúc% * không?

Trong một tệp bó, tôi có phải làm (ví dụ) như sau không?

@echo off
call other.bat %1 %2 %3 %4 %5 %6 %7 %8 %9

Các tệp bó của Windows (kể từ Windows XP, nhưng có thể sớm hơn) hỗ trợ %*cấu trúc, ước tính cho tất cả các tham số từ% 1 trở đi.

Thật không may, điều này không tôn trọng SHIFTlệnh, vì vậy những điều sau đây sẽ không hoạt động:

@echo off
set EATEN=%1
shift

call other.bat %*

Nó vẫn sẽ chuyển tham số đầu tiên vào tệp bó thứ hai.

Bạn có thể tập hợp tất cả các đối số lại với nhau bằng cách sử dụng một cái gì đó như:

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Điều này hoạt động bất kể có bao nhiêu đối số.

Ví dụ, nếu bạn muốn bỏ qua 3 tham số đầu tiên và chuyển phần còn lại:

@echo off
for /f "tokens=1-3*" %%a in ("%*") do (
   set par1=%%a
   set par2=%%b
   set par3=%%c
   set therest=%%d
   )

call other.bat %therest%

Có thể có vấn đề với dấu ngoặc kép trong các tham số.

danh tiếng cho Patrick Cuff, /programming/382587/how-to-get-batch-file-parameter-from-nth-poseition-on

Có họ làm.

Bạn có thể viết ví dụ của bạn như sau:

@echo off
call other.bat %*

Ngoài ra: sự thay đổi được hỗ trợ trên windows ... Xem này .
Nhưng thực tế, liên kết cuối cùng đó xác nhận rằng ca làm việc không hoạt động kết hợp với% *:

• Sử dụng% * với shift
  Shift không ảnh hưởng đến tham số lô% *.

@echo off
cls
setlocal enabledelayedexpansion

:: Disable the display of information by changing [set "_ENABLE_INFO="] to [set "_ENABLE_INFO=::"].
set "_ENABLE_INFO="
set _DBQ="

set "_PARMS.ORIGINAL=%*" && if defined _PARMS.ORIGINAL (
   if not defined _PARMS.IDX (
      echo Parameter Index^(es^) to extract eg.:
      echo 1 2 5 9 11 39 400
      set /p "_PARMS.IDX=>"
   )
   set "_PARMS.IDX=¡!_PARMS.IDX: =¡ ¡!¡"
   set "_PARMS.IDX=!_PARMS.IDX:¡¡=!"
   set "_PARMS.IDX=!_PARMS.IDX: =!"
   call :_FN_PROC.STRING %*
%_ENABLE_INFO% goto :FINISH
   goto :eof
) else (
   echo No input parameters.
)
goto :eof


:_FN_PROC.STRING
set "_PARMS.PROCESS.STRING=%*"
:_FN_PROC.STRING.LOOP
set "_PARMS.PROCESS.STRING=!_PARMS.PROCESS.STRING:%_DBQ%=¡!"
set /a _PARMS.COUNT+=1
for /f "tokens=1* delims= " %%a in ("!_PARMS.PROCESS.STRING!") do (
   set _PARMS.TMP.CHECK=%%a
   set _PARMS.PROCESS.STRING=%%b
   if "!_PARMS.TMP.CHECK!" NEQ "!_PARMS.TMP.CHECK:¡=!" (
      for /f "tokens=1* delims=¡" %%c in ("%%a !_PARMS.PROCESS.STRING!") do (
         set _PARMS.TMP.CHECK="%%c"
         set _PARMS.PROCESS.STRING=%%d
      )
   )
)

if "!_PARMS.IDX:¡%_PARMS.COUNT%¡=!" EQU "!_PARMS.IDX!" (
   set _PARMS.REMAINING=!_PARMS.REMAINING! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX!{%_PARMS.COUNT%}
) else (
   set _PARMS.EXTRACTED=!_PARMS.EXTRACTED! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX:¡%_PARMS.COUNT%¡=!
   set _PARMS.IDX=!_PARMS.IDX![%_PARMS.COUNT%]
)

if "!_PARMS.PROCESS.STRING: =!"=="" (set _PARMS.PROCESS.STRING=)
if defined _PARMS.PROCESS.STRING (goto :_FN_PROC.STRING.LOOP)

set _DBQ=
set _PARMS.TMP.CHECK=
if defined _PARMS.REMAINING (set _PARMS.REMAINING=!_PARMS.REMAINING:~1!)
if defined _PARMS.EXTRACTED (set _PARMS.EXTRACTED=!_PARMS.EXTRACTED:~1!)
goto :eof


:FINISH
echo.
echo _PARMS.IDX ^:
echo    ¡^=¡ no Parameter Index was specified for extraction.
echo    ¡n¡ nth Parameter was not processed (Index larger than Parameters Count).
echo    [n] nth Parameter was Extracted.
echo    {n} nth Parameter was Ignored (Remaining).
echo.
set _
goto :eof