Làm cách nào để tôi viết một công thức trong excel cho phép tôi đánh giá nếu mỗi giá trị trong một hàng là TRUE?

3

Về cơ bản, tôi muốn cách hiệu quả nhất để làm một cái gì đó như sau theo cách hiệu quả nhất có thể và với nhiều cột hơn:

=and(f2=true,g2=true,h2=true,i2=true)

Cảm ơn bạn.

microsoft-excel

— debryc
nguồn

10

Bạn có thể làm điều này rất chính xác với một công thức mảng. Dán đoạn sau vào thanh công thức và nhấn Ctrl+ Shift+ Enter.

=AND(F2:I2)

EDIT:
Đáp lại nhận xét của Jerry, nếu phạm vi bạn đang kiểm tra sẽ chứa bất kỳ thứ gì ngoài giá trị boolean, bạn sẽ cần sử dụng một công thức cụ thể hơn (vì tất cả văn bản, khoảng trắng và số không bằng 0 sẽ đánh giá là TRUE). Sau đây sẽ chỉ coi các ô có giá trị boolean TRUElà đúng.

=AND(F2:I2=TRUE)

Điều này cũng nên được nhập dưới dạng một hàm mảng bằng cách nhấn Ctrl+ Shift+ Enter.

Nếu tình cờ bạn muốn tính cả hai TRUEvà 1là đúng, bạn có thể sử dụng công thức mảng phức tạp hơn này (được nhập bằng Ctrl+ Shift+ Enter).

=AND(NOT(ISERROR(MATCH(F2:I2,{TRUE,1},0))))

— Xuất sắc
nguồn

Điều này chắc chắn là con đường để đi.

— LPChip

Bằng cách nào đó, tôi đã có ấn tượng rằng tất cả các công thức mảng không hoạt động AND(). Hóa ra điều đó chỉ áp dụng khi có nhiều hơn một điều kiện! +1 Mặc dù vậy, tôi thích các công thức không phải là mảng khi có thể.

— Jerry

@Jerry Tôi biết ý của bạn về việc ANDkhông làm việc trong các công thức mảng. Nó hoạt động như một trình tổng hợp (không chắc đó là thuật ngữ phù hợp) như SUM, MINvà SUMPRODUCT, nghĩa là, nó có thể lấy một mảng làm đối số, nhưng nó chỉ trả về một giá trị, không bao giờ là một mảng các giá trị. Vì vậy, nếu bạn cố gắng nhấn ANDvào dịch vụ trong điều kiện của một IFcông thức mảng, nó sẽ không trả về mảng các giá trị T / F mà bạn có thể đang tìm kiếm, mà là một T / F duy nhất. Cùng đi cho OR.

— Xuất sắc

6

Bạn có thể làm một cái gì đó như thế này cho ngắn hơn:

=COUNTIF(F2:I2,TRUE)=4

Điều này đếm số lượng TRUEvà kiểm tra nếu có 4.

Hoặc nếu bạn không muốn 'đếm' chúng và đặt số ...

=COUNTIF(F2:I2,TRUE)=COUNTA(F2:I2)

Ở trên sẽ không xem xét các ô trống. Nếu bạn cũng muốn đếm chúng:

=COUNTIF(F2:I2,TRUE)=COUNTA(F2:I2)+COUNTBLANK(F2:I2)

— Jerry
nguồn

2

Một lựa chọn khác là sử dụng thực tế là TRUE đánh giá thành 1 và FALSE ước tính thành 0 trong một số trường hợp nhất định.

Mô tả đánh giá TRUE và FALSE

Sử dụng liên kết ở trên, bạn có thể sử dụng chức năng

=product(F2:I2*1)

sẽ đánh giá 1 nếu tất cả đều đúng và 0 nếu có bất kỳ sai lệch hoặc khoảng trống nào.

chức năng này cần được nhập bằng cách nhấn ctrl + shift + enter vì đây là công thức mảng.

— gtwebb
nguồn

Nhưng nếu có 1và TRUEtrong dữ liệu, công thức đó sẽ đếm 1như TRUElà tốt, mà tôi không nghĩ là để dành. Nhưng tốt, nếu phạm vi của OP chỉ có thể chứa boolean, không có cách nào điều này có thể sai.

— Jerry