Tiện ích Windows để hiển thị phím nào tôi đang nhấn trên màn hình [đã đóng]

Tôi đang đào tạo cho một nhóm lớn người từ xa và sẽ bao gồm một số phím tắt ứng dụng.

Tôi đã thấy màn hình nhấn phím trên màn hình của MousePose ; Có một sản phẩm tương tự cho Windows?

Các tính năng khác của MousePose (con trỏ chuột ưa thích, v.v.) không thực sự hữu ích với tôi, chỉ là OSD của các lần nhấn phím.

KeyPosé là một thay thế miễn phí cho MousePosé cho Windows. Bạn có thể thấy nó trong hành động trong screencast .

Đây là một ảnh chụp màn hình mẫu:

Tôi đánh giá cao Carnac . Đây là một dự án miễn phí được lưu trữ trên GitHub.

Một tiện ích ghi nhật ký và trình bày bàn phím cho các bài thuyết trình, screencasts và để giúp bạn trở thành người dùng bàn phím tốt hơn.

Nó được thực hiện độc đáo, được thiết kế độc đáo và cũng có nguồn mở trên GitHub .

Tìm một bản phát hành ngã ba với các bản sửa lỗi và trực quan hóa đầu vào chuột tại đây: https://github.com/bfritscher/carnac/release/tag/v3-beta

Tôi muốn chia sẻ công cụ của tôi - keycastow.

https://brookhong.github.io/2014/04/11/keycast-on-windows.html

Tôi đã viết một kịch bản AutoHotkey_L cho mục đích này.

Để chạy nó, hãy sử dụng AutoHotkey_L ( dl trực tiếp ), đó là FOSS. Ngoài ra, với AutoHotkey, bạn có thể biên dịch tập lệnh thành EXE (đơn giản ).Ahk2Exe.exe /inDisplayPressedKeyOnScreen.ahk/outDisplayPressedKeyOnScreen.exe

Nó có thể hiển thị các phím được nhấn giống như OSD hoặc Mẹo công cụ tiêu chuẩn gần con trỏ chuột. Ngoài ra, nó hiển thị nhấp chuột và cuộn bánh xe.

(lưu ý rằng khung và làm mờ được thực hiện cho mục đích minh họa, bản thân tập lệnh chỉ hiển thị văn bản với bất kỳ sự xáo trộn nào)

Đây là tập lệnh (sao chép và dán vào notepad, lưu dưới dạng DisplayPressionKeysOnScreen.ahk):

#NoEnv
#SingleInstance force
#InstallKeybdHook

Global KeyStates, MouseState, ClickCount, IdleDelay, LargeDisplay

IdleDelay=3000

LargeDisplay=1
; 0 = Tooltip near mouse pointer
; 1 = Big pane at screen bottom

If LargeDisplay
{
;Initializing GUI
;modded func originated from http://www.autohotkey.com/board/topic/8190-osd-function/

SysGet Monitor, Monitor

GUIx := MonitorLeft
GUIw := MonitorRight - MonitorLeft
GUIh := (MonitorBottom - MonitorTop) * GUIw * 0.00003
If (GUIh > ((MonitorBottom - MonitorTop) * 0.3))
    GUIh := (MonitorBottom - MonitorTop) * 0.3

opacity=230
fname="Tahoma"
fsize:=GUIh * 0.65 ; really, pixel = 0.75 point, but with 0.75 lowercase letter with lower part (like "g") get cut
fcolor=cccccc
bcolor=222222
fformat="600"

Gui +LastFound +AlwaysOnTop +ToolWindow -Caption
Gui Margin, 0, 0 ;pixels of space to leave at the left/right and top/bottom sides of the window when auto-positioning.
Gui Color, ffffff ;changes background color
Gui Font, s%fsize% w%fformat%, %fname%

;    0x80 = SS_NOPREFIX -> Ampersand (&) is shown instead of underline one letter for Alt+letter navigation
Gui Add, Text, c%bcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName, tesT test test
Gui Add, Text, c%fcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName2 xp-3 yp-3 , tesT test test

WinSet ExStyle, +0x20 ; WS_EX_TRANSPARENT -> mouse klickthrough
WinSet TransColor, ffffff %opacity%
}


TrayTip %A_ScriptName%, To Exit`, press the Right Windows logo key.

Loop
{
Input SingleKey, L1 V M I B, {LControl}{RControl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{BS}{Capslock}{Numlock}{PrintScreen}{Pause}
GetKeyStates()

;    IfInString ErrorLevel, EndKey
;   CollectedText .= (CollectedText =="" ? "" : " + " ) . SubStr(ErrorLevel, 8)
If SingleKey
{
    SingleKeyText=
    If (SingleKey==Chr(27))
    SingleKeyText=Esc
    Else If (SingleKey==Chr(32))
    SingleKeyText=Space

    If (GetKeyState("LControl", "P") || GetKeyState("RControl", "P"))
    {
    If (SingleKey==Chr(10) && EnterPressed)
        SingleKeyText=Enter
    Else If (SingleKey >= Chr(1) && SingleKey <= Chr(26)) ; With "M" in Input, Ctrl-A through Ctrl-Z correspond to Chr(1) through Chr(26)
        SingleKeyText := Chr(Asc("A")-1+Asc(SingleKey))
    } Else {
    If (SingleKey==Chr(10))
        SingleKeyText=Enter
    }

    If Not SingleKeyText
    SingleKeyText:=SingleKey
    ShowKeys(KeyStates . SingleKeyText)
;    . (MouseState ? "`n" . MouseState : "")
    EnterPressed=0
    GoSub ClearMouseState
} Else {
    ShowKeys(SubStr(KeyStates, 1, -3) . (MouseState ? " + " . MouseState : ""))
}
SetTimer TooltipOff, % -IdleDelay
}

RWin::
ExitApp

~*Enter::
EnterPressed=1
return

~*LButton::
~*RButton::
~*MButton::
~*XButton1::
~*XButton2::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3) . " Pressed"
MouseTooltip()
return

~*WheelDown::
~*WheelUp::
~*WheelLeft::
~*WheelRight::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3)
MouseTooltip()
return

~*LButton Up::
~*RButton Up::
~*MButton Up::
~*XButton1 Up::
~*XButton2 Up::
;    MsgBox %A_PriorHotkey%`n%A_ThisHotkey%
If (A_PriorHotkey == SubStr(A_ThisHotkey, 1, -3) && A_TimeSincePriorHotkey < 200)
{
    ClickCount++
    Suffix := " Clicked " . ClickCount . "x"
} Else {
    ClickCount:=0
    Suffix := " Released"
}
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3, -3) . Suffix
MouseTooltip()
return

MouseTooltip(){
GetKeyStates()
ShowKeys(KeyStates . MouseState)
SetTimer ClearMouseState,  % -IdleDelay
SetTimer TooltipOff, % -IdleDelay
}

ClearMouseState:
MouseState=
ClickCount=0
return
TooltipOff:
If LargeDisplay
    Gui Hide
Else
    Tooltip
return

GetKeyStates() {
KeyStates := ""
    . ( GetKeyState("LControl", "P") ? "LControl + " : "" )
    . ( GetKeyState("RControl", "P") ? "RControl + " : "" )
    . ( GetKeyState("LAlt", "P") ? "LAlt + " : "" )
    . ( GetKeyState("RAlt", "P") ? "RAlt + " : "" )
    . ( GetKeyState("LShift", "P") ? "LShift + " : "" )
    . ( GetKeyState("RShift", "P") ? "RShift + " : "" )
    . ( GetKeyState("LWin", "P") ? "LWin + " : "" )
    . ( GetKeyState("AppsKey", "P") ? "AppsKey + " : "" )
    . ( GetKeyState("F1", "P") ? "F1 + " : "" )
    . ( GetKeyState("F2", "P") ? "F2 + " : "" )
    . ( GetKeyState("F3", "P") ? "F3 + " : "" )
    . ( GetKeyState("F4", "P") ? "F4 + " : "" )
    . ( GetKeyState("F5", "P") ? "F5 + " : "" )
    . ( GetKeyState("F6", "P") ? "F6 + " : "" )
    . ( GetKeyState("F7", "P") ? "F7 + " : "" )
    . ( GetKeyState("F8", "P") ? "F8 + " : "" )
    . ( GetKeyState("F9", "P") ? "F9 + " : "" )
    . ( GetKeyState("F10", "P") ? "F10 + " : "" )
    . ( GetKeyState("F11", "P") ? "F11 + " : "" )
    . ( GetKeyState("F12", "P") ? "F12 + " : "" )
    . ( GetKeyState("Left", "P") ? "Left + " : "" )
    . ( GetKeyState("Right", "P") ? "Right + " : "" )
    . ( GetKeyState("Up", "P") ? "Up + " : "" )
    . ( GetKeyState("Down", "P") ? "Down + " : "" )
    . ( GetKeyState("Home", "P") ? "Home + " : "" )
    . ( GetKeyState("End", "P") ? "End + " : "" )x
    . ( GetKeyState("PgUp", "P") ? "PgUp + " : "" )
    . ( GetKeyState("PgDn", "P") ? "PgDn + " : "" )
    . ( GetKeyState("Del", "P") ? "Del + " : "" )
    . ( GetKeyState("Ins", "P") ? "Ins + " : "" )
    . ( GetKeyState("BS", "P") ? "BS + " : "" )
    . ( GetKeyState("Capslock", "P") ? "Capslock + " : "" )
    . ( GetKeyState("Numlock", "P") ? "Numlock + " : "" )
    . ( GetKeyState("PrintScreen", "P") ? "PrintScreen + " : "" )
    . ( GetKeyState("Pause", "P") ? "Pause + " : "" )
}

ShowKeys(text) {
If LargeDisplay
{
    Global blkOsdCtrlName, blkOsdCtrlName2, MonitorLeft, MonitorRight, MonitorBottom, MonitorTop, GUIx, GUIy, GUIh

    CoordMode Mouse, Screen
    MouseGetPos MouseX, MouseY

    If ((!GUIy) || (MouseX >= MonitorLeft && MouseX <= MonitorRight && MouseY >= GUIy && MouseY <= (GUIy+GUIh)) ) {
    If (MouseY < (MonitorTop + (MonitorBottom - MonitorTop) / 2) )
        GUIy := MonitorBottom - (MonitorBottom - MonitorTop) * 0.2
    Else
        GUIy := MonitorTop + (MonitorBottom - MonitorTop) * 0.2
    }

    GuiControl Text, blkOsdCtrlName, %text%
    GuiControl Text, blkOsdCtrlName2, %text%

    Gui, Show, x%GUIx% y%GUIy% NoActivate
} Else {
    Tooltip % text
}
}

Bạn có thể sử dụng bàn phím trên màn hình để hiển thị các phím bấm đi kèm với cửa sổ. Khi bạn gõ trên bàn phím vật lý, trên màn hình sẽ có một phím nổi bật.

Con trỏ trình bày là một thay thế tốt nhất cho MousePosé cho Windows. Nó cung cấp Hiệu ứng con trỏ, Hiệu ứng nhấp chuột, tổ hợp phím và thậm chí cho phép bạn vẽ tự do trên màn hình nhưng không khóa màn hình. Đó thực sự là một lợi thế của chương trình.

Con trỏ tập trung có thể hiển thị tổ hợp phím của bạn.

Tôi đã viết một ứng dụng Windows nhỏ có tên QiPress . Nó có các điều khiển để thay đổi giao diện, hiển thị hoặc bỏ qua các nhóm khóa nhất định, thậm chí thêm văn bản tĩnh (ví dụ tên của bạn hoặc tên công ty). Định vị có thể bằng cách vô hiệu hóa nhấp qua và kéo nhấp vào cửa sổ bật lên. Có những tính năng khác mà bạn có thể không yêu cầu, nhưng nó bao gồm hầu hết những gì bạn muốn.

Bạn có thể sử dụng PassMark KeyboardTest (Đánh giá miễn phí 30 ngày, sau đó là US $ 24,00 để mua hàng.)

Tài chính

• Một câu hỏi tương tự đã được hỏi trên SO: Làm thế nào để hiển thị các phím tắt được nhấn trên màn hình trong khi thuyết trình hoặc ghi lại màn hình
• Một câu hỏi tương tự đã được đặt ra cho OS X: https://apple.stackexchange.com/q/62168/20338
• Một câu hỏi liên quan đã được hỏi về các khuyến nghị phần mềm (OP yêu cầu chương trình hiển thị các phím mà người dùng hiện đang nhấn trong khi sử dụng các chương trình khác. Nó sẽ hiển thị tất cả các phím được nhấn và ngay khi người dùng nhả phím - nó sẽ biến mất. ): Tiện ích để hiển thị trên màn hình các phím hiện được nhấn