& thật bất ngờ vào lúc này

Tôi có một tệp bó được cho là đặt một số biến ở đầu.

for /f %%A in ('wmic os get osarchitecture ^| find /i "bit"') do set "OSARCH=%%A"
for /f "skip=1 tokens=4" %%B in ('wmic product where "name like 'Microsoft .NET%'" get name') do set "DNVER=%%B"
for /f "tokens=3" %%C in ('reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v svcVersion' do set "IEFULLVER=%%C"
set IEVER=%IEFULLVER:~0,4%

Nếu tôi chạy các lệnh này trong dấu nhắc CMD, (thay thế %% A cho% A, v.v.), chúng hoạt động như mong đợi, nhưng khi tôi chạy tệp bó, dòng đầu tiên chạy như mong đợi và sau đó tôi gặp & was unexpected at this timelỗi. Tôi nghĩ rằng nó có thể được thực hiện %sau đó .NET, nhưng nó phải ở đó nếu không truy vấn wmi sẽ không trả về giá trị tôi cần.

"& không ngờ vào lúc này"

Có hai lỗi trong tệp bó của bạn.

Sai lầm 1:

for /f "skip=1 tokens=4" %%B in ('wmic product where "name like 'Microsoft .NET%'" get name') do set "DNVER=%%B"

Lệnh trên cần phải có đơn %sau khi NETthoát. Sử dụng %%thay thế:

for /f "skip=1 tokens=4" %%B in ('wmic product where "name like 'Microsoft .NET%%'" get name') do set "DNVER=%%B"

Sai lầm 2:

for /f "tokens=3" %%C in ('reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v svcVersion' do set "IEFULLVER=%%C"

Lệnh trên bị thiếu một )trước do. Nó nên là:

for /f "tokens=3" %%C in ('reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v svcVersion') do set "IEFULLVER=%%C"

Tệp bó làm việc (test.cmd):

@echo off
setlocal EnableDelayedExpansion
for /f %%A in ('wmic os get osarchitecture ^| find /i "bit"') do set "OSARCH=%%A"
for /f "skip=1 tokens=4" %%B in ('wmic product where "name like 'Microsoft .NET%%'" get name') do set "DNVER=%%B"
for /f "tokens=3" %%C in ('reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v svcVersion') do set "IEFULLVER=%%C"
echo %OSARCH%
echo %DNVER%
echo %IEFULLVER%
endlocal

Ví dụ đầu ra:

F:\test>test
64-bit
4.5.2
11.0.9600.17691

Phần trăm thoát

Ký %tự có ý nghĩa đặc biệt cho các tham số dòng lệnh và tham số FOR.

Để coi phần trăm là một nhân vật thông thường, hãy nhân đôi nó:

%%

Cú pháp nguồn

Đọc thêm

• Một chỉ mục AZ của dòng lệnh Windows CMD - Một tài liệu tham khảo tuyệt vời cho tất cả những thứ liên quan đến dòng cmd của Windows.
• cú pháp - Ký tự thoát, dấu phân cách và dấu ngoặc kép.
• wmic - Lệnh quản lý thiết bị Windows.