Một ổ đĩa mạng được ánh xạ có thể được kết nối lại từ dòng lệnh?

Trên cơ sở hàng ngày, tôi thấy mình trong dấu nhắc lệnh của Windows cần truy cập vào ổ đĩa mạng được ánh xạ nhưng bị ngắt kết nối. Tôi vẫn chưa tìm thấy một lệnh sẽ kết nối lại ổ đĩa này mà không hủy ánh xạ và ánh xạ lại (điều này dẫn đến một trò chơi đoán mật khẩu, vì tôi không sở hữu các máy tính này). Tôi cũng muốn có thể viết kịch bản này để mỗi đêm ổ đĩa được kết nối lại nếu nó bị ngắt kết nối bằng cách nào đó.

Giải pháp nhanh nhất tôi hiện có là:

1. Nhập " start." để mở explorer,
2. Alt- Dđể tập trung thanh địa chỉ,
3. gõ ký tự ổ đĩa tôi muốn và nhấn enter, và đợi nó hiển thị nội dung ổ đĩa,
4. cuối cùng, đóng explorer và quay lại dấu nhắc lệnh.

Tôi biết đó là một bất tiện nhỏ, nhưng tôi thường làm điều này thông qua kết nối VNC hoặc PCAnywhere chậm, nơi làm bất cứ điều gì thông qua GUI là khủng khiếp, vì vậy tôi chỉ tự hỏi liệu có giải pháp nào tốt hơn không.

Có thể thử pushd \\server\share?

Tôi phải khởi động Windows 7 trước khi có thể chạy chương trình VPN kết nối tôi với các ổ đĩa mạng của công ty. Do đó, các ổ đĩa mạng của tôi không tự động kết nối lại, chỉ mở chúng trong Windows Explorer kết nối lại chúng.

Tôi đã tạo một tệp bó nhỏ để khởi động VPN, kết nối lại các ổ đĩa mạng và khởi động một số ứng dụng tôi luôn sử dụng.

Trong tập tin Batch của tôi, tôi có những điều sau đây:

REM Connect VPN here...

REM Opens an Explorer window looking at T: forcing a reconnect
Start /min explorer t:\

timeout 3 /nobreak

REM Kill all Explorer windows beginning with "T_drive" in the title
Taskkill /fi "windowtitle eq T_drive*"

REM Finish starting up here...

exit

Các Taskkill /fi "windowtitle eq"lệnh là trường hợp nhạy cảm!

tạo một tệp bó (refreshletters.cmd) với các lệnh này trong đó

( những thứ này sẽ chỉ hoạt động trong một tệp bó )

Đã thử nghiệm trên Win7 và XP để làm mới các chữ cái trình điều khiển 'Ngắt kết nối' và 'Không khả dụng' trong cửa sổ bảng điều khiển (dòng lệnh).

@echo off
net use |FIND ":" > %temp%\used.txt
FOR /F " tokens=1,2,3 delims= " %%i in (%temp%\used.txt) do (

  if %%i EQU Unavailable  (
    net use %%j %%k
    echo Activated %%j
   ) ELSE (
     if %%i EQU Disconnected (
       pushd .
       cd /d %%j
       dir . %>nul
       if NOT exist %%j\. (
          net use %%j /del /y
          net use %%j %%k
          echo Remapped %%j
          ) else (
             echo Fixed-up %%j
            )
       popd
       ) ELSE (
          echo Checked %%j
          )
     )
 )

Đây có lẽ là một câu hỏi ngu ngốc, nhưng giả sử ổ đĩa "bị ngắt kết nối" của bạn là H:, bạn đã thử thay đổi trực tiếp sang ổ đĩa chưa?

Nó hoạt động với tôi theo XPSP3:

C:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
Disconnected H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.


C:\>h:

H:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
OK           H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.

Tôi biết bạn đã nói "sử dụng mạng" không hiệu quả với bạn - nhưng đây là những gì bạn có thể thử.

Chạy một tệp bó với tùy chọn sử dụng ròng / XÓA để xóa các kết nối hiện có / liên tục Và sau đó bạn có thể sử dụng mạng với tùy chọn / SAVECRED để sử dụng lại thông tin đăng nhập được sử dụng trong lần đăng nhập thành công cuối cùng. Tôi không chắc chắn nếu điều này sẽ giải quyết vấn đề của bạn nhưng nó đáng để xem xét.

Tôi có cùng một vấn đề với nhiều kết nối và nó không liên tục. Khi tôi khởi động lại máy tính, đôi khi kết nối là "tốt" và đôi khi không. Tôi không gặp vấn đề về mật khẩu vì tôi thuộc mạng LAN của công ty, nhưng tôi vẫn gặp phải vấn đề khác.

Tôi đã tạo một tệp bó có tên ex.bat và lưu trữ nó (cùng với nhiều thứ khác) trong thư mục \ produc mà tôi đặt trong đường dẫn của mình. Tôi có thể gõ "ex h:" và nó sẽ chạy Windows Explorer và đặt nó trực tiếp vào ổ h :. Đây là tập tin bó:

start explorer /e,/select,%1

Điều này hoạt động, với rất ít tổ hợp phím. Hoặc nếu lúc đầu nó không hoạt động, hãy nhấn phím Enter để mở thư mục h: root và hiển thị nội dung. Hoặc, nhập "ex h: \ sub" trong đó thư mục con "phụ" tồn tại.

Vấn đề này dường như đã trở nên tồi tệ hơn rất nhiều gần đây, có lẽ là do một trong các bản vá bảo mật của Windows XP.

Một thứ khác để thử là ở phía máy chủ. Trên các máy chủ Windows, sửa đổi khóa Registry được cho là để giữ cho máy chủ không ngắt kết nối các kết nối của nó khi hết thời gian. Tôi làm điều này trên khá nhiều máy chủ của chúng tôi. Các tập tin là:

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]
"autodisconnect"=dword:ffffffff

Tôi gặp vấn đề tương tự và phát hiện ra rằng tôi có thể buộc kết nối lại với một "dir x:" đơn giản từ dòng lệnh (trong đó X: là ổ đĩa được ánh xạ nhưng bị ngắt kết nối.) Đây là từ hệ thống Server 2003 để ánh xạ ổ đĩa trên XP và Win7 máy tính.

Tôi đã tạo một tệp bó, Wake_network_drive.bat, với hai dòng sau:

    dir x:
    dir z:

và thiết lập một tác vụ theo lịch trình để chạy nó hàng đêm trước khi chương trình sao lưu bị lỗi vì các ổ đĩa thỉnh thoảng hiển thị là bị ngắt kết nối.

Chỉ loại:

NET USE H: \\server\share

(trong đó H: là ký tự ổ đĩa của bạn)

Nhập 'NET /? SỬ DỤNG 'để xem tất cả các tùy chọn lệnh này cung cấp cho bạn.

Nếu bạn không phản đối việc giữ các mật khẩu này ở dạng văn bản đơn giản trong một đợt, bạn có thể tạo kịch bản xóa và ánh xạ lại bao gồm thông tin đăng nhập.

net use H: /delete
net use H: \\server\share /user:domain\user password /persistent:yes

Tôi biết nó không đáp ứng yêu cầu của bạn về việc không xóa chia sẻ, nhưng nó giải quyết được gốc rễ của vấn đề phải nhớ mật khẩu.

Tóm tắt TL; DR: sử dụng net usevàif exist

Tôi gặp phải một vấn đề liên quan trong khi tạo ra một kịch bản sao lưu hàng đêm. Nó phải kiểm tra xem máy tính đã được bật chưa (sử dụng ping), gửi gói ma thuật để bật nếu cần (sử dụng MC-WOL ), đợi Windows khởi động, sau đó thiết lập kết nối với chia sẻ SMB và chờ đợi hiện tại.

Mặc dù các câu trả lời khác ở đây rất hay, tôi không muốn các ký tự ổ đĩa được ánh xạ xuất hiện hoặc không kết nối bất cứ thứ gì mà người dùng có thể làm việc cùng, cũng như không có cửa sổ Explorer nhấp nháy xung quanh. tức là mục tiêu không làm người dùng mất tập trung .

Đây là một đoạn mã có thể hữu ích cho bạn:

set TARGET_IP=192.168.1.3
set TARGET_PATH=\\%TARGET_IP%\d$\backups
set ATTEMPTS=0

:LOOP

REM Give up eventually
if %ATTEMPTS% GEQ 200 goto NOJOY

REM Wait for IP connectivity to host, and/or burn up a couple seconds before retry
ping -n 1 -w 2000 %TARGET_IP% | find "TTL" > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

REM See if we're already connected, and try to give it a kick
if exist %TARGET_PATH% goto CONNECTED

REM Try to reconnect
net use %TARGET_PATH% > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

:CONNECTED
echo Connected
exit /b

:NOJOY
echo Couldn't connect

Nếu bạn thích, bạn có thể thay thế địa chỉ IP ở trên bằng tên máy chủ (ví dụ server1).

net uselà cần thiết trong trường hợp không có kết nối hiện có. Tôi đã gặp một số trường hợp ở góc mà chỉ một mình nó dường như không đủ để "đánh thức" phần chia sẻ (ví dụ nếu có một kết nối trước đó tồn tại ở trạng thái ngắt kết nối). Tôi tìm thấy if existschỉ có tác dụng tương tự như các lựa chọn thay thế đề cập trong câu trả lời khác (như pushd, dir, Explorer, vv), nhưng nó dường như là một cách tiếp cận trọng lượng nhẹ hơn.

Câu trả lời từ StanZ đã làm việc cho tôi, nhưng tôi phải có thể lập trình xác định bất kỳ ổ đĩa được ánh xạ nào mà không có trạng thái OK, vì người dùng trong miền của chúng tôi có các ánh xạ ổ đĩa khác nhau. Tôi đã mã hóa ở đây để chạy như một phiên bản độc lập, thực thi net usetrước và sau mã thực tế, để bạn có thể xem kết quả, nhưng bạn chỉ cần sao chép một FORcâu lệnh (ba dòng) vào mã của mình để có kết quả mong muốn.

@ECHO OFF
::  
:: revision of answer from StanZ on superuser.com at the following url  
:: https://superuser.com/questions/52595/can-a-mapped-network-drive-be-reconnected-from-the-command-line/367910#367910  
:: https://superuser.com/a/367910  
:: which resulted in my  
::  
:: DriveStatusOK.bat  
:: iCharlieC  
::  
SETLOCAL ENABLEEXTENSIONS  
::  
:: you need only copy the one FOR statement (three lines)  
::   to use in your own code  
::   to force status of mapped network drives to OK  
::  
:: "tokens=1-2 delims=: " is used in the for statement  
:: to output only the drive letter from the output of...  
:: net use  
:: is piped to the first findstr which outputs only lines with drive letters  
::   then piped to another findstr to eliminate drives with a status of OK  
::   then piped to another findstr to get lines that start with a status  
::     -in other words, those lines that the first character is a letter-  
::     -this due to the fact that in our domain we have a drive  
::      that is mapped to a letter, but never has a status.  
::      I do not know the reason for this,  
::      but adding that last findstr prevents me from getting an error  
::      from trying to execute a dir on a non-existant drive letter.-  
::   then dir is executed on each drive letter (after appending ":\" to the letter)  
::      and the output redirected to NUL  
::  
:: run net use before as a visual here  
net use  
::  
FOR /F "tokens=1-2 delims=: " %%i in (  
    'net use ^| findstr ":" ^| findstr /i /v "^OK" ^| findstr /i "^[A-Z]"'  
    ) do dir "%%j:" > NUL  
::  
:: run net use after "waking" drive(s)  
net use  
::  
ENDLOCAL  

Có thể một câu hỏi cũ nhưng vẫn có liên quan trong năm 2017 và Windows 10 vì các chia sẻ mạng thường không được kết nối lại hoặc được đính kèm một cách chính xác bởi các cửa sổ vì những lý do khác nhau. Dựa trên vấn đề này và sự vắng mặt của một giải pháp hoạt động đầy đủ và có thể thực hiện được, tôi đã tạo một dự án Github có chứa Tác vụ lập lịch và VBS để giải quyết vấn đề bằng cách cố gắng kết nối lại các ổ đĩa sau khi tiếp tục hoặc đăng nhập nếu không được kết nối hoặc trực tuyến.

Kịch bản có thể cấu hình đầy đủ và có thể được thiết lập tùy theo nhu cầu của người dùng thực tế.

Đường dẫn đến dự án Github