Nghe sự kiện tắt màn hình và tắt chuột trong Windows

Tôi muốn ngăn chuột đánh thức màn hình của mình (trong khi PC của tôi đang bật nhưng màn hình tắt hoặc trình bảo vệ màn hình đang bật).

Tôi đã đọc tất cả các tài nguyên cho tôi biết chính xác "không thể thực hiện được", ví dụ như câu hỏi này . Hoặc những người nói rút phích cắm chuột của bạn, hoặc lật ngược chuột xuống hoặc ngăn chuột đánh thức PC khỏi giấc ngủ. - Không quan tâm đến những cái đó.

Tôi muốn ai đó giúp tôi tìm ra giải pháp này:

• cách chặn màn hình tắt sự kiện hoặc trình bảo vệ màn hình khi có sự kiện.
• nếu không, thì ít nhất là chặn một lệnh tắt màn hình rõ ràng mà tôi gửi bằng cách chạy tệp Monitor Offer.bat hoặc lệnh nircmd hoặc lệnh AHK AutoHotkey.
• sau đó chạy một tập lệnh vô hiệu hóa ngay lập tức chuột / chuột / không phải bàn phím của tôi.
• sau đó, nếu màn hình bị đánh thức trở lại hoặc nếu đóng trình bảo vệ màn hình hoặc ít nhất là nếu có bất kỳ phím bàn phím nào được nhấn, thì hãy bật lại chuột.

Chúc mừng.

[CHỈNH SỬA]

Chúng tôi có một giải pháp tuyệt vời với AHK bởi user3419297. Lý tưởng nhất là chức năng cũng sẽ hoạt động nếu / trong khi windows bị khóa (không đăng xuất, nhưng bị khóa).

Có thể bằng cách nào đó sử dụng các phím dính như DaaBoss nói hoặc các phần khác của khả năng truy cập cửa sổ.

Hãy thử tập lệnh AHK này:

$F1 Up::  ; or whatever combination you want
    Keyboard_Blocked := true   ; assign the Boolean value "true" or "1" to this variable
    BlockInput On   ; disable keyboard and mouse
    SendMessage, 0x112, 0xF170, 2,, Program Manager ; turn the monitor off, similar to power saving mode
    ; or:
    ; Run path of your screensaver 
return


; The #If directive creates context-sensitive hotkeys:

#If (Keyboard_Blocked) ; If this variable has the value "true" 

    $F1 Up::  ; press F1 to re-enable keyboard and mouse and turn the monitor on
        BlockInput Off
        Keyboard_Blocked := false
    return

#If ; turn off context sensitivity

CHỈNH SỬA:

Thay vì định cấu hình trong các tùy chọn nguồn thời gian không hoạt động sau đó màn hình tắt hoặc nhấn Win + L để khóa hệ thống, bạn có thể thực hiện bằng cách sử dụng tập lệnh AHK chạy vĩnh viễn. Trong kịch bản này, bạn có thể thêm nhiều nội dung (phím nóng, hotstrings, chức năng, v.v.) để tạo thuận lợi cho công việc của bạn.

#NoEnv
#SingleInstance Force
SetTimer, DetectTimeIdle, 50
return

DetectTimeIdle:
; lock the computer automatically after 20 seconds of inactivity.
; Replace 20000 with 60000 for 1 minute etc.
If (A_TimeIdle > 20000) ; as long as there is no input within the last 20 seconds
    GoSub !F1 Up ; jump to this hotkey definition
return


; Press Alt+F1 to manually lock the computer
!F1 Up::
    Keyboard_Blocked := true   ; assign the Boolean value "true" or "1" to this variable
    BlockInput On   ; disable keyboard and mouse
    SendMessage, 0x112, 0xF170, 2,, Program Manager ; turn the monitor off, similar to power saving mode
return


#If (Keyboard_Blocked) 

    ; press F1 or F2 or Space ... to re-enable keyboard and mouse and turn the monitor on
    $F1 Up:: 
    $F2 Up::
    $Space Up::
    ; ...
        BlockInput Off
        Keyboard_Blocked := false
        ; Move the mouse  (speed 10) by 20 pixels to the right and 30 pixels down from its current location to unlock the computer:
        MouseMove, 20, 30, 10, R
        reload
    return

#If