Excel nói quá nhiều đối số cho hàm IF / AND / MONTH

Tôi cần nó để sản xuất các đơn đặt hàng ở Canada hoặc Mexico, trên 1.000 đô la và trong tháng bảy. Công thức tôi đang cố gắng sử dụng là:

=IF(OR(A2="Canada","Mexico", IF(C2>1000, "Ship by Air", IF(MONTH(B2=7, "Ship by Air", "Ship by Ground")))

Tôi không biết làm thế nào khác để viết nó với tất cả các thông tin đó.

OR cần mỗi phần là biểu thức Boolean của riêng nó:

OR(A2="Canada","Mexico"

Nên là:

OR(A2="Canada",A2="Mexico")

HOẶC LÀ

OR(A2={"Canada","Mexico"})

Và

MONTH(B2

đang thiếu )

Vì thế:

=IF(OR(A2={"Canada","Mexico"}), IF(C2>1000, "Ship by Air", IF(MONTH(B2)=7, "Ship by Air", "Ship by Ground")))

Ngoài ra, bạn đang thiếu FALSE ở IF bên ngoài, có thể là những gì bạn muốn, nhưng tôi có xu hướng thêm nó để công thức của tôi dễ đọc hơn:

=IF(OR(A2={"Canada","Mexico"}), IF(C2>1000, "Ship by Air", IF(MONTH(B2)=7, "Ship by Air", "Ship by Ground")),FALSE)

Nhưng chúng ta có thể kết hợp cả hai bên trong vì đầu ra giống nhau trên đúng:

=IF(OR(A2={"Canada","Mexico"}), IF(OR(C2>1000, MONTH(B2)=7), "Ship by Air", "Ship by Ground"),FALSE)

Chỉnh sửa: điều này sẽ trở lại Ship by Airnếu bất kỳ điều nào sau đây là TRUE:

• A2 bằng "Canada" hoặc "Mexico"
• C2> 1000
• Tháng B2 là tháng 7

:

=IF(OR(A2={"Canada","Mexico"},C2>1000, MONTH(B2)=7), "Ship by Air", "Ship by Ground")

Edit2: điều này sẽ trở lại Ship by Airnếu Tất cả những điều sau đây là TRUE:

• A2 bằng "Canada" hoặc "Mexico"
• C2> 1000
• Tháng B2 là tháng 7

:

=IF(AND(OR(A2={"Canada","Mexico"}),C2>1000, MONTH(B2)=7), "Ship by Air", "Ship by Ground")

Bạn đã có một khởi đầu tốt; công thức của bạn là "mã giả" cho những gì bạn muốn thực hiện. Bạn chỉ cần cấu trúc nó cho Excel.

Vấn đề đầu tiên là các yếu tố được sử dụng bởi các hàm cần được đặt trong dấu ngoặc đơn để Excel biết chúng bắt đầu và kết thúc ở đâu. HOẶC đầu tiên của bạn không có dấu ngoặc đơn chặt chẽ; tương tự với hàm MONTH.

Vấn đề thứ hai là OR cần có sự lựa chọn các điều kiện hoàn chỉnh. Excel không xử lý các so sánh với một danh sách, ít nhất là ở định dạng không phải là mảng như bạn đang sử dụng.

Ngoài ra, IF đầu tiên không chứa kết quả cho những gì sẽ hiển thị nếu OR sai, vì vậy bạn có thể muốn thêm điều đó.

Vì vậy, công thức nên như:

=IF(OR(A2="Canada",A2="Mexico"), IF(C2>1000, "Ship by Air", IF(MONTH(B2)=7, "Ship by Air", "Ship by Ground")),"Not Canada or Mexico")

Đếm các dấu ngoặc: Bạn có năm dấu ngoặc mở và ba dấu ngoặc đóng. Nhưng số lượng phải phù hợp.

Bạn có thể thấy vấn đề với thụt lề chính xác của biểu thức:

=IF(
    OR(
       A2="Canada","Mexico", 
       IF(
          C2>1000, "Ship by Air", 
          IF(
             MONTH(
                   B2=7, "Ship by Air", "Ship by Ground"
             )
          )
       )
// ---------------- Here your expression ends
    )    // missing
)        // missing

Tôi đã đánh dấu hai dấu ngoặc đóng thiếu. Những biểu thức bạn muốn đóng )phụ thuộc vào logic bạn muốn thực hiện.