Tiếp tục Zsh-Terminal (OS X Lion)

OS X Lion có tính năng "Tiếp tục lại", tức là khi bạn mở lại một ứng dụng, nó sẽ khôi phục tất cả các cửa sổ và nội dung của chúng. Điều đó cũng làm việc cho Terminal. Nhưng nếu bạn sử dụng Zsh thay vì Bash thì nó không khôi phục thư mục đã mở. Làm thế nào tôi có thể sửa lỗi này?

CẬP NHẬT : Điều này không hoàn toàn chính xác, vì lý do được đề cập trong các ý kiến. Sử dụng câu trả lời dưới đây . Cảm ơn @ChrisPage đã đi thêm một dặm :)

Câu trả lời có thể được tìm thấy bằng kỹ thuật đảo ngược cách bash thực hiện /etc/bashrc. Tôi đã thử nhiều cách tiếp cận từ khắp nơi trên mạng nhưng cách của Apple dường như hoạt động tốt nhất (hình minh họa).

Trong của bạn .zshrcthêm như sau

# Set Apple Terminal.app resume directory
if [[ $TERM_PROGRAM == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]] {
  function chpwd {
    local SEARCH=' '
    local REPLACE='%20'
    local PWD_URL="file://$HOSTNAME${PWD//$SEARCH/$REPLACE}"
    printf '\e]7;%s\a' "$PWD_URL"
  }

  chpwd
}

Hạnh phúc nối lại.

Để làm rõ, câu trả lời này liên quan đến thông điệp bí ẩn trong tùy chọn Terminal.app của OS X Lion:

** Các chương trình thông báo cho Terminal của thư mục làm việc hiện tại bằng các chuỗi thoát. Bạn có thể cần định cấu hình trình bao của mình hoặc các chương trình khác để kích hoạt hành vi này. *

Câu trả lời này hoạt động khi bạn sử dụng zsh làm vỏ của bạn. Terminal Resume cho bash đã được Apple triển khai.

Đây là bản chuyển thể của tôi về / etc / bashrc cho zsh. Tôi đã bao gồm mã hóa phần trăm cho tất cả các ký tự URL yêu cầu nó, điều này rất quan trọng nếu bạn muốn nó hoạt động với tất cả các tên tệp và thư mục hợp lệ.

Điều này đăng ký một precmdhook, cho phép nhiều hơn một chức năng được đăng ký trong các tập lệnh và tập tin cấu hình khác.

CẬP NHẬT Tháng 3 năm 2019: Đặt LC_ALLthành trống để nó không ghi đè LC_CTYPE. Sử dụng precmdđể cập nhật thư mục làm việc tại mỗi dấu nhắc thay vì sử dụng chpwdđể cập nhật thư mục mỗi khi nó bị thay đổi, các đường ống lệnh của lệnh có thể thay đổi tạm thời và thiết bị đầu cuối không nên hiển thị các lệnh đó. Ngoài ra, có thể hữu ích khi mỗi lần cập nhật trạng thái thiết bị đầu cuối trong trường hợp nó bị thay đổi trong lệnh trước đó. Sử dụng printf -vđể ghi rõ ràng vào biến thay vì sử dụng cú pháp subshell.

# Tell the terminal about the working directory whenever it changes.

if [[ "$TERM_PROGRAM" == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]]; then

    update_terminal_cwd() {
        # Identify the directory using a "file:" scheme URL, including
        # the host name to disambiguate local vs. remote paths.

        # Percent-encode the pathname.
        local url_path=''
        {
            # Use LC_CTYPE=C to process text byte-by-byte. Ensure that
            # LC_ALL isn't set, so it doesn't interfere.
            local i ch hexch LC_CTYPE=C LC_ALL=
            for ((i = 1; i <= ${#PWD}; ++i)); do
                ch="$PWD[i]"
                if [[ "$ch" =~ [/._~A-Za-z0-9-] ]]; then
                    url_path+="$ch"
                else
                    printf -v hexch "%02X" "'$ch"
                    url_path+="%$hexch"
                fi
            done
        }

        printf '\e]7;%s\a' "file://$HOST$url_path"
    }

    # Register the function so it is called at each prompt.
    autoload add-zsh-hook
    add-zsh-hook precmd update_terminal_cwd
fi