VBA - bật lên các lệnh để điền chi tiết trên bảng tính

Tôi có thể tìm thành công một hàng cụ thể (bằng cách tham chiếu trong cột A), sao chép hàng đó và dán bên dưới bản gốc.

Bây giờ tôi muốn khả năng yêu cầu thông tin để điền vào một số ô nhất định. Ví dụ.

1. Tìm hàng 7, bản sao và dán vào Hàng 8.
2. Sau đó nhận được thông báo "Cập nhật thông tin công việc" và sau đó sẽ nhập thông tin đó vào Cell G8.

Mẫu này luôn giống nhau, tức là cập nhật cột G trong các hàng được dán vào.

Bất kỳ trợ giúp nào cũng được đánh giá rất cao.

Là một phần mở rộng cho câu trả lời của tôi cho câu hỏi cuối cùng của bạn, đây là macro một lần nữa với việc thêm lời nhắc nhập dữ liệu.

Sub CopyData()
    Dim res As String
    Dim cl As Range
    Dim sh As Worksheet

    ' operate on the active sheet
    Set sh = ActiveSheet

    ' ask for ID to find in column A
    res = InputBox("Enter ID to Find", "Copy Row")

    ' If no responce, exit
    If res = "" Then
        Exit Sub
    End If

    With sh
        ' Find first occurance
        Application.FindFormat.Clear
        Set cl = .Columns(1).Find(What:=res, _
            After:=.Cells(.Rows.Count, 1), _
            LookIn:=xlValues, _
            LookAt:=xlWhole, _
            SearchOrder:=xlByRows, _
            SearchDirection:=xlNext, _
            MatchCase:=True)

        If Not cl Is Nothing Then
            ' if found, select entire row
            Set cl = cl.EntireRow
            ' copy and insert paste data into next row
            cl.Copy
            cl.Offset(1, 0).Insert
            ' turn off copy highlight (moving border)
            Application.CutCopyMode = False

            ' Prompt for input
            res = InputBox("Enter some info for Column G", "Update job information")
            If res <> "" Then
                cl.Cells(2, 7) = res
            End If
        End If
    End With
End Sub