Làm cách nào để buộc Windows kiểm tra các bản cập nhật?

Sau khi cài đặt Windows mới - XP hoặc 7 - làm cách nào tôi có thể "buộc" các bản cập nhật Windows?

Tôi không muốn có các bản cập nhật Windows "cũ" sau một tuần, vì vậy nó có thể được thực hiện trong "một bước" không? Có bất kỳ lệnh "ma thuật" nào buộc Windows phải kiểm tra các bản cập nhật không, và nếu có, hãy cài đặt chúng?

Bạn có thể kiểm tra và cài đặt các bản cập nhật tự động bằng cách sử dụng tập lệnh. Điều này sẽ hoạt động trong cả XP hoặc Windows 7.

Có một số tập lệnh có sẵn để tải xuống, đây là của tôi :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain.  It may be freely
' used, modified, and distributed.  However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
'   0 = scripting failure
'   1 = error obtaining or installing updates
'   2 = installation successful, no further updates to install
'   3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete.  Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop 

Bạn chạy cái này từ dòng lệnh như thế này:

cscript wsusupdate.vbs

Kịch bản của tôi chỉ có chức năng tối thiểu nhưng vẫn có thể hữu ích. Có các tập lệnh khác như vậy có sẵn với nhiều tính năng bổ sung, hãy thử tìm kiếm Google.

Ngoài cách sử dụng Windows Update thông thường, bạn có thể buộc kiểm tra từ một dòng lệnh.

Mở một dấu nhắc lệnh quản trị viên và chạy:

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exe là Máy khách AutoUpdate của Windows Update và được sử dụng để kiểm tra các bản cập nhật có sẵn (đối với các phiên bản khác nhau của nền tảng MS Windows) từ Microsoft Update.

Điều này sẽ không bắt buộc cài đặt.

Để kiểm tra các bản cập nhật, đi tới Bảng điều khiển, Bảo mật, Cập nhật Windows, sau đó bấm "Kiểm tra cập nhật".

Một cách khác để buộc quét lại các bản cập nhật thực sự là xóa sạch bảng, bằng cách xóa tất cả các bản cập nhật được lưu trữ trong % Windir% \ Windows \ SoftwareDistribution \ Download :

    NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

Sau đó, vào Windows Update và "Kiểm tra cập nhật". Có thể mất một giờ, vì mọi tệp có thể cập nhật trên khối lượng hệ thống của bạn đều được kiểm tra ("Kiểm tra cập nhật" tiếp theo sẽ nhanh chóng). Cách tiếp cận này giúp loại bỏ lỗi, cập nhật đã được khắc phục và mang lại một hệ thống cập nhật, sạch sẽ, ít nhất là trong chừng mực mà MS nhìn thấy.

Tôi đang sử dụng một công cụ của bên thứ hai được gọi là wuinstall để cập nhật cài đặt windows mới. với điều đó bạn có thể tự động hóa toàn bộ quá trình cập nhật, bao gồm cả khởi động lại tự động. Tôi nghĩ rằng đó là một trong những cách nhanh nhất để có được một cửa sổ mới cập nhật mà không cần người dùng tham dự.

Tôi đã thấy rằng, như là một phần của bản cài đặt mới trên Windows 7, bạn đã nâng cấp IE hoặc bạn chưa chạy IE và trả lời các câu hỏi giới thiệu, rằng Windows Update sẽ báo lỗi cho bạn. Tôi cũng chưa tìm được cách chuyển Windows Update sang Microsoft Update mà không cần thông qua GUI, vì vậy tôi tự khởi động IE, khởi chạy nó và sau đó thiết lập Windows Update thông qua GUI, vì vậy tôi có thể chuyển sang Microsoft Update và tránh lỗi ban đầu. Số dặm của bạn có thể thay đổi.

Tôi đã thành công sau các bước trên bài đăng này , bằng cách cài đặt IE8 & WI4.5 , nó sẽ kích hoạt cập nhật tự động để bắt đầu tải xuống.