Mặc dù tôi cố gắng tránh nó, thỉnh thoảng tôi phải mở tệp CSV trong Excel. Khi tôi làm, nó định dạng các cột chứa số, làm cho chúng vô dụng cho mục đích của tôi. Theo như tôi có thể nói, cách duy nhất để ngăn điều này xảy ra khi nhập là đổi tên tệp để phần mở rộng không phải là .csv và sử dụng trình hướng dẫn nhập để chỉ định định dạng của từng cột. Đối với các tệp có 50-60 cột, điều này là không thực tế.

Vì mọi câu trả lời cho câu hỏi thường gặp này trên internet đều gợi ý một số phương tiện chuyển đổi các số được định dạng trở lại sau khi tệp được mở (điều này sẽ không hiệu quả với tôi - tôi muốn giải quyết vấn đề chung, không phải một vài trường hợp cụ thể) hoặc chọn thủ công loại định dạng của từng cột (mà tôi không muốn làm), tôi đang tìm cách đặt tùy chọn hoặc kiểu toàn cầu sao cho tất cả các cột của tất cả các tệp CSV được mở luôn được định dạng dưới dạng văn bản. Tôi cũng biết về việc "bọc thép" các số có dấu ngoặc kép, nhưng các tệp tôi nhận được không giống như vậy và tôi hy vọng sẽ không phải xử lý trước các tệp để Excel không làm hỏng chúng.

Có cách nào để thực hiện việc này một cách cụ thể : Luôn định dạng tất cả các cột trong tệp CSV đã mở dưới dạng văn bản mà không chọn thủ công từng cột mỗi lần trong khi nhập?

Tôi đang sử dụng Excel 2003, nhưng tôi sẽ trả lời cho năm 2007 nếu đó là những gì bạn biết.

Những công việc này:

Sub OpenCsvAsText(ByVal strFilepath As String)

    Dim intFileNo As Integer
    Dim iCol As Long
    Dim nCol As Long
    Dim strLine As String
    Dim varColumnFormat As Variant
    Dim varTemp As Variant

    '// Read first line of file to figure out how many columns there are
    intFileNo = FreeFile()
    Open strFilepath For Input As #intFileNo
    Line Input #intFileNo, strLine
    Close #intFileNo
    varTemp = Split(strLine, ",")
    nCol = UBound(varTemp) + 1

    '// Prepare description of column format
    ReDim varColumnFormat(0 To nCol - 1)
    For iCol = 1 To nCol
        varColumnFormat(iCol - 1) = Array(iCol, xlTextFormat)
        ' What's this? See VBA help for OpenText method (FieldInfo argument).
    Next iCol

    '// Open the file using the specified column formats
    Workbooks.OpenText _
            Filename:=strFilepath, _
            DataType:=xlDelimited, _
            ConsecutiveDelimiter:=False, Comma:=True, _
            FieldInfo:=varColumnFormat

End Sub

Sử dụng:

OpenCsvAsText "C:\MyDir\MyFile.txt"

Tệp được phân tách bằng dấu phẩy hiện đang mở dưới dạng bảng Excel với tất cả các cột được định dạng dưới dạng văn bản.

Lưu ý rằng giải pháp thuật sĩ của @ Wetiwi chỉ hoạt động tốt, nhưng nếu bạn đang mở nhiều tệp thì bạn có thể, như tôi, trở nên mệt mỏi, mỗi lần, cuộn đến cột 60 để Shift-Click vào nó.

EDIT @GSerg nêu trong nhận xét bên dưới rằng "không hoạt động" và "ăn không gian và số 0 hàng đầu". Tôi sẽ chỉ trích dẫn nhận xét cho câu hỏi, mô tả nhiều hơn:

Vì những lý do không rõ, ngay cả khi bạn cung cấp rõ ràng các định dạng cho tất cả các cột trong VBA, Excel sẽ bỏ qua nó nếu phần mở rộng tệp là CSV. Ngay khi bạn thay đổi tiện ích mở rộng, cùng mã đó sẽ mang lại kết quả chính xác.

Vì vậy, đoạn mã trên "hoạt động", nhưng bị giết bởi hành vi vô lý này của Excel. Dù bạn cắt nó theo cách nào, bạn vẫn bị mắc kẹt khi phải thay đổi tiện ích mở rộng thành một thứ khác ngoài ".csv", xin lỗi! Sau đó, bạn về nhà miễn phí.

Cách mở CSV trong Excel

Cách tốt

• Excel → Dữ liệu → Nhận dữ liệu ngoài → Chọn tất cả các cột Shiftvà chọn Văn bản

  Ưu điểm: Xử lý tất cả các giá trị chính xác như văn bản mà không có ngoại lệ

  Nhược điểm: Nhiều bước hơn so với nhấp đúp

Cách xấu

• Mở một CSV bằng Double Click hoặc Excel's Open với hộp thoại

  Nhược điểm: Trình xử lý CSV nội bộ của Excel diễn giải sai các giá trị bằng một đầu -hoặc =ký dưới dạng công thức thay vì văn bản

  Nhược điểm: Bạn sẽ mất các số 0 đứng đầu từ các giá trị nhị phân như 0001do định dạng cột được phát hiện tự động của Excel

Cách tốt (cho VBA)

• Sử dụng QueryTables (bản sao VBA để Get external data) → Mã ví dụ

  Ưu điểm: Xử lý tất cả các giá trị chính xác như văn bản mà không có ngoại lệ

  Nhược điểm: Mã nhiều hơn một chút so với OpenTextphương thức

Cách xấu (đối với VBA)

• Sử dụng Workbooks.OpenTextphương thức → Mã ví dụ

  Nhược điểm: Phương pháp này vẫn đang sử dụng trình xử lý nhập CSV nội bộ của Excel với tất cả các lỗi của nó

  Nhược điểm: Ngoài ra, fieldinfotham số của OpenTextbị bỏ qua nếu tiện ích mở rộng là CSV. Thông thường, tham số này cho phép bạn chọn mọi định dạng cột, nhưng không phải nếu phần mở rộng là CSV. Bạn có thể đọc thêm về hành vi này trên Stack Overflow

  ^{Tạm thời đổi tên phần mở rộng nguồn từ CSV sang TXT và sau đó quay lại CSV là một cách giải quyết hợp lệ nếu bạn có toàn quyền kiểm soát tệp nguồn}

Phương pháp bổ sung

• Nếu bạn có quyền truy cập vào nguồn tạo CSV của mình, bạn có thể thay đổi cú pháp CSV.
  Gửi kèm mọi giá trị bằng dấu ngoặc kép và tiền tố một dấu bằng như ="00001"hoặc thêm một tab vào mỗi giá trị. Cả hai cách sẽ buộc Excel coi giá trị là văn bản

  _{Nội dung CSV gốc}
  

  _{CSV trong Excel khi được mở thông qua nhấp đúp}
  

  Lưu ý cách dòng 2 (phương pháp trích dẫn kép) và dòng 3 (phương pháp tab) không được thay đổi bởi Excel

• Mở CSV trong Notepad và sao chép và dán tất cả các giá trị vào Excel. Sau đó, sử dụng nhược điểm của Dữ liệu - Văn bản thành Cột
  : Văn bản trong Cột để thay đổi định dạng cột từ chung trở lại thành văn bản tạo ra kết quả không nhất quán. Nếu một giá trị chứa một -ký tự được bao quanh bởi các ký tự (ví dụ: "= E1-S1"), Excel sẽ cố gắng chia giá trị đó thành nhiều hơn một cột. Các giá trị nằm ngay bên phải ô đó có thể bị ghi đè
  ^{(Hành vi của Văn bản thành cột đã được thay đổi ở đâu đó giữa Excel 2007 và 2013 để nó không hoạt động nữa)}

Bổ trợ Excel để mở CSV và nhập tất cả các giá trị dưới dạng văn bản

Đây là Trình cắm Excel để đơn giản hóa các hành động Nhập CSV.
Ưu điểm chính: Đó là giải pháp một lần bấm và sử dụng QueryTables, cùng một phương pháp chống đạn phía sau Nhận dữ liệu ngoài

• Nó thêm lệnh menu mới vào Excel cho phép bạn nhập tệp CSV và TXT. Tất cả các giá trị được nhập vào trang tính hoạt động bắt đầu từ ô hiện được chọn
• Bổ trợ Excel có sẵn cho tất cả các phiên bản Office trên Windows và Mac
• Toàn bộ Bổ trợ chỉ có 35 dòng mã. Kiểm tra mã nguồn nhận xét nếu bạn tò mò
• Dấu tách danh sách CSV đã sử dụng (dấu phẩy hoặc dấu chấm phẩy) được lấy từ cài đặt Excel cục bộ của bạn
• Mã hóa được đặt thành UTF-8

Cài đặt

1. Tải xuống Bổ trợ và lưu nó vào thư mục Bổ trợ của bạn:%appdata%\Microsoft\AddIns
2. Mở Excel và kích hoạt Bổ trợ: File tab → Options → Add-Ins → Go Tovà chọnImportCSV.xla
3. Kích hoạt macro VBA: File tab → Options → Trust Center → Trust Center Settings → Macro Settings → Enable all macros
4. Khởi động lại Excel

Bạn sẽ nhận thấy một mục nhập thanh menu mới có tên Bổ trợ và bạn sử dụng nút này để nhanh chóng mở các tệp CSV của mình mà không gặp rắc rối với hộp thoại Nhập

Tập lệnh PowerShell để mở CSV trực tiếp từ Windows Explorer

Bạn có thể sử dụng tập lệnh PowerShell để mở tệp CSV và tự động chuyển chúng sang Excel. Tập lệnh âm thầm sử dụng phương thức nhập văn bản của Excel, xử lý các giá trị luôn dưới dạng văn bản và, như một phần thưởng, xử lý mã hóa UTF-8

1. Tạo một tệp văn bản mới và dán đoạn script dưới đây. Một phiên bản bình luận có thể được tìm thấy ở đây

$CSVs = @()
$args.ForEach({
    If ((Test-Path $_) -and ($_ -Match "\.csv$|\.txt$")) {
        $CSVs += ,$_
    } 
})

if (-Not $null -eq $CSVs) {

    $excel = New-Object -ComObject excel.application 
    $excel.visible = $true
    $excel.SheetsInNewWorkbook = $CSVs.Count    
    $workbook = $excel.Workbooks.Add()

    for ($i=0; $i -lt $CSVs.Count; $i++){

        $csv = Get-Item $CSVs[$i]
        $worksheet = $workbook.worksheets.Item($i + 1)
        $worksheet.Name = $csv.basename

        $TxtConnector = ("TEXT;" + $csv.fullname)
        $Connector = $worksheet.QueryTables.add($TxtConnector,$worksheet.Range("A1"))
        $query = $worksheet.QueryTables.item($Connector.name)
        $query.TextFilePlatform = 65001
        $query.TextFileTextQualifier = 1
        $query.TextFileOtherDelimiter = $Excel.Application.International(5) 
        $query.TextFileParseType  = 1
        $arrFormats = ,2 * $worksheet.Cells.Columns.Count
        $query.TextFileColumnDataTypes = $arrFormats
        $query.AdjustColumnWidth = 1
        $query.Refresh()
        $query.Delete()
    }
}

2. Lưu nó ở đâu đó như thế nào C:\my\folder\myScript.ps1. (Lưu ý phần mở rộng .ps1)
   • Mở thư mục sendto của bạn thông qua WinR» shell:sendto» Enter
3. Tạo một lối tắt mới thông qua Nhấp chuột phải »Mới» Phím tắt và dán dòng này. Đừng quên thay đổi đường dẫn đến đường dẫn của chính bạn, nơi bạn đã đặt tập lệnh của mình. Đặt tên cho lối tắt, ví dụ: Excel

"% SystemRoot% \ system32 \ WindowsPowerShell \ v1.0 \ powershell.exe" -NoProfile -NonInteractive -WindowStyle Hidden -File "C: \ my \ library \ myScript.ps1"

Bây giờ bạn có thể chọn (nhiều) CSV và mở chúng trong Excel thông qua Right-click » SendTo » Excel

Bạn có thể thử bằng cách mở .xlsx trước, sau đó tạo kết nối dữ liệu và nhập .csv. Chọn "dấu phẩy" được phân cách, sau đó chọn tùy chọn để coi tất cả các cột là văn bản thay vì "Chung".

Chỉnh sửa: Ồ, tôi đã không đọc hết câu hỏi. Trong trình hướng dẫn nhập, chọn tiêu đề cột đầu tiên mà bạn muốn nhập dưới dạng văn bản, cuộn đến tiêu đề cột cuối cùng và Shift + Nhấp vào tiêu đề. Sau đó chọn tùy chọn xuyên tâm "Văn bản".

Gợi ý của dưa hấu hoạt động (ngay cả với .CSV) nếu bạn làm như sau:

1. Mở Excel vào một sổ làm việc hoặc bảng tính trống
2. Nhấp vào Dữ liệu> [Nhận Dữ liệu Ngoài] Từ Văn bản
3. Sử dụng "Trình hướng dẫn nhập văn bản" như mô tả dưa hấu (Dấu phẩy được phân cách, chọn cột đầu tiên, SHIFT + BẤM cột cuối cùng, đặt mọi thứ thành Văn bản).

Tôi biết đó là nhiều bước hơn, nhưng ít nhất nó cho phép tôi mở CSV theo cách này mà không phải thay đổi tiện ích mở rộng

Cẩn thận!

Khi sử dụng phương pháp thủ công "Excel → Dữ liệu → Nhận dữ liệu ngoài → Chọn tất cả các cột và chọn Văn bản" ......

Điều này sẽ chỉ đặt các cột thành văn bản "có dữ liệu ở hàng đầu tiên" (thường là hàng tiêu đề). Trình hướng dẫn này không hiển thị cho bạn các cột xa hơn bên phải có thể có dữ liệu hơn bên dưới nhưng không ở hàng đầu tiên. Ví dụ:

Row1Col1, Row1Col2, Row1Col3

Row2Col1, Row2Col2, Row2Col3, Row2Col4

Bạn sẽ không bao giờ thấy Col 4 trong trình hướng dẫn nhập vì vậy bạn sẽ không có tùy chọn thay đổi từ định dạng chung sang định dạng văn bản trước khi nhập !!!!

Đây là thủ tục thay thế cho mã được đăng ở trên bởi Jean-François Corbett

Quy trình này sẽ nhập tệp csv vào Excel với tất cả các cột được định dạng là Văn bản

Public Sub ImportCSVAsText()
    Dim TempWorkbook As Workbook
    Dim TempWorksheet As Worksheet
    Dim ColumnCount As Integer
    Dim FileName As Variant
    Dim ColumnArray() As Integer

    'Get the file name
    FileName = Application.GetOpenFilename(FileFilter:="All Files (*.*),*.*", FilterIndex:=1, Title:="Select the CSV file", MultiSelect:=False)

    If FileName = False Then Exit Sub

    Application.ScreenUpdating = False

    'Open the file temporarily to get the count of columns
    Set TempWorkbook = Workbooks.Open(FileName)
    ColumnCount = TempWorkbook.Sheets(1).Range("A1").SpecialCells(xlCellTypeLastCell).Column
    TempWorkbook.Close SaveChanges:=False

    'Resize the array to number of columns
    ReDim ColumnArray(1 To ColumnCount)

    For i = 1 To ColumnCount
        ColumnArray(i) = xlTextFormat
    Next i

    Set TempWorkbook = Workbooks.Add
    Set TempWorksheet = TempWorkbook.Sheets(1)

    Application.DisplayAlerts = False
    TempWorkbook.Sheets(2).Delete
    TempWorkbook.Sheets(2).Delete
    Application.DisplayAlerts = True

    With TempWorksheet.QueryTables.Add("TEXT;" & FileName, TempWorksheet.Cells(1, 1))
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .TextFilePromptOnRefresh = False
        .TextFilePlatform = 1251
        .TextFileStartRow = 1
        .TextFileParseType = xlDelimited
        .TextFileTextQualifier = xlTextQualifierDoubleQuote
        .TextFileConsecutiveDelimiter = False
        .TextFileTabDelimiter = False
        .TextFileSemicolonDelimiter = False
        .TextFileCommaDelimiter = True
        .TextFileSpaceDelimiter = False
        .TextFileColumnDataTypes = ColumnArray
        .TextFileTrailingMinusNumbers = True
        .Refresh BackgroundQuery:=False
    End With

End Sub

Nếu bạn luôn nhập cùng một dữ liệu (định dạng bản ghi không đổi, bố cục, v.v.), bạn có thể viết macro truy cập bằng cách sử dụng thông số nhập và sau đó chuyển dữ liệu trở lại Excel. Thực hiện điều này có thể nhiều lần. Một cách khác mà tôi đã thực hiện là sử dụng VBA và đọc dữ liệu vào bảng ghi một lần và phân tích cú pháp khi đọc. Theo tôi biết, không có cách nào để đặt định dạng mặc định trong quá trình nhập trong Excel và ngay cả khi bạn có thể gây ra sự cố với loại tệp tiếp theo mà bạn cố phân tích.

Theo yêu cầu, gửi nhận xét của tôi dưới dạng câu trả lời (có thêm một chút thông tin được thêm vào):

Hey Scripting Guy đã làm một bài viết trên blog về Nhập CSV vào Excel có thể có một số mẩu tin hữu ích cho bạn. Chơi với đối tượng dữ liệu bên trong powershell có thể cho phép bạn làm những gì bạn muốn.

Mặc dù bài viết chỉ đề cập đến việc nhập dữ liệu vào các ô có thể để lại định dạng số, nhưng có thể chơi xung quanh với một số thuộc tính và phương thức ComObject của Excel để buộc dữ liệu nhập vào các ô dưới dạng văn bản thô thay thế (hoặc ép buộc định dạng của các ô thành văn bản trước hoặc sau khi nhập).

Vì các lý do không xác định, ngay cả khi bạn cung cấp rõ ràng các định dạng cho tất cả các cột, Excel sẽ bỏ qua nó nếu phần mở rộng tệp là CSV.

Một số tùy chọn:

• Tạo một truy vấn để nhập dữ liệu, như Wet dưa gợi ý .
  Nhược điểm: bạn có thể thiếu trình điều khiển cơ sở dữ liệu CSV trên máy 64 bit.

• Sử dụng mã của Jean , nhưng kết hợp sao chép tệp vào thư mục tạm thời và thay đổi phần mở rộng của bản sao.
  Nhược điểm: Không có liên kết đến tệp gốc (lưu sẽ ghi đè lên bản sao); bạn sẽ phải tự xóa bản sao sau đó. Tuy nhiên, bạn có thể lưu thủ công dưới dạng CSV gốc.

• Mở CSV trong Notepad, Ctrl+A, Ctrl+C, dán vào Excel, sau đó dữ liệu - Text to Columns, sau đó nó thuật sĩ thông thường, nơi bạn có thể thiết lập tất cả các cột văn bản trong một đi. Đó là một hương vị khác nhau của tùy chọn trước đó, bởi vì nó cũng ẩn phần mở rộng quý giá từ Excel.
  Nhược điểm: thủ công.

• Có một vòng lặp VBA rất đơn giản để đọc toàn bộ tệp vào bộ nhớ và đặt nó lên trang tính, từng ô.
  Nhược điểm: chậm, xấu.

Nếu tôi hiểu chính xác câu hỏi, điều này có thể dễ dàng giải quyết bằng cách sử dụng tùy chọn Transpose trong Paste-Special như được mô tả ở đây .