Tổng nếu CHỈ tất cả các ô có giá trị?

1

Tôi cần tổng hợp 9 ô dữ liệu, mỗi ô trên một trang riêng, nhưng luôn ở cùng một vị trí. Tôi chỉ muốn một hình được trả về khi tất cả các ô có dữ liệu, ngay cả khi đó là 0. Nhưng, nếu một trong các ô trống, tôi muốn trả về trống.

Tôi đang cố gắng để có được đầu óc của mình, thực sự làm cho nó trở thành, nơi IF và ISBLANK và SUMS sẽ đi. Bât cư thông tin được cung câp nao cung được la sự suât hiện tuyệt vơi.

SUM(IF(ISBLANK(RANGEA,OR(RANGEB),0,ALLRANGES)))

Cảm ơn nhiều

Michael

microsoft-excel microsoft-excel-2007 worksheet-function

— Tên lửa
nguồn

6

Giả sử dữ liệu nằm trong A1 đến A9:

=IF(COUNTA(A1,A2,A3,A4,A5,A6,A7,A8,A9)<9,"",SUM(A1,A2,A3,A4,A5,A6,A7,A8,A9))

Và vâng, điều này sẽ hoạt động cho các ô trên các trang tính khác nhau, thậm chí các tệp, chỉ cần thay đổi tham chiếu, đảm bảo bạn thay đổi nó trong cả hai phần của công thức.

— Thủy
nguồn

Không có thanh cuộn ngang: đẹp! ;-)

— Arjan

Đã thử nó và nó hoạt động - tắt để đưa nó vào thử nghiệm thực sự bây giờ mặc dù. Công dụng tuyệt vời của COUNTA (Tôi sử dụng nó mọi lúc nhưng không bao giờ nghĩ về nó như thế!). Chúc mừng.

— RocketGoal

Gợi ý thêm: COUNTA()sẽ đếm các ô có số hoặc văn bản, COUNT()sẽ chỉ đếm các ô có số.

— Bavi_H

2

Để bổ sung cho câu trả lời của nnewton ở trên, bạn có thể định dạng lại =IF(COUNTA(A1:A9)<9,"",SUM(A1:A9))với cùng kết quả

— Diễm
nguồn

Ngoại trừ việc mỗi ô nằm trên một tờ riêng biệt ...

— mellamokb

1

Tuy nhiên, bạn có thể sử dụng COUNTA với tham chiếu "3d" (để áp dụng trên một phạm vi trang tính), vì vậy, giả sử ô B3 trên trang 1 đến 9, bạn có thể sử dụng phiên bản công thức được đề xuất này của Diễm=IF(COUNTA(Sheet1:Sheet9!B3)<9,"",SUM(Sheet1:Sheet9!B3))

— barry houdini vào

1

Các IFchức năng làm việc như thế này:

IF(TEST, DO_IF_TRUE, DO_IF_FALSE)

Thật không may, ISBLANKhàm chỉ hoạt động cho một ô, vì vậy bạn phải lồng các câu lệnh IF như thế này:

=IF( ISBLANK(CELL1) , " " , IF( ISBLANK(CELL2), " ", IF( ISBLANK(CELL3), " ", SUM(RANGE) ) ) )

Điều đó sẽ kiểm tra nếu ô đầu tiên trống. Nếu vậy nó sẽ in một khoảng trống. Nếu không, nó sẽ kiểm tra xem ô thứ hai có trống không, in một khoảng trống nếu có và tiếp tục kiểm tra nếu không. Cuối cùng, nó in SUMnếu tất cả đều trống.

Vì vậy, với 9 ô, nó sẽ trông như thế này:

=IF(ISBLANK(A1),"",IF(ISBLANK(A2),"",IF(ISBLANK(A3),"",IF(ISBLANK(A4),"",IF(ISBLANK(A5),"",IF(ISBLANK(A6),"",IF(ISBLANK(A7),"",IF(ISBLANK(A8),"",IF(ISBLANK(A9),"",SUM(A1:A9))))))))))

— Bản vá lỗi
nguồn

Nó cho tôi biết tôi đã nhập vào nhiều đối số (tổng cộng 9 If) cho hàm này.

— RocketGoal

Tôi chỉ thử nghiệm điều này với 9 ô và nó hoạt động tốt. "Quá nhiều đối số" biểu thị bạn có dấu phẩy hoặc dấu ngoặc đơn ở đâu đó. Tôi sẽ thêm một ví dụ kiểm tra 9 ô để làm cho nó dễ dàng hơn một chút.

— Bản vá lỗi

7 ifs lồng nhau là giới hạn

— datatoo

Đây có thể là một điểm cần thiết cho các câu trả lời khác ở đây nhưng 7 hàm lồng nhau là giới hạn trong Excel 2003 - trong Excel 2007 và sau đó bạn có thể sử dụng tối đa 64

— barry houdini

0

Bạn cũng có thể làm điều đó bằng cách sử dụng này:

=IF(OR(ISBLANK(A1),ISBLANK(A2),ISBLANK(A3),ISBLANK(A4),ISBLANK(A5),ISBLANK(A6),ISBLANK(A7),ISBLANK(A8),ISBLANK(A9)),"",SUM(A1:A9))

— Craig
nguồn

0

Sử dụng một công thức mảng {sum(a1:a10)*1}. (Sử dụng Ctrl+ Shift+ Enterđể có được niềng răng bên ngoài.)

— Pete
nguồn