Bảng tính (Excel, Google Docs, v.v.), trích xuất giá trị được phân tách bằng dấu phẩy

7

Tôi có một giá trị trong một ô trông như thế này

4,8,2

Hãy nói rằng nó trong A1tế bào

Làm thế nào tôi có thể nhận được bên trong 8(giá trị được phân tách bằng dấu phẩy thứ hai) từ ô này vào ô B1?

=?

Đã thử =SPLIT(A1, ","), nhưng điều này phân tách các giá trị và ghi chúng vào nhiều ô.

Có ý kiến gì không?

microsoft-excel spreadsheet google-spreadsheets

— thiên văn
nguồn

Mỗi ô thuộc loại này có chính xác ba số được phân cách bằng dấu phẩy không?

— Steven

có, tất cả các chữ số từ 1 đến 8

— astropanic

Bạn cũng có thể thử chức năng "chuyển văn bản thành cột" trong Excel

— sq33G

9

Trong Google Sheets:

=INDEX(SPLIT(A1,","),2)

Trường hợp 2là chỉ số bạn muốn.

Trong Excel:

=TRIM(MID(SUBSTITUTE(A1,",",REPT(" ",999)),(2-1)*999+1,999))

Hoặc công thức mảng này:

=INDEX(TRIM(MID(SUBSTITUTE(A1,",",REPT(" ",999)),(ROW(INDIRECT("1:" & LEN(A1)-LEN(SUBSTITUTE(A1,",",""))+1))-1)*999+1,999)),2)

Là một công thức mảng, nó cần được xác nhận bằng Ctrl-Shift-Enter Thay vì Enter khi thoát khỏi chế độ chỉnh sửa. Nếu thực hiện đúng thì excel sẽ đặt {}xung quanh công thức.

Một lần nữa thay thế 2với chỉ số mong muốn.

— Scott Craner
nguồn

Lý do đằng sau việc sử dụng là REPTgì? và 999đây?

— Cướp

1

Nó đang cho tôi một mục tiêu lớn để đánh. 999 không gian mà các trim sau đó loại bỏ.

— Scott Craner

5

4,8,2

Công thức cho mỗi số.

=LEFT(A1, SEARCH(",",A1,1)-1)
=MID(A1, SEARCH(",",A1) + 1, SEARCH(",",A1,SEARCH(",",A1)+1) - SEARCH(",",A1) - 1)
=RIGHT(A1,LEN(A1) - SEARCH(",", A1, SEARCH(",", A1) + 1))

Nguồn: https://www.ablebits.com/office-addins-blog/2016/06/01/split-text-opes-excel/

Lưu ý: Điều này sẽ chỉ hoạt động cho ba số được phân cách bằng dấu phẩy.

— Steven
nguồn

3

Bạn có thể sử dụng Mid trong Excel, công thức sau sẽ tìm "đầu tiên", "thứ hai", "để trích xuất giá trị giữa nó:
=MID(A1,FIND(",",A1,1)+1,FIND(",",SUBSTITUTE(A1,","," ",1),1)-1-FIND(",",A1,1))
bất kể giá trị nào là một hoặc nhiều chữ số

— yass
nguồn