Công thức Excel để tự động điền ngày

Tôi muốn có các ô F4-F23 tự động điền ngày hôm nay bất cứ khi nào dữ liệu được nhập vào các ô E4-E23. Sau đó, tôi cần phải có các ô I4-I23 tự động điền vào ngày hôm nay bất cứ khi nào dữ liệu được nhập vào các ô H4-H23. Dữ liệu được nhập vào các ô H4-H23 sẽ được nhập vào các ngày khác nhau sau đó dữ liệu được nhập vào các ô E4-E23. Tôi tìm thấy mã này hoạt động cho phần đầu tiên của câu hỏi của tôi, tôi cần biết cách sửa đổi nó để hoạt động trên các ô H và I.

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim E As Range, F As Range, Inte As Range, r As Range
    Set E = Range("E:E")
    Set Inte = Intersect(E, Target)
    If Inte Is Nothing Then Exit Sub
    Application.EnableEvents = False
        For Each r In Inte
            r.Offset(0, 1).Value = Date
        Next r
    Application.EnableEvents = True
End Sub

Thử đi:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim E As Range, H As Range, Inte As Range, r As Range
    Set E = Range("E:E")
    Set H = Range("H:H")
    Set Inte = Intersect(E, Target)
    If Not Inte Is Nothing Then
        Application.EnableEvents = False
        For Each r In Inte
            r.Offset(0, 1).Value = Date
        Next r
        Application.EnableEvents = True
    End If
    Set Inte = Intersect(H, Target)
    If Not Inte Is Nothing Then
        Application.EnableEvents = False
        For Each r In Inte
            r.Offset(0, 1).Value = Date
        Next r
        Application.EnableEvents = True
    End If
End Sub

Thay vì thoát khỏi phụ khi giao lộ không có gì, hãy kiểm tra đối diện không có gì và chạy mã riêng trên mỗi giao lộ.

Lưu ý, tôi đã khai báo H là phạm vi và loại bỏ khai báo F không sử dụng là phạm vi.