Làm cách nào tôi có thể tự động cập nhật Flash Player bất cứ khi nào phiên bản mới được phát hành?

Tóm lược:

Flash Player Update Service không chạy theo một lịch trình đáng tin cậy, và không tự động tải về và áp dụng bản cập nhật khi nó không chạy.

Do tầm quan trọng của việc cài đặt phiên bản Flash Player cập nhật (đối với những người trong chúng ta không sử dụng Chrome với trình phát tích hợp), tôi muốn tìm cách đảm bảo rằng các bản cập nhật mới được phát hiện kịp thời và cài đặt.

Sau đây là chi tiết về những nỗ lực của tôi để tự mình giải quyết vấn đề này ...

Phụ lục A: Dịch vụ cập nhật Flash Player

OK, quay trở lại trong Flash Player 11.2 (hoặc hơn?) Adobe đã thêm Dịch vụ cập nhật Flash Player (FlashPlayerUpdateService.exe), nó được cho là để cập nhật Flash Player ...

• Sau khi cài đặt, FPUS được cấu hình để chạy dưới dạng Dịch vụ Windows, với Loại Bắt đầu được đặt thành Thủ công.

• Một tác vụ theo lịch trình (Adobe Flash Player Updater.job) được thêm vào để bắt đầu dịch vụ này mỗi giờ.

Cho đến nay, rất tốt - thiết lập này tránh có dịch vụ chạy liên tục, nhưng đảm bảo rằng các kiểm tra được chạy thường xuyên đủ để nắm bắt mọi cập nhật nhanh chóng. Updater phần mềm của Google được cấu hình trong một thời trang tương tự, và rằng chỉ hoạt động tốt ...

... Tuy nhiên, khi tôi kiểm tra phiên bản Flash Player đã cài đặt của mình, tôi thấy đó là 11.6.602.180 , dựa trên việc xem dấu thời gian của các tệp trong C:\Windows\System32\Macromed\Flashđã được cập nhật lần cuối (hoặc cài đặt) trên Tue, 12 tháng 3, 2013 --- 3/12/13, 5:00:08 chiều .

Tôi đã thực hiện quan sát này vào Thu, ngày 25 tháng 4 năm 2013 --- 25/11/13, 7:00:00 tối và khi kiểm tra trang web của Adobe thấy rằng phiên bản Flash Player hiện tại là 11.7.700.169 .

Đó là hơn một tháng kể từ lần cập nhật cuối cùng, với một bản mới có sẵn rõ ràng trên trang web nhưng không có dấu hiệu nào cho thấy việc kiểm tra hàng giờ chạy trên máy của tôi đã nhận thấy nó hoặc có bất kỳ ý định tải xuống nào.

Phụ lục B: chạy trình cập nhật Flash Player theo cách thủ công

Ngày xửa ngày xưa, việc chạy sẽ cung cấp cho bạn một cửa sổ với nút Cài đặt ; nhấn nó sẽ tải xuống trình cài đặt cho phiên bản hiện tại (tự động, không cần mở trình duyệt) và chạy nó, sau đó bạn nhấp vào trình cài đặt đó và hoàn tất. Đó là thủ công, nhưng nó đã làm việc! Tìm thấy cài đặt hiện tại của tôi đã lỗi thời (xem Phụ lục A), lần đầu tiên tôi đã thử quy trình cập nhật thủ công này. Tuy nhiên...FlashUtil32_<version>_Plugin.exe -update plugin

• Chạy (trong trường hợp của tôi, đó là ) ... chỉ hiển thị một cửa sổ có nút Tải xuống, nhấp vào nút Tải xuống đó sẽ mở trình duyệt của tôi tới URL https://get3.adobe.com/flashplayer/update/activex .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• Chạy (trong trường hợp của tôi, đó là ) ... chỉ hiển thị một cửa sổ với nút Tải xuống, nhấp vào nút Tải xuống đó sẽ mở trình duyệt của tôi tới URL https://get3.adobe.com/flashplayer/update/plugin .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

Tôi có thể tiếp tục với trang Tải xuống mà nó đã gửi cho tôi, bỏ chọn hộp foistware ("Miễn phí! McAfee Security Scan Plus"), tải xuống trình cài đặt đó (ActiveX, không có foistware: install_flashplayer11x32axau_mssd_aih.exe, Plugin, không có foistware: install_flash_ có thể đã có Flash cập nhật ... nhưng sau đó, điểm của Dịch vụ cập nhật Flash Player là gì nếu tôi phải tải xuống và chạy một exe khác theo cách thủ công?

Phần kết

Kể từ đó, tôi đã nghi ngờ rằng dịch vụ cập nhật có chủ ý cố tình lái những người dùng đầu tiên đến trang tải xuống thủ công. Nếu điều này là đúng, có lẽ không có giải pháp nào cho việc viết bản cập nhật của riêng tôi; hy vọng tôi sai

Có lẽ trình cập nhật chỉ áp dụng các bản cập nhật trong phạm vi 11.6.x?

Bạn luôn có thể sử dụng các liên kết trực tiếp đến các trình cài đặt mà tôi thấy đáng tin cậy hơn: ActiveX ; Plugin .

Với tệp .bat này, nó sẽ thử tự động cập nhật hoặc cài đặt trình phát flash cho Internet Explorer, Firefox (SeaMonkey, v.v.), dựa trên Chromium (Chrome, Opera 15+, v.v.):

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

Yêu cầu wget bạn có thể tải xuống ở đây và cần đặt nó vào cùng thư mục nơi .bat được đặt.

Một ví dụ nâng cao hơn một chút được viết bằng Autoit .

Tính năng: Kiểm tra đơn giản cho phiên bản mới, nếu ở đây không có phiên bản mới thì thoát chương trình mà không tải xuống trình cài đặt flash player. Nếu trình cài đặt tải xuống không thành công thì hiển thị hộp thông báo có lỗi và thoát. Cửa sổ nhắc lệnh ẩn. Đừng cần wget.

Sau khi cài đặt Autoit và Editor . Nhấp chuột phải vào màn hình-> Mới-> Autoit Script. Nhấp chuột phải vào tập tin đã tạo này-> Chỉnh sửa. Bây giờ bạn sẽ thấy cửa sổ ScITE và sau dòng "Thêm mã của bạn bên dưới đây" thêm mã này:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Sau đó, trong cửa sổ SciTE, nhấn Công cụ-> Xây dựng hoặc nhấn F7. Bây giờ bạn sẽ có được tệp thực thi độc lập trong cùng thư mục có tập lệnh Autoit.

Tôi khuyên bạn nên tạo thư mục mới (có quyền truy cập ghi) cho "trình cập nhật" này. Bạn có thể thêm lối tắt vào "trình cập nhật" này để khởi động .

Ở đây ứng dụng để gỡ cài đặt flash player.

Chỉ là, tôi muốn chia sẻ tập lệnh bó của mình với bạn, chỉ cần lưu đoạn mã này vào notepad của bạn và đặt tên là Download_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************