Công thức định dạng giá trị phút thành giờ N, chuỗi phút M

Tôi đang đề cập đến câu hỏi này tương ứng với câu trả lời được chỉnh sửa này . Có một cột với khoảng thời gian tính bằng phút. Khoảng thời gian ba giờ và hai phút sẽ là 182. Làm thế nào để định dạng có điều kiện các ô bằng cách sử dụng một công thức để có được kết quả sau đây?

0 → 0 minutes

1 → 1 minute

2 → 2 minutes

60 → 1 hour

120 → 2 hours

181 → 3 hours, 1 minute

63 → 1 hour, 3 minutes

Tôi có cần thực hiện một số phép chia (làm tròn) và một số phép tính modulo không? Hoặc có một chức năng tích hợp cho những thứ như vậy?

=IF(A1=0,"0 minutes",IF(A1>=60,FLOOR(A1/60,1) & " hour" & IF(A1>=120,"s",""),"") & IF(MOD(A1,60)>0,IF(A1>=60,", ","") & MOD(A1,60) & " minute" & IF(MOD(A1,60)>1,"s",""),""))

Theo các nhận xét bạn đang sử dụng Excel của Đức, sử dụng dấu chấm phẩy để phân tách các tham số chức năng, vì vậy hãy thay thế dấu phẩy bằng dấu chấm phẩy:

=IF(A1=0;"0 minutes";IF(A1>=60;FLOOR(A1/60;1) & " hour" & IF(A1>=120;"s";"");"") & IF(MOD(A1;60)>0;IF(A1>=60;", ";"") & MOD(A1;60) & " minute" & IF(MOD(A1;60)>1;"s";"");""))

(Lưu ý: vẫn còn một dấu phẩy trong đó vì đó là trong chuỗi đầu ra.)

0      0 minutes
1      1 minute
2      2 minutes
59     59 minutes
60     1 hour
61     1 hour, 1 minute
62     1 hour, 2 minutes
119    1 hour, 59 minutes
120    2 hours
121    2 hours, 1 minute
122    2 hours, 2 minutes
179    2 hours, 59 minutes
180    3 hours
181    3 hours, 1 minute
182    3 hours, 2 minutes
1439   23 hours, 59 minutes
1440   24 hours

Giả sử dữ liệu của bạn nằm trong cột A. Viết công thức này vào C2 và điền nó xuống để dịch phút sang ngày phân số (đó là cách Excel lưu trữ thời gian):

=A2/1440

Lưu ý , như bạn có thể tìm thấy ở trên trong các bình luận, rằng để chuyển đổi số thập phân thành định dạng thời gian, bạn có thể áp dụng công thức 24*60này mang lại 1440.

Với số phút được chuyển đổi thành biểu mẫu trong đó Excel xử lý thời gian, bạn chỉ cần sử dụng định dạng thời gian tùy chỉnh để hiển thị nó. Chọn phạm vi dữ liệu và áp dụng định dạng ô này:

h "hours, " m "minutes"

Lưu ý rằng Excel sẽ coi thời gian là giờ chỉ trong phạm vi mà chúng ít hơn cả ngày, vì vậy điều này sẽ hoạt động miễn là thời gian của bạn không quá 24 giờ.

Hoặc, bạn có thể sử dụng các hàm HOUR và MINUTE để trích xuất các thành phần của thời gian. Trong D2 bạn có thể sử dụng:

=HOUR(C2)&" hours, "&MINUTE(C2)&" minutes "

Bạn lấy,

Một lần nữa, điều này được giới hạn trong phần thời gian của bạn ít hơn một ngày. Nếu bạn có thể có nhiều lần hơn một ngày, hãy thêm số ngày:

=INT(C2)&" days, "&HOUR(C2)&" hours, "&MINUTE(C2)&" minutes "

Bây giờ bạn nhận được,