Phím tắt trong phiên bản không phải tiếng Anh của Microsoft Office

Tôi có một vấn đề lớn với phiên bản tiếng Bồ Đào Nha của MS Office 2007 và 2010.

Các phím tắt tiêu chuẩn mà bất kỳ ứng dụng phổ biến sử dụng đều được thay đổi.
Một số phím tắt không hoạt động: Ctrl+ s(lưu), Ctrl+ f(tìm) và Ctrl+ a(chọn tất cả).

Tôi muốn cấu hình nó để sử dụng các phím tắt của phiên bản tiếng Anh.

Có một tùy chọn cho phép cấu hình từng phím tắt riêng biệt. Hơn nữa, tôi phải định cấu hình cho từng ứng dụng, nếu tôi định cấu hình trong Word, tôi sẽ phải định cấu hình lại cho Excel.

Làm cách nào để sử dụng các phím tắt của phiên bản tiếng Anh của MS Office bất kể ngôn ngữ Office là gì?

Cảm ơn

Tôi gần như chắc chắn rằng không có cách tích hợp để thay đổi các phím tắt trong các ứng dụng MS Office.

Tuy nhiên, bạn có thể sử dụng AutoHotkey cho mục đích này.

Kịch bản

^a::
^f::
^s::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a")
           SendPlay, ^e
       if(A_ThisHotKey = "^f")
           SendPlay, ^b
       if(A_ThisHotKey = "^s")
           SendPlay, ^g
    }
    else
        SendPlay, %A_ThisHotKey%
return

Làm thế nào nó hoạt động

• ^a::, chỉ định một trong các phím nóng chạy tập lệnh trước returncâu lệnh, trong đó ^chỉ ra Ctrlkhóa.

• WinGet, Process, ProcessName, Alưu trữ Atên tiến trình của cửa sổ active ( ) trong biến Process.

• if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$")) {...} else ...kiểm tra xem có Process khớp với biểu thức chính quy hay không , nếu nó khớp với một trong các chuỗi WINWORD.EXEhoặc EXCEL.EXE.

  • Nếu vậy, khối đầu tiên được thực thi.

    • if(A_ThisHotKey = "^a")kiểm tra xem phím nóng được nhấn là Ctrl+ A.

      Nếu đúng, nó mô phỏng khóa bom Ctrl+ E, là phím nóng Bồ Đào Nha để chọn tất cả ¹ .

  • Mặt khác, SendPlay, %A_ThisHotKey%mô phỏng tổ hợp phím đã được nhấn ban đầu.

    Bằng cách này, các ứng dụng khác vẫn hoạt động như bình thường.

Cách sử dụng

1. Tải xuống và cài đặt phiên bản mới nhất của AutoHotkey.

2. Lưu tập lệnh trên dưới dạng ms-office.ahk, sử dụng trình soạn thảo văn bản yêu thích của bạn.

3. Bấm đúp vào tệp để chạy tập lệnh.

4. Nếu bạn muốn, sao chép tập lệnh (hoặc một liên kết đến nó) trong Startupthư mục.

5. Để thêm các ứng dụng MS Office khác, chỉ cần sửa đổi biểu thức thông thường.

   Để thêm PowerPoint, ví dụ, thay thế (WINWORD|EXCEL)bằng (WINWORD|EXCEL|POWERPNT).

6. Để thêm các phím nóng, bạn phải sửa đổi hai phần của tập lệnh.

   Để thêm Ctrl+ O(Mở ...), ví dụ: thêm dòng ^o::vào danh sách ở trên cùng, thêm các dòng này vào bên trong ifkhối:

   if(A_ThisHotKey = "^o")
       SendPlay, ^a
   

¹ Ít nhất, tôi nghĩ rằng nó được. Tôi lấy các phím nóng từ Văn phòng MS Tây Ban Nha của tôi. Điều chỉnh nếu cần.

Dựa trên câu trả lời trước, thêm một vài phím tắt (có thể được thêm vào câu trả lời trước):

^a::
^f::
^s::
^w::
^n::
^u::
^d::
^r::
^b::
^i::
^k::
^g::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a") ;seleccionar rango
           SendPlay, ^e
       if(A_ThisHotKey = "^f") ;buscar
           SendPlay, ^b
       if(A_ThisHotKey = "^s") ;guardar
           SendPlay, ^g
       if(A_ThisHotKey = "^w") ;cerrar
           SendPlay, ^r
       if(A_ThisHotKey = "^n") ;nuevo libro
           SendPlay, ^u
       if(A_ThisHotKey = "^u") ;subrayar
           SendPlay, ^s
       if(A_ThisHotKey = "^b") ;negrita
           SendPlay, ^n
       if(A_ThisHotKey = "^i") ;cursiva
           SendPlay, ^k
       if(A_ThisHotKey = "^d") ;filldown
           SendPlay, ^j
       if(A_ThisHotKey = "^r") ;fill right
           SendPlay, ^d
       if(A_ThisHotKey = "^k") ;hyperlink
           SendPlay, ^!k
       if(A_ThisHotKey = "^g") ;goto
           SendPlay, ^i
    }
    else
        SendPlay, %A_ThisHotKey%
return