nhúng hình ảnh từ web bằng url trong bảng tính excel (hoặc oo calc)

2

Tôi muốn nhúng ảnh từ web vào bảng tính excel.

Tôi muốn nhúng hình ảnh theo url, giống như cách hình ảnh được nhúng trong trang html. Tôi không muốn tải xuống hình ảnh và chèn nó như một hình ảnh thông thường.

Và tôi muốn hình ảnh được hiển thị (tất nhiên nếu tôi đang trực tuyến), không chỉ là url.

Điều này có thể được thực hiện? Nếu vậy thì thế nào?

Tốt nhất là trong excel, nhưng OO calc sẽ ổn

microsoft-excel images openoffice-calc

— flybywire
nguồn

1

Chỉ trong trường hợp điều này khiến bạn gặp phải những lỗi lạ, thì thật tốt khi biết rằng Office có thể sử dụng trình duyệt ("Tác nhân người dùng") được gọi là "Microsoft Office Existence Discovery" trước cả khi cố gắng tìm nạp hình ảnh. Tác nhân người dùng đó có thể được xem như một robot tìm kiếm và do đó trên một số trang web có thể có quyền truy cập khác với thành phần IE được sử dụng để thực sự tìm nạp hình ảnh ... Thông tin thêm một chút tại superuser.com/questions/41935/ Tiết

— kiệm

2

Trong Excel, đi tới Chèn > Ảnh > Từ tệp ... và nhập URL của ảnh bạn muốn chèn. Tôi không biết nếu hình ảnh tự cập nhật vì tôi chưa bao giờ thử nó.

— alex
nguồn

Tôi tin rằng sẽ chỉ đọc hình ảnh từ web.

— harrymc

Vâng, nó có. Nó hoạt động

— ukanth

Tôi nghĩ rằng vấn đề là làm điều đó theo chương trình.

— Dan

@Dan không thực sự, nếu không nó sẽ có trên stackoverflow.

— alex

1

Đây là phiên bản sửa đổi của tôi về câu trả lời được chia sẻ bởi tomelin5. Nó hoạt động trong Excel 2016 và có khả năng trong (nhiều) phiên bản cũ hơn.

Trong trường hợp của tôi, tôi đã tạo một ứng dụng Microsoft PowerApps để thu thập và lưu trữ chữ ký bằng cách sử dụng điều khiển nhập bút .

Ngoài ra: Trong trường hợp bạn đang đọc điều này bởi vì bạn đang cố gắng tạo một PowerApp: nước sốt kỳ diệu để lưu nội dung điều khiển của bạn vào bảng tính chính là Patchchức năng.

Cách thức hoạt động là điều khiển nhập bút sẽ lưu hình ảnh dưới dạng tệp PNG trong thư mục và lưu địa chỉ tương đối vào tệp PNG dưới dạng URL trong các ô trong một bảng tính: URL, ví dụ: .\MyAppName_images\x829ca33re2d6114588e59ca45829d21.png

Tôi muốn hiển thị những chữ ký đó trong bảng tính Excel đó để có thể sắp xếp chúng bằng cách sử dụng dữ liệu khác được nhập thông qua ứng dụng. Giải pháp của tomelin5 đã hoạt động rất tốt làm cơ sở cho giải pháp của tôi, tôi nghĩ rằng tôi nên chia sẻ bản phối lại của mình.

Giải pháp của tôi lưu trữ các URL trong cột "A" (1) và đặt các hình ảnh vào cột "I" (9). Nó cũng điều chỉnh chiều cao của các hàng theo chiều rộng cột của cột 9, tuy nhiên, bạn có thể sẽ muốn sửa đổi / loại bỏ hành vi đó.

Tất cả các URL được xử lý bắt đầu bằng A2 và mở rộng đến ô được điền cuối cùng trong cột A. Lưu ý rằng giải pháp của tôi không thực hiện bất kỳ xử lý ngoại lệ nào và bạn cần điều đó trong trường hợp không có hình ảnh.

Sub Button1_Click()
    ' https://msdn.microsoft.com/en-us/library/office/aa221353(v=office.11).aspx
    ' http://www.excelhowto.com/macros/loop-range-cells/
    ' https://www.excelcampus.com/vba/find-last-row-column-cell/
    ' https://superuser.com/questions/52760/embed-pictures-from-web-by-url-in-excel-spreadsheet-or-oo-calc#

    Dim Pic As Picture
    Dim SrcRange As Range
    Dim LastRowA As Long

    LastRowA = Cells.Find(What:="*", _
                    After:=Range("A1"), _
                    LookAt:=xlPart, _
                    LookIn:=xlFormulas, _
                    SearchOrder:=xlByRows, _
                    SearchDirection:=xlPrevious, _
                    MatchCase:=False).Row

    Set SrcRange = ActiveSheet.Range(Cells(2, 1), Cells(LastRowA, 1))

    SrcRange.Rows().RowHeight = ActiveSheet.Columns(9).Width

    For Each Cell In SrcRange.Cells
        With Cell
            Set Pic = .Parent.Pictures.Insert(.Value)
            With .Offset(, 8)
                Pic.Top = .Top
                Pic.Left = .Left
                Pic.Height = .Height
                Pic.Width = .Width
                Pic.Border.Color = vbRed
            End With
        End With
    Next
End Sub

— người dùng 2021355
nguồn

0

Tôi nghĩ giải pháp là viết một macro VBA sẽ lấy hình ảnh và nhúng nó vào bảng tính.

Tôi nghĩ đó là cách duy nhất để hình ảnh này được tự động làm mới.

— harrymc
nguồn

0

Nếu URL ở C1, điều này sẽ đưa hình ảnh vào B1 (được thử nghiệm trong Excel 2003 và 2013 bởi tôi):

Sub Test()
    Dim Pic As Picture
    Application.ScreenUpdating = False
    With ActiveSheet.Range("C1")
        Set Pic = .Parent.Pictures.Insert(.Value)
        With .Offset(, -1)
            Pic.Top = .Top
            Pic.Left = .Left
            Pic.Height = .Height
            Pic.Width = .Width
        End With
    End With
    Application.ScreenUpdating = True
End Sub

nguồn

— tomelin5
nguồn

0

Thực hiện theo các bước dưới đây,

Nhấp vào 'Hình ảnh' trong tab Chèn
Chèn URL vào hình ảnh (jpg | png, v.v.) HOẶC chọn đường dẫn đến một hình ảnh trong máy tính để bàn của bạn
Nhấp vào mũi tên hướng xuống trên nút Chèn và chọn Chèn và Liên kết
Bây giờ mỗi khi bạn đóng và mở lại tệp excel của bạn, bạn sẽ thấy hình ảnh được cập nhật (nếu nó được thay đổi)

— Anmol Saraf
nguồn