TextWrangler: phím nóng để di chuyển lên / xuống

Trong Eclipse, bạn có thể nhấn ALT- (mũi tên) để di chuyển một dòng lên hoặc xuống.

Có ai phát hiện ra các tính năng phím nóng này trong TextWrangler chưa?

Đối với Mac OS X, nó là ctrl+ ↑hoặc ctrl+ ↓.

Bạn có thể cần thay đổi cài đặt phím nóng Mission Control (trong Tùy chọn hệ thống) vì hai nét bàn phím được đặt sẵn ở đó.

Không có gì được đề cập trong hướng dẫn (chỉ trao đổi ký tự và từ Exchange ).

Nếu TextWrangler hỗ trợ Hệ thống văn bản ca cao (mà tôi nghi ngờ là không, nhưng vẫn vậy), bạn có thể tạo tệp ~/Library/Keybindings/DefaultKeyBinding.dictvà nhập thông tin sau:

{
    "~\UF701" = (
        "moveToBeginningOfLine:",
        "deleteToEndOfLine:",
        "deleteForward:",
        "moveDown:",
        "yank:",
        "insertNewline:",
        "moveUp:"
    );
}

Điều này sẽ thêm lối tắt Opt-DownArrowcho lệnh hoán đổi dòng (với dòng bên dưới) cho mọi ứng dụng hỗ trợ hệ thống văn bản Ca cao.

Tôi không nghĩ TextWrangler có tính năng này.

Bạn có thể chạy applescripts trong TextWrangler, vì vậy bạn có thể thực hiện công việc này. Tôi thậm chí đã tìm thấy một số applescripts sẽ làm điều này.

Bạn sẽ cần thay thế BBEdit bằng TextWrangler trong các applescripts. Đặt các tập lệnh vào "~ / Thư viện / Hỗ trợ ứng dụng / TextWrangler / Sc scripts /" và chúng sẽ hiển thị trên menu tập lệnh trong TextWrangler. Nhấp vào Cửa sổ -> Bảng màu -> Tập lệnh để xem bảng tập lệnh, nơi bạn có thể đặt các phím tắt tùy chỉnh.

giải pháp nathangs hoạt động khá tốt. Nhưng liên kết được cung cấp không hoạt động nữa. Vì vậy, đây là các kịch bản như văn bản đơn giản. Chỉ cần dán chúng vào "Trình soạn thảo AppleScript" và lưu chúng vào ~ / Thư viện / Hỗ trợ ứng dụng / TextWrangler / Sc scripts /

Hoạt động tốt trên Mountain Lion và với TextWrangler 4.

MoveLineDown.scpt:

tell application "TextWrangler"
    set x to startLine of selection
    tell text 1 of window 1
        if x = (count of lines) then return
        set myline to contents of line x
        delete line x
        if length of line x = 0 then
            make line at line x with data "
"
            make line at line (x + 1) with data myline
        else
            make line at line x with data myline

        end if
        select insertion point before line (x + 1)
    end tell
end tell

MoveLineUp.scpt:

tell application "TextWrangler"
    set x to startLine of selection
    if x = 1 then
        beep
        return
    end if
    tell text 1 of window 1
        set oldCount to count of lines
        set myline to contents of line x
        delete line x
        if x = 2 then
            if length of line 1 = 0 then
                make line at beginning with data "
"
            end if
            make line at beginning with data myline
        else
            if length of line (x - 2) = 0 then
                make line at line (x - 2) with data "
"
                make line at line (x - 1) with data myline
            else
                make line at line (x - 2) with data myline
            end if
        end if
        select insertion point before line (x - 1)
    end tell
end tell