Làm cách nào để thay đổi ngôn ngữ của tất cả các slide Powerpoint cùng một lúc?

Mặc dù chủ đề này khá cũ, Microsoft đã không cung cấp giải pháp nào mà tôi biết. Tôi đề xuất một cách tiếp cận khác cho người dùng Mac: mở bản trình bày của bạn trong Keynote, thay đổi ngôn ngữ chính tả và có thể chỉnh sửa toàn bộ bản trình bày của bạn, sau đó xuất nó sang PowerPoint.

Để dễ dàng thay đổi ngôn ngữ của toàn bộ PowerPoint, hãy mở tab Xem và chọn chế độ xem Phác thảo .

Bây giờ bấm

• Ctrl+ Ađể chọn tất cả.
• Công cụ → Ngôn ngữ → Chọn ngôn ngữ của bạn để đặt.

Tương tự như vậy trong khi bạn có mọi thứ được chọn, bạn có thể thay đổi những thứ khác như phông chữ, màu sắc, v.v. Mặc dù trong nhiều trường hợp, điều này được thực hiện tốt hơn bằng cách thay đổi slide master, một bài thuyết trình có nhiều trình chỉnh sửa có thể có nhiều định dạng 'cứng' lệch khỏi chủ cơ bản và cần thiết lập lại để được nhất quán. Bạn cũng có thể đặt lại các trang chiếu riêng lẻ theo kiểu chính, nhưng điều này có thể dẫn đến việc giữ chỗ cũng di chuyển, điều này có thể không mong muốn trong một số trường hợp.

PowerPoint 2013

• Xem → Phác thảo → chọn tất cả các trang chiếu (trong menu bên trái) qua Ctrl+ A.
• Xem lại → Ngôn ngữ → Đặt ngôn ngữ kiểm chứng ... → Chọn ngôn ngữ của bạn để đặt.

Đối với tôi - Khởi động lại PowerPoint là cần thiết. Có lẽ bởi vì tôi cũng đã thay đổi Ngôn ngữ chỉnh sửa :

• Xem lại → Ngôn ngữ → Đặt ngôn ngữ kiểm chứng ... → Tùy chọn ngôn ngữ → Chọn ngôn ngữ chỉnh sửa .

Sử dụng Powerpoint 2010 tôi đã mở menu Outline -

Đã chọn tất cả văn bản (Ctrl + A), mở menu ngôn ngữ và đặt ngôn ngữ kiểm chứng của tôi

Va no đa hoạt động!

Menu ngôn ngữ nằm trên tab Xem lại dải băng (sau tab Trình chiếu và không hiển thị trên ảnh chụp màn hình).

Các câu trả lời hiện có làm việc cho văn bản có mặt trong đề cương. Thật không may trong trường hợp của tôi, điều này không bao gồm một phần quan trọng của văn bản, bao gồm cả hình, bảng, v.v.

Macro này đã giải quyết vấn đề cho tôi:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

"MsoL LanguageIDEnglishUS" được sử dụng trong macro ở trên có thể được thay thế bằng bất kỳ ngôn ngữ mong muốn nào. Danh sách đầy đủ các ngôn ngữ có thể được tìm thấy trong bài viết này

(Tín dụng đi vào Ganesh Kumar đã đăng vĩ mô ban đầu ở đây . Tôi thêm hỗ trợ cho cấp độ đầu tiên của hình dạng nhóm. Tiếp tục hoàn thiện nó vĩ mô có thể được thực hiện đệ quy để tìm kiếm các nhóm có chứa các nhóm khác, vv)

Tôi đã cải thiện câu trả lời của Inigo để cung cấp phiên bản đệ quy thay đổi tất cả các mục thành ngôn ngữ mong muốn.

Phiên bản này sẽ điều tra đệ quy từng hình dạng là một loại nhóm. Một số thử nghiệm cho thấy msoGroupvà msoSmartArtlà các loại nhóm - vui lòng thêm vào danh sách đó nếu bạn tìm thấy các loại hình dạng khác có thể chứa các đối tượng văn bản.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Dựa trên câu trả lời của Inigo, Duncan, Maria và DomDev, cách này hoạt động cho các hình dạng, bảng, nhóm, SmartArt, hiện tại và trong tương lai:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Phiên bản của Duncan hoạt động tốt cho mọi thứ trừ bảng. Tôi đã tìm thấy một mã khác dường như cũng hoạt động với các bảng: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-lingu-on-tables-charts-etc-that-contains-text

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

Ngoài câu trả lời do Mastergalen cung cấp và để giải quyết các bình luận liên quan đến văn bản mới gõ:

Nếu bạn sẽ nhận thấy, ngôn ngữ đó sẽ tự động thay đổi trở lại bất cứ khi nào bạn bắt đầu nhập văn bản mới (rất khó chịu), bạn phải thay đổi ngôn ngữ mặc định hiện tại cho PowerPoint:

• đảm bảo cửa sổ PowerPoint là cửa sổ đang hoạt động
• trong Windows Taskbar(có, thực tế không có trong PowerPoint), kiểm tra xem Language barcó hiển thị không,
  • nếu không đi Control Panel > Region and Language > Keyboards and Languages. Nhấp Change keybords..., chuyển sang Language bartab và kiểm tra Docked in the taskbartùy chọn. (đây là từ Win7, vì vậy có thể hơi khác một chút trong các phiên bản khác).
• bây giờ hành động chính - trong Language barthanh tác vụ, nhấp vào mã ngôn ngữ và chuyển sang EN (nếu bạn muốn sử dụng tiếng Anh trong PowerPoint). Từ giờ trở đi, tất cả văn bản mới trong PowerPoint sẽ ở ngôn ngữ đã chọn :-)
• nếu bạn muốn viết bằng ngôn ngữ gốc của bạn, chỉ cần thay đổi lại.

Tôi đã tạo một bổ trợ vào năm 2014 cho chính mình nhưng vẫn hoạt động tốt trong PowerPoint 2016. https://github.com/wobba/officeaddin/release/tag/v1.0.1

Nó quét các ngôn ngữ đã sử dụng và cho phép bạn thay đổi tất cả cùng một lúc, lặp lại.