Trong Outlook2010, có cách nào để xem lời nhắc hiện đang báo lại không?

Có cách nào trong Outlook 2010 để hiển thị danh sách các mục hiện đang được báo lại không? Ví dụ: giả sử hai tuần tôi đặt một lời nhắc bật lên vào thứ Sáu cho một cuộc họp ăn trưa quan trọng vào thứ Hai tuần sau (tôi muốn được nhắc nhở về các nhiệm vụ thứ Hai trước cuối tuần). Khi lời nhắc bật lên vào thứ Sáu, tôi đã báo lại trong ba ngày để nó sẽ bật lại ngay trước bữa trưa vào thứ Hai. Sau đó, thứ Hai lăn lộn và trí nhớ của tôi mờ nhạt và tôi hơi hoang tưởng rằng tôi đã vô tình bỏ qua lời nhắc nhở vào thứ Sáu thay vì báo lại chính xác. Tôi vẫn có thể thấy cuộc hẹn ban đầu trên lịch của mình, nhưng tôi cần đảm bảo rằng tôi thực sự sẽ có lời nhắc bật lên khi tôi mong đợi nó để tôi không bỏ lỡ cuộc họp của mình.

Có cách nào trong Outlook 2010 để hiển thị danh sách các lời nhắc hiện đang được báo lại không? Điều này cũng sẽ hữu ích cho những trường hợp tôi hoàn thành một nhiệm vụ mà lời nhắc nhở tôi đã báo lại cho đến sau này và bây giờ tôi muốn kéo lên lời nhắc đã được báo lại và hủy nó.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Nếu bạn không quen thuộc với VBA, hãy xem trang giải thích của Slipstick . Bạn sẽ tìm thấy thông tin về:

• cài đặt bảo mật vĩ mô;
• nơi để đặt mã (Bạn có thể sử dụng một mô-đun thông thường với Chèn | Mô-đun); và
• Làm thế nào để tạo một nút.

Theo bài đăng trên diễn đàn Xem các mục được báo lại , không thể xem danh sách các mục được báo lại. Bài đăng gợi ý rằng bạn có thể thấy một lượng thông tin hữu ích hạn chế bằng cách tạo chế độ xem tùy chỉnh hiển thị một số trường nhắc nhở.

Hãy thử nhấp vào tab Lịch, chọn Xem và Thay đổi Chế độ xem. Sau đó chọn Danh sách. Điều này xuất hiện để hiển thị một danh sách của tất cả các lời nhắc.