Làm cách nào tôi có thể buộc thông báo Growl của bản nhạc iTunes hiện đang phát?

Tôi muốn một phím nóng để nói (hỏi một cách lịch sự) Growl để đưa ra thông báo về những gì hiện đang phát trong iTunes.

Tôi đã chọc ngoáy một chút nhưng không thể tìm thấy câu trả lời "ngoài kia".

Có suy nghĩ gì không?

Nếu bạn thích định dạng mà GrowlTunes cung cấp, bạn cũng có thể tạo tập lệnh sử dụng nó:

tell application "GrowlTunes" to show current track

Applescript bị hack của tôi được đăng dưới đây. Điều này phù hợp với đầu ra Growl của iScrobbler. Cảm ơn các xúc tu cho công việc! Có thông tin về cách đặt Quicksilver để khởi chạy tập lệnh tại đây .

tell application "GrowlHelperApp"
-- Make a list of all the notification types
-- that this script will ever send:
set the allNotificationsList to {"iTunes Playing Track"}
-- Make a list of the notifications
-- that will be enabled by default.
-- Those not enabled by default can be enabled later
-- in the 'Applications' tab of the growl prefpane.
set the enabledNotificationsList to {"iTunes Playing Track"}
-- Register our script with growl.
-- You can optionally (as here) set a default icon
-- for this scripts notifications.
register as application "Growl iTunes Notification" all notifications allNotificationsList default notifications enabledNotificationsList icon of application "iTunes"

set title_text to "Null"
set body_text to ""
set body_temp to ""
set has_artwork to false

tell application "iTunes"
    if player state is playing then
        set trck to current track

        if artworks of trck is not {} then
            get artwork 1 of trck
            set pic to data of result
            set has_artwork to true
        end if

        set title_text to "Now Playing"

        get name of trck
        set body_text to "Track: " & result

        get rating of trck
        set rate to result / 20

        repeat rate times
            set body_temp to body_temp & "★"
        end repeat

        if rate is less than 5 then
            repeat (5 - rate) times
                set body_temp to body_temp & "☆"
            end repeat
        end if

        set body_text to body_text & " (" & body_temp & ")" & return

        get album of trck
        set body_text to body_text & "Album: " & result & return

        get artist of trck
        set body_text to body_text & "Artist: " & result

    end if
end tell

if has_artwork then
    notify with name "iTunes Playing Track" title title_text description body_text application name "Growl iTunes Notification" pictImage the pic
else
    notify with name "iTunes Playing Track" title title_text description body_text application name "Growl iTunes Notification" image from location "file:///Users/drewbeck/Library/Scripts/Custom/no_album.tiff"
end if 

kết thúc

Bạn cần một plugin cho iTunes. Nó đây rồi

Bạn có thể sử dụng một applescript cho điều này (đừng nhớ tôi đã lấy cái này ở đâu) - Tôi biên dịch nó cho một ứng dụng được kích hoạt bởi Quicksilver, để nhận thông báo ngay lập tức về những gì đang phát khi tôi muốn, giữ cho iTunes luôn được giảm thiểu mọi lúc:

 tell application "GrowlHelperApp"
    -- Make a list of all the notification types
    -- that this script will ever send:
    set the allNotificationsList to {"iTunes Playing Track"}
    -- Make a list of the notifications
    -- that will be enabled by default.
    -- Those not enabled by default can be enabled later
    -- in the 'Applications' tab of the growl prefpane.
    set the enabledNotificationsList to {"iTunes Playing Track"}
    -- Register our script with growl.
    -- You can optionally (as here) set a default icon
    -- for this scripts notifications.
    register as application "Growl iTunes Notification" all notifications allNotificationsList default notifications enabledNotificationsList icon of application "iTunes"

    set title_text to "Nothing playing"
    set body_text to ""
    set has_artwork to false

    tell application "iTunes"
        if player state is playing then
            set trck to current track

            if artworks of trck is not {} then
                get artwork 1 of trck
                set pic to data of result
                set has_artwork to true
            end if

            get name of trck
            set title_text to result

            get time of trck
            set title_time to result
            set body_text to title_time & " =["

            get rating of trck
            set rate to result / 20

            repeat rate times
                set body_text to body_text & " ❤ "

            end repeat

            get artist of trck
            set body_text to body_text & "]   ❧ " & result

            get album of trck
            set body_text to body_text & " ⇒ " & result

        end if
    end tell

    if has_artwork then
        notify with name "iTunes Playing Track" title title_text description body_text application name "Growl iTunes Notification" pictImage the pic
    else
        notify with name "iTunes Playing Track" title title_text description body_text application name "Growl iTunes Notification"
        "iTunesLibraryPlaylistIcon.icns"
    end if

end tell