Cách tính dựa trên nhiều điều kiện

Tôi đang cố gắng tạo ra công thức sau đây

=SUM(IF(AND(K3:K138="Tekken",L3:L138="American Football"),1))

Tuy nhiên, nó dường như luôn dẫn đến số không, ngay cả khi một hàng duy nhất sẽ có cả hai giá trị cho Tekken và Bóng đá Mỹ. Tôi đã có được công thức đơn giản hơn để làm việc ...

=SUM(IF(K3:K138="Tekken",1))

Công thức này hoạt động tốt và đếm các hàng có giá trị cho Tekken. Tôi tự hỏi tại sao điều này hoạt động, nhưng kết quả trước đây có giá trị 0. Tôi có các hàng có cả hai giá trị và nên đại diện cho 1.

Có phải sử dụng AND đặc biệt khi giao dịch với Mảng không?

microsoft-excel microsoft-excel-2010 worksheet-function

— jab
nguồn

Tại sao chức năng thứ hai hoạt động trong trường hợp đó?

— tiêm

Amer đã cho bạn cách tiếp cận tốt nhất. AND không hoạt động theo yêu cầu với các công thức mảng vì nó trả về một kết quả duy nhất (TRUE hoặc FALSE) chứ không phải là một mảng kết quả, do đó, AND(K3:K138="Tekken",L3:L138="American Football")TRUE chỉ khi tất cả các giá trị trong tất cả các hàng là các giá trị văn bản được chỉ định. Trong các công thức mảng, bạn có thể mô phỏng AND với * để phiên bản này hoạt động -=SUM(IF((K3:K138="Tekken")*(L3:L138="American Football"),1))

— barry houdini

Lưu ý: đối với phiên bản thứ 2, COUNTIF tốt hơn=COUNTIF(K3:K138,"Tekken")

— barry houdini

Bạn sẽ tìm thấy các COUNTIFSchức năng sẽ phù hợp hơn cho bạn.

Vì vậy, hãy thử điều này:

=COUNTIFS(K3:K138,"Tekken",L3:L138,"American Football")

Các COUNTIFSchức năng cho phép bạn chọn nhiều dãy và các tiêu chí mà bạn muốn liên kết với phạm vi cụ thể. Sau đó cung cấp cho bạn tổng của tất cả các phạm vi phù hợp với tất cả các tiêu chí.

Điều đó nói rằng, lý do tại sao chức năng của bạn ANDkhông hoạt động là vì ANDhy vọng tất cả các giá trị trong phạm vi sẽ bằng "Tekken" (hoặc "Bóng đá Mỹ" cho phạm vi khác) trước khi nó trả về giá trị TRUE.

Thay vào đó, nếu bạn muốn sử dụng SUMvà IFbáo cáo, bạn sẽ phải lồng các IFcâu lệnh của mình vào một cái gì đó như:

=SUM(IF(K3:K138="Tekken",IF(L3:L138="American Football",1,0),0))

Chỉ cần làm rõ cho những người đọc khác, các chức năng với SUMsẽ chỉ hoạt động nếu bạn nhấn Ctrl + Shift + Enter khi nhập công thức. Điều này làm cho công thức thành một công thức mảng và nó sẽ đạt được { }xung quanh công thức. Nhưng COUNTIFScông thức không cần phải là một hàm mảng.

— Amer
nguồn