Excel ngăn ô và nội dung của nó bị xóa (không bảo vệ trang tính)

Tôi có 2 cột trong bảng excel mà tôi muốn bảo vệ theo cách bạn không thể xóa ô cũng như nội dung của nó. Tôi không muốn sử dụng bảo vệ trang tính tích hợp, thay vào đó tôi muốn sử dụng VBA (vì không cần mật khẩu). Tôi đã tìm thấy một số mã sẽ ngăn các ô bị xóa, nhưng nó không hoạt động. Ngoài ra tôi không biết VBA hoạt động như thế nào và do đó tôi sẽ rất vui nếu ai đó có thể cung cấp giải pháp hoặc hướng dẫn tôi cách tự làm.

Mã tôi tìm thấy là đây:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("A6:B1048576")) Is Nothing Then Exit Sub
    On Error GoTo ExitPoint
    Application.EnableEvents = False
    If Not IsDate(Target(1)) Then
        Application.Undo
    End If
ExitPoint:
    Application.EnableEvents = True
End Sub

Điều này tương tự như mã trong câu hỏi của bạn, nhưng ngăn bất kỳ ô nào trong các cột A: B bị xóa / đặt thành trống:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim c As Range
    Dim b As Boolean

    On Error GoTo Terminate

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    For Each c In Target.Cells
        If Not Intersect(c, Range("A:B")) Is Nothing And c.Value = "" Then
            b = True
            GoTo UndoChange
        End If
    Next c

UndoChange:
    If b Then Application.Undo

Terminate:
    If Err Then
        Debug.Print "Error", Err.Number, Err.Description
        Err.Clear
    End If

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Nó hoạt động với nhiều lựa chọn ô, vì nó lặp qua từng ô trong phạm vi đã thay đổi và kiểm tra giá trị trống.

EDIT: Mã sửa đổi, để tích hợp Worksheet_Changechức năng hiện có của bạn ;

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim c As Range
    Dim b As Boolean

    On Error GoTo Terminate

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    For Each c In Target.Cells
        If Not Intersect(c, Range("A:B")) Is Nothing And c.Value = "" Then
            b = True
            GoTo UndoChange
        End If
        If c.Column = 10 And c.Row >= 6 Then
            c.Value = UCase(c.Value)
        End If
    Next c

UndoChange:
    If b Then Application.Undo

Terminate:
    If Err Then
        Debug.Print "Error", Err.Number, Err.Description
        Err.Clear
    End If

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub