Có cách nào để phân biệt hai điều này một cách dứt khoát không?

Tôi nhận ra rằng tôi có thể tìm kiếm một thanh tác vụ hoặc nút nguồn trên Màn hình Bắt đầu, nhưng tôi quan tâm hơn đến việc có nơi nào thực sự hiển thị 8.1 Cập nhật 1. Tôi biết MS có trang này , nhưng một cách lập trình để phát hiện ra nó sẽ là tốt đẹp, đặc biệt là các ISO mới nhất có bản cập nhật được cập nhật.

Theo như tôi có thể nói, đầu ra vervà wmic osgiống nhau giữa Windows 8.1 và Windows 8.1. Cập nhật 1 và Thuộc tính hệ thống vẫn báo cáo Windows 8.1.

Phương pháp khả thi

Bên dưới có một vài tập lệnh bó có thể kiểm tra xem hệ điều hành có phải là Windows 8.1 hay không, có hoặc không có KB2919355 . Mã thoát sẽ là một trong những điều sau đây:

• 0: Windows 8.1
• 1: Cập nhật Windows 8.1 (đã cài đặt KB2919355)
• 2: Không phải Windows 8.1

Batch script A - Kiểm tra cập nhật

Đây là cách đáng tin cậy nhất. Tập lệnh trước tiên kiểm tra xem hệ điều hành có phải là Windows 8.1 hay không bằng cách so sánh phiên bản với 6.3.9600. Sau đó, tất cả các bản cập nhật đã cài đặt được truy vấn để xác minh xem bản cập nhật KB2919355 đã được cài đặt chưa.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

wmic qfe get hotfixid | findstr /i /c:"KB2919355" >nul
set /a errorlevel=%errorlevel% ^^ 1

exit /b %errorlevel%

Batch script B - Kiểm tra phiên bản xây dựng

Để thay thế, bạn có thể kiểm tra phiên bản xây dựng của Windows, phiên bản đầu tiên nhanh hơn kịch bản đầu tiên vì bạn không cần liệt kê tất cả các bản cập nhật. Vì nó sử dụng một giá trị đăng ký, nó có thể không đáng tin cậy.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=4 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "BuildLabEx" | findstr /i /c:"REG_SZ" "'
) do set /a build=%%~G

if %build% geq 17031 exit /b 1
exit /b 0

Batch script C - Kiểm tra phiên bản xây dựng (Internet Explorer)

Cũng giống như tập lệnh trước, ở đây khái niệm này tương tự ngoại trừ phiên bản Internet Explorer (IE) được kiểm tra thay thế.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=3,6 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v "svcVersion" | findstr /i /c:"REG_SZ" "'
) do set /a major=%%~G & set /a build=%%~H

if %major% equ 11 if %build% geq 17031 exit /b 1
if %major% geq 12 exit /b 1
exit /b 0

Lưu ý Tập lệnh giả định rằng mọi phiên bản IE cao hơn hoặc bằng 12 sẽ có sẵn trên hệ thống Windows 8.1 có cài đặt bản cập nhật KB2919355.

Tất cả các bản cập nhật bảo mật và không bảo mật trong tương lai cho Windows RT 8.1, Windows 8.1 và Windows Server 2012 R2 yêu cầu bản cập nhật này phải được cài đặt. Chúng tôi khuyên bạn nên cài đặt bản cập nhật này trên máy tính chạy Windows RT 8.1, Windows 8.1 hoặc Windows Server 2012 R2 để nhận các bản cập nhật tiếp theo trong tương lai.

_{Nguồn: Windows RT 8.1, Windows 8.1 và Windows Server 2012 R2 Cập nhật: Tháng 4 năm 2014}

Với những điều trên, thật hợp lý khi nghĩ rằng bất kỳ phiên bản IE mới hơn nào cũng yêu cầu cập nhật là điều kiện tiên quyết, giống như SP2 được yêu cầu để cài đặt IE 9 trên Windows Vista .

Phân tích BuildLabExchuỗi

reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" | findstr BuildLabEx

và nếu số lượng lớn hơn 17031số người dùng đã cài đặt Bản cập nhật 1.

Chúng tôi sử dụng tiện ích dòng lệnh có tên WuInstall ( http://www.wuinstall.com ) để thực hiện một số điều hữu ích xung quanh việc vá lỗi, trong số đó cho phép các tập lệnh bó để kiểm tra các bản cập nhật đã được cài đặt

Dòng lệnh để hiển thị tất cả các bản cập nhật đã cài đặt

WUInstall.exe / search / iteria "IsInstalled = 1" / offline

Để kiểm tra xem một KB nhất định đã được cài đặt chưa (có nhiều tùy chọn lọc), bạn có thể kiểm tra:

WUInstall.exe / tìm kiếm / tiêu chí "IsInstalled = 1" / offline / khớp "KB982214"

Tiện ích thực hiện một số đầu ra dòng lệnh, có thể được chuyển hướng đến một tệp xml với tùy chọn có tên / xmlout hoặc chỉ được chuyển hướng đến một tệp có ví dụ> out.txt

Tôi chỉ cần kiểm tra thư mục "winstore" trong Windows vì tôi nhận thấy đó là một sự khác biệt rõ ràng trong tất cả các phiên bản của windows.

Thậm chí có thể chạy lệnh WinStore để xem nó.

Kiểm tra mô phỏng hệ điều hành REM: Cài đặt c: cd \ if tồn tại "c: \ windows \ WinStore" goto WIN8

: Win8 Mã đặc biệt cho máy win8