Tại sao kịch bản của tôi không hoạt động?

Các kịch bản tôi đang sử dụng là
FOR /F "tokens=91 delims=<>" %%v IN ('curl http://ci.onarandombox.com/job/Multiverse-Core/lastStableBuild/api/xml') DO ECHO %%v
gì tôi muốn nó phải làm là tìm kiếm đầu ra của
curl http://ci.onarandombox.com/job/Multiverse-Core/lastStableBuild/api/xml
(sao chép và dán url để xem nó. Ở dấu nhắc lệnh, lệnh đặt nó trên cùng một dòng mặc dù)
cho <artifact><displayPath> **THIS BIT HERE** </displayPath>và echo kết quả. Tuy nhiên, khi tôi chạy nó, nó sẽ hiển thị thông tin tải xuống cURL, nhưng không lặp lại bất cứ điều gì. Tôi cần gì để thay đổi trong kịch bản của mình?

Vấn đề là "tokens=91", số mã thông báo tối đa được phép là 31. Bạn cần một kỹ thuật đặc biệt để xử lý các tệp xml như vậy với hơn 3000 ký tự trên mỗi dòng. Kỹ thuật này nằm ngoài phạm vi của một câu trả lời tại SU.

BTW: nếu bạn muốn kiểm tra số lượng mã thông báo tối đa, bạn có thể sử dụng mã sau đây:

@echo off &setlocal enabledelayedexpansion
set /a maxtok=40
set /a curtok=0

for /l %%i in (1,1,%maxtok%) do set "tokvar=!tokvar! %%i"
echo variable with tokens: %tokvar%
:tokloop
set /a curtok+=1
set "disptok="
for /f "tokens=%curtok%" %%i in ("%tokvar%") do set "disptok=%%i"
echo %disptok% ^<-- there should be number %curtok%
if %curtok% lss %maxtok% goto :tokloop

Ngay lập tức, bạn có thể thử đoạn mã sau sau khi tải xuống xml và đặt nó vào một tệp ( file.xml):

@echo off &setlocal
set "xmlfile=file.xml"
set "prefix=<artifact><displayPath>"

for /f "delims=" %%i in (%xmlfile%) do if not defined xmlline set "xmlline=%%i"
setlocal enabledelayedexpansion
:xmlloop
set /a xmlcount+=1
set "xmlline=!xmlline:*%prefix%=!"
for /f "delims=<" %%i in ("%xmlline%") do set "line%xmlcount%=%%i"
if %xmlcount% lss 3 goto:xmlloop
echo %line1%
echo %line2%
echo %line3%