Cách di chuyển các thư mục có tên tương tự

tôi muốn biết làm thế nào nhiều một loạt các thư mục có tên tương tự với các thư mục khác nhau. ví dụ: (01/15) Mẹ (01/15) Bố (02/15) Bố (01/15) Anh (03/15) Con trai Vì vậy, những gì tôi muốn thực hiện là thư mục Parent (01/15) - thư mục con (01 / 15) Mẹ, (01/15) Bố và cứ thế. Nói cách khác, tôi muốn nhóm theo whats trong ngoặc. Vì vậy, những gì tôi muốn là tạo ra một thư mục ngày để di chuyển thư mục hình ảnh nhóm ngày phù hợp của nó. Họ rất nhiều thư mục vì vậy tôi không thể làm điều đó bằng tay.

Âm thanh như bạn có thể có nhiều vấn đề ở đây. Ảnh của bạn có dữ liệu meta không?

Làm thế nào ban đầu bạn nhóm các bức ảnh vào mẹ, cha, v.v. - quên ngày tháng bây giờ.

Họ đã được nhóm vào tên người dùng của họ? Hoặc tất cả các tệp trong một thư mục chỉ có ngày mà tệp được tạo trong tên tệp?

Bạn có thể thực hiện tìm kiếm trong Windows (tôi giả sử các cửa sổ của nó?) Và sắp xếp các bức ảnh theo ngày và các dữ liệu meta khác như thẻ, v.v. - các bộ lọc này đều nằm trong chức năng tìm kiếm của windows - tùy thuộc vào cách tạo ra các bức ảnh mà bạn có thể đơn giản đặt bộ lọc trong tìm kiếm và di chuyển tất cả chúng trong một lần.

Tôi làm điều này gần như hàng ngày với những bức ảnh, cả gia đình tôi và tôi mất rất nhiều tiền mỗi ngày và cuối cùng tôi luôn phải sắp xếp và sao lưu tất cả chúng!

Trong thư mục cấp cao nhất tạo tệp sort.vbs và thêm văn bản sau:

set objFSO = CreateObject("Scripting.FileSystemObject")
set objFolder = objFSO.GetFolder(".")
set colSubfolders = objFolder.Subfolders

strStartChar = "("
strEndChar   = ")"

for each objSubfolder in colSubfolders
    strNameOfFolder = objSubfolder.Name

    if instr(strNameOfFolder, strStartChar) > 0 then

        intStartCharacter = instr(strNameOfFolder,strStartChar) +1
        intEndCharacter   = instr(strNameOfFolder,strEndChar) 
        intLength         = intEndCharacter - intStartCharacter
        strNewFolderName  = mid(strNameOfFolder, intStartCharacter, intLength )

        wscript.echo "Processing: " & strNameOfFolder & ", extracted text for new folder: " & strNewFolderName

        if not objFSO.FolderExists(strNewFolderName) then
            objFSO.CreateFolder strNewFolderName
        end if    

        if objFSO.FolderExists(strNewFolderName) then
            set ExistingFolder = objFSO.GetFolder(strNameOfFolder)
            objFSO.MoveFolder ExistingFolder.name, strNewFolderName & "\"
        end if    

    else
        wscript.echo strNameOfFolder & " not for processing.  No " & strStartChar & " character in directory."
    end if

next

Sau đó mở một dấu nhắc lệnh trong cùng thư mục và chạy:

cscript.exe sort.vbs.

Như bạn có thể thấy, nó lấy chuỗi giữa (và) để tạo thư mục mới và di chuyển nội dung của thư mục gốc sang nó.

Lưu ý: Có rất ít lỗi kiểm tra và nó đưa ra một vài giả định về tên thư mục.