Làm cách nào để định cấu hình Firefox thông qua tập lệnh?

Tôi đang tìm cách định cấu hình các cài đặt Firefox sau thông qua tập lệnh (VBS hoặc đợt)

• Trang chủ mặc định
• công cụ tìm kiếm mặc định
• tắt cập nhật tự động

Điều này có thể không?

Bạn có thể làm điều này bằng cách tạo hoặc thao tác các tệp tùy chọn Mozilla bằng ngôn ngữ kịch bản ưa thích của bạn.

Để biết danh sách các tùy chọn có thể được đặt qua các tệp này, hãy xem Tài liệu tùy chọn Mozilla và about: config , mặc dù các tùy chọn tương ứng với danh sách của bạn có vẻ là: -

• browser.startup.homepage (Trang chủ mặc định)
• browser.search.defaultenginename (công cụ tìm kiếm mặc định)
• app.update.auto (bật / tắt cập nhật tự động)

Tuy nhiên, tùy thuộc vào môi trường của bạn, bạn có thể thấy tốt hơn khi đẩy cài đặt thông qua tiện ích bổ sung tùy chỉnh (xem các nhận xét XPI trong Hướng dẫn ngắn gọn về Tùy chọn Mozilla ) hoặc thông qua GPO với FirefoxADM hoặc tương tự.

Bạn có thể ghi đè các tùy chọn trình duyệt riêng tư trong tệp user.js trong thư mục hồ sơ người dùng. Tôi sử dụng nó thường xuyên để ghi đè một số tùy chọn ví dụ đường ống. Firefox cần được khởi động lại sau khi bạn cập nhật user.js. Nếu tệp user.js không tồn tại, bạn phải tạo một tệp.

theo nghĩa đen là sao chép / dán phần câu trả lời mà tôi đang tìm kiếm (win env.)

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

thêm vào

user_pref("browser.startup.homepage", "http://www.URL");

tôi cố gắng sao chép vào các máy từ xa bằng đường dẫn Get-Content / cat string.txt / "String" >>, kết thúc bằng việc rác được chèn vào prefs.jstệp do các ký tự thoát trong chuỗi.

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

Các chủ đề là một litte cũ, nhưng tôi muốn chia sẻ giải pháp của tôi dù sao. Hy vọng điều này sẽ giúp được ai đó. Chúng tôi đã có một vấn đề tương tự và muốn thêm các chứng chỉ từ windows store vào firefox. Vì vậy, tôi đã tạo ra một kịch bản để làm như vậy. Dù sao, bạn có thể thay đổi nó theo nhu cầu của mình: Chỉ cần thêm hoặc xóa các dòng tại :: tạo cfg_file_name.cfg [...] và chèn những gì bạn cần, ví dụ: để bắt đầu trang chủ, v.v. Hãy nhớ đặt ^ trước lần cuối), nếu không nó sẽ không hoạt động! echo pref("browser.startup.homepage", "http://superuser.com"^);

Kể từ phiên bản 49, bạn có thể làm như vậy:

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit