Excel - Xóa từ cụ thể trong mỗi hàng?

3

Có cách nào để Excel xóa một từ riêng biệt trong mỗi hàng không? Ví dụ: mỗi hàng nói Ông bà {tên đầu tiên {{họ} và tôi muốn xóa {tên đầu tiên} khỏi mỗi tên. (Hoặc cách khác, bằng cách trích xuất ba từ đầu tiên và từ cuối cùng, sau đó kết hợp chúng.)

Cảm ơn!

microsoft-excel worksheet-function

— Dave
nguồn

2

Đây là giải pháp của tôi. Mà sử dụng một phần điều này .

=LEFT(A6,FIND(" ",A6,FIND(" ",A6,FIND(" ",A6)+1)+1))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

Điều này giữ 3 từ đầu tiên và từ cuối cùng và không cần phải giả sử ba từ đầu tiên là "Ông bà". Nếu bạn cho rằng bạn có thể sử dụng phiên bản ngắn hơn:

="Mr. and Mrs. "&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

Chỉnh sửa : sử dụng công thức hàng đầu của tôi và công thức này (chỉ đưa ra từ đầu tiên và từ cuối cùng):

=LEFT(A6,FIND(" ",A6))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

Chúng ta có thể kết hợp những thứ đó với một câu lệnh if ... Tôi không chắc câu lệnh if nào là tốt nhất, nhưng hãy để tôi chỉ cho bạn thấy một cái sẽ trông như thế nào khi chúng ta đếm số "." trong tuyên bố. Nếu là 2 hoặc lớn hơn, hãy sử dụng 3 từ đầu tiên và cuối cùng, nếu không chỉ là từ đầu tiên và cuối cùng.

IF(LEN(A6)-LEN(SUBSTITUTE(A6,".",""))>=2,LEFT(A6,FIND(" ",A6,FIND(" ",A6,FIND(" ",A6)+1)+1))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ",""))))),LEFT(A6,FIND(" ",A6))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ",""))))))

Chỉnh sửa2: Nếu bạn muốn sử dụng giải pháp -và của mình, bạn có thể sử dụng công thức này:

=LEFT(A6,FIND(" ",SUBSTITUTE(A6," and ","-and-")))&RIGHT(A6,LEN(A6)-FIND("@",SUBSTITUTE(A6," ","@",LEN(A6)-LEN(SUBSTITUTE(A6," ","")))))

— Jarvin
nguồn

Ồ điều đó thật tuyệt. Tôi đã tự hỏi làm thế nào để đối phó với các trường hợp chỉ có một tiêu đề (ví dụ: chỉ "Bà"). Suy nghĩ của tôi là tạm thời thay thế "và" bằng "-và", để tất cả các tiêu đề được coi là một từ duy nhất; sau đó giữ lời đầu tiên và cuối cùng; và cuối cùng, chuyển "-và-" trở lại "và". Có lẽ có một cách để kết hợp điều này vào công thức, nhưng tôi thậm chí không biết bắt đầu từ đâu. Cảm ơn!

— Dave

Giải pháp cuối cùng của bạn là chính xác những gì tôi cần. Cảm ơn một lần nữa!

— Dave

2

Đây là công thức để tìm từ thứ ba, nhưng nó là một từ dài:

=MID(MID(MID(SUBSTITUTE(A1," ","^",3),1,256),FIND("^",SUBSTITUTE(A1," ","^",3)),256),2,FIND(" ",MID(MID(SUBSTITUTE(A1," ","^",3),1,256),FIND("^",SUBSTITUTE(A1," ","^",3)),256))-2)

liên kết tham khảo đây .

Bây giờ, đặt cái này vào một cột, nhấp và kéo, sau đó tạo cột thứ hai loại bỏ từ này.

Trên thực tế, trong trường hợp cụ thể của bạn, bạn chỉ có thể sử dụng công thức này, trong ví dụ này, A1 có chuỗi và C1 là công thức ở trên:

=LEFT(A1, 13) & RIGHT(A1,LEN(A1) - (13 + LEN(C1)))

Và, tất nhiên, bạn có thể thay thế toàn bộ công thức đầu tiên cho C1, để có được tất cả trong một công thức.

— Lance Roberts
nguồn

Điều này giả sử 3 từ đầu tiên là 13 ký tự.

— Jarvin

@Dan, vâng, đó là lý do tại sao tôi nói in your specific case.

— Lance Roberts

1

tất cả các giải pháp trên là tuyệt vời; tuy nhiên, một cách hay để làm điều này (Giả sử ông John Smith ở trong một cột) là làm tools to columns từ Data thực đơn và sử dụng space như một dấu phân cách

— dassouki
nguồn

Tuyệt quá! Ngoài ra, bạn có thể sử dụng một hàm để lấy chuỗi sau ký tự khoảng trắng đầu tiên.

— kokbira

0

Ctrl + F, chọn thay thế, đặt "Mr." (đừng quên ký tự khoảng trắng) và thay thế bằng phải trống. Sau đó thay thế tất cả.
Ctrl + F, chọn thay thế, đặt "Bà" (đừng quên ký tự khoảng trắng) và thay thế bằng phải trống. Sau đó thay thế tất cả.

Giải pháp đó rất nhanh đối với một vài từ để thay thế, nhưng chỉ được sử dụng với những từ không có trong tên (ví dụ như "James Amr. Kohn"; trong trường hợp này, tùy chọn "phân biệt chữ hoa chữ thường" giải quyết nó).

— kokbira
nguồn

0

Tôi sẽ sử dụng Ctr + F và sử dụng công cụ thay thế, chỉ cần nhập từ bạn muốn xóa sau đó nhấp vào thay thế - điều này sẽ thay thế từ bạn đã chọn không có gì!

— Kieran
nguồn