Hãy xác định lời nhắc với bố cục này:
top_left top_right
bottom_left bottom_right
Để làm điều này, chúng ta sẽ cần một hàm cho chúng ta biết có bao nhiêu ký tự mà một chuỗi đã cho khi được in.
# Usage: prompt-length TEXT [COLUMNS]
#
# If you run `print -P TEXT`, how many characters will be printed
# on the last line?
#
# Or, equivalently, if you set PROMPT=TEXT with prompt_subst
# option unset, on which column will the cursor be?
#
# The second argument specifies terminal width. Defaults to the
# real terminal width.
#
# Assumes that `%{%}` and `%G` don't lie.
#
# Examples:
#
# prompt-length '' => 0
# prompt-length 'abc' => 3
# prompt-length $'abc\nxy' => 2
# prompt-length '❎' => 2
# prompt-length $'\t' => 8
# prompt-length $'\u274E' => 2
# prompt-length '%F{red}abc' => 3
# prompt-length $'%{a\b%Gb%}' => 1
# prompt-length '%D' => 8
# prompt-length '%1(l..ab)' => 2
# prompt-length '%(!.a.)' => 1 if root, 0 if not
function prompt-length() {
emulate -L zsh
local COLUMNS=${2:-$COLUMNS}
local -i x y=$#1 m
if (( y )); then
while (( ${${(%):-$1%$y(l.1.0)}[-1]} )); do
x=y
(( y *= 2 ));
done
local xy
while (( y > x + 1 )); do
m=$(( x + (y - x) / 2 ))
typeset ${${(%):-$1%$m(l.x.y)}[-1]}=$m
done
fi
echo $x
}
Chúng ta sẽ cần một hàm khác có hai đối số và in hoàn toàn tốt với các đối số này ở các cạnh đối diện của màn hình.
# Usage: fill-line LEFT RIGHT
#
# Prints LEFT<spaces>RIGHT with enough spaces in the middle
# to fill a terminal line.
function fill-line() {
emulate -L zsh
local left_len=$(prompt-length $1)
local right_len=$(prompt-length $2 9999)
local pad_len=$((COLUMNS - left_len - right_len - ${ZLE_RPROMPT_INDENT:-1}))
if (( pad_len < 1 )); then
# Not enough space for the right part. Drop it.
echo -E - ${1}
else
local pad=${(pl.$pad_len.. .)} # pad_len spaces
echo -E - ${1}${pad}${2}
fi
}
Cuối cùng, chúng ta có thể định nghĩa một hàm đặt PROMPTvà RPROMPThướng dẫn ZSH gọi hàm đó trước mỗi dấu nhắc và đặt các tùy chọn mở rộng dấu nhắc phù hợp:
# Sets PROMPT and RPROMPT.
#
# Requires: prompt_percent and no_prompt_subst.
function set-prompt() {
emulate -L zsh
local git_branch="$(git rev-parse --abbrev-ref HEAD 2>/dev/null)"
git_branch=${${git_branch//\%/%%}/\\/\\\\\\} # escape '%' and '\'
local top_left='%F{blue}%~%f'
local top_right="%F{green}${git_branch}%f"
local bottom_left='%B%F{%(?.green.red)}%#%f%b '
local bottom_right='%F{yellow}%T%f'
PROMPT="$(fill-line "$top_left" "$top_right")"$'\n'$bottom_left
RPROMPT=$bottom_right
}
autoload -Uz add-zsh-hook
add-zsh-hook precmd set-prompt
setopt noprompt{bang,subst} prompt{cr,percent,sp}
Điều này tạo ra lời nhắc sau:
~/foo/bar master
% █ 10:51
- Trên cùng bên trái: Thư mục hiện tại màu xanh.
- Trên cùng bên phải: Chi nhánh Git xanh.
- Dưới cùng bên trái:
#nếu root, %nếu không; xanh thành công, đỏ lỗi.
- Dưới cùng bên phải: Thời gian hiện tại màu vàng.
Bạn có thể tìm thấy chi tiết bổ sung trong lời nhắc nhiều dòng: Thành phần còn thiếu và mã hoàn chỉnh trong ý chính này .