Số màu khác nhau trong emacs

Tôi muốn tô màu các số khác với các ký tự văn bản trong emacs cho bất kỳ chế độ nào có emacs. Làm cách nào để sửa đổi tệp .emacs cho mục đích này? Tôi muốn số của tôi luôn luôn hiển thị màu hồng.

Gvim dường như đã tích hợp sẵn tính năng này.

emacs

— smilebuddha
nguồn

Đó là vào đêm khuya ở đây, nơi tôi đang ở và tôi chỉ thử nghiệm một lần này:

(add-hook 'text-mode-hook (lambda () (font-lock-add-keywords nil (list (list "\\([0-9]+\\)" '(0 font-lock-warning-face t)) ))))

Điều đó sẽ đưa bạn đi đúng hướng - cái móc dành cho chế độ chính text-mode. Bạn có thể điều chỉnh regrec khi cần thiết.

— luật

Có chế độ số nổi bật trên melpa và cũng có sẵn ở đây .

— amitp

Sử dụng - kích hoạt hoặc hủy kích hoạt cục bộ với: M-x smilingbuddha-mode

Để kích hoạt smilingbuddha-mode trên toàn cầu , không ghi chú (global-smilingbuddha-mode)và khởi động lại; hoặc, gõ M-x global-smilingbuddha-mode(sẽ vẫn có hiệu lực cho đến khi bạn khởi động lại).

Xin vui lòng sửa đổi regrec cho phù hợp với nhu cầu cá nhân của bạn.

(define-minor-mode smilingbuddha-mode
  "Minor mode for highlighting numbers."
  :group 'smilingbuddha
  :lighter " :)"
  (cond
    (smilingbuddha-mode
      (when (not (or font-lock-mode global-font-lock-mode))
        (font-lock-mode 1))
      (font-lock-add-keywords nil
        (list (list "\\([0-9]+\\)" '(0 'smilingbuddha-pink-face t)) ))
      (message "Turned ON `smilingbuddha-mode`."))
    ((not smilingbuddha-mode)
      (font-lock-remove-keywords nil
        (list (list "\\([0-9]+\\)" '(0 'smilingbuddha-pink-face t)) ))
      (font-lock-fontify-buffer)
      (message "Turned OFF `smilingbuddha-mode`."))))

(defgroup smilingbuddha nil
  "Highlight numbers."
  :version "0.1"
  :group 'smilingbuddha)

(defface smilingbuddha-pink-face
  '((t (:foreground "black" :background "pink")))
  "Face for `smilingbuddha-pink-face`."
  :group 'smilingbuddha)

(defun turn-on-smilingbuddha-mode ()
(interactive)
  (smilingbuddha-mode 1))

(defun turn-off-smilingbuddha-mode ()
(interactive)
  (smilingbuddha-mode -1))

(define-globalized-minor-mode global-smilingbuddha-mode
  smilingbuddha-mode turn-on-smilingbuddha-mode)
;; (global-smilingbuddha-mode)

— danh sách luật
nguồn