Tính số ngày chủ nhật trong tháng

8

Trong Microsoft Excel, tôi đang tìm cách xác định số ngày chủ nhật trong bất kỳ tháng nào. Tôi đang kết hợp một bảng tính ngân sách và một số tài khoản phụ được tài trợ thêm khi năm Chủ nhật trong tháng thay vì bốn.

Ô duy nhất tôi phải tham chiếu là tiêu đề của trang tính trong Ô A1 và bằng với tháng hiện tại. Ví dụ6/1/14

— wbeard52
nguồn

12

Hãy thử đây A1là ngày bắt đầu của tháng:

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))),"ddd")="Sun"))

Bạn cũng có thể sử dụng điều này cho bất kỳ ngày nào trong tuần chỉ cần thay đổi "Sun"và bất kỳ phạm vi ngày nào bằng cách thay thế A1bằng ngày bắt đầu và EOMONTH(A1,0)ngày kết thúc.

— Jay-ar
nguồn

1

Ồ Điều này thực sự sáng tạo. Hãy để tôi hiểu. Chúng ta tạo các giá trị ngày cho cả tháng bằng các hàm gián tiếp và hàng? Sau đó, chúng tôi chuyển đổi chúng thành văn bản dưới dạng Mặt trời, Thứ Hai, v.v. Chúng tôi đánh giá tình trạng của Mặt trời và thay đổi kết quả thành một hoặc bằng 0 và sau đó tổng hợp kết quả. Đúng không?

— wbeard52

yup chính xác .. :)

— Jay-ar

9

Nếu ngày bạn đề cập luôn luôn là ngày đầu tiên của tháng, thì ngày này cũng sẽ hoạt động:

=INT((WEEKDAY(A1-1)+EOMONTH(A1,0)-A1)/7)

— teylyn
nguồn

Đơn giản. Rất thanh lịch so với công thức của tôi ở trên. Cảm ơn.

— wbeard52

3

Rất giống với câu trả lời trước đó, nhưng chỉ cần sạch hơn một chút ...

=SUMPRODUCT(N(WEEKDAY(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))))=1))

— người dùng743733
nguồn

3

=DAY(EOMONTH(A1,0))-NETWORKDAYS.INTL(A1,EOMONTH(A1,0),11)

EDIT: Điều này hoạt động trong Excel 2016, không chắc chắn khi NETWORKDAYS.INTL được giới thiệu.

— SRCP
nguồn

Networkday là gì. Tôi không hoạt động với tất cả excel

— yass

À, bạn nói đúng. Tôi không thấy anh ấy đề cập đến Excel 2010. Tôi có 2016. Không giống như các ngày mạng, Networkday.intl cho phép bạn chọn các ngày cuối tuần. Trong trường hợp này, tôi đã nói với Excel rằng cuối tuần chỉ là Chủ nhật, đó là những gì 11 đại diện. Vì vậy, nó cung cấp cho bạn số ngày trong một khoảng thời gian không kể chủ nhật.

— SRCP

NETWORKDAYS.INTLcó sẵn kể từ Excel 2010 . Bạn có thể thấy số 2010 bên cạnh tên của nó. xem ảnh chụp màn hình của nó hoạt động trong Excel 2010

— phuclv

1

Tôi tin rằng tôi đã tìm thấy một cách khác để lột da con mèo này (có thể nói như vậy).

Nếu, bạn muốn tránh nhập ngày và có một bảng lớn để chiếu (ví dụ: hết 18 tháng) thì bạn có thể chỉ cần nói cho công thức biết tháng và năm của bạn là gì và có định dạng phù hợp. Điều này được kết hợp với một tham chiếu tuyệt đối đến một ô tiêu đề chứa ngày trong tuần và bạn có một bảng gọn hơn và gọn gàng hơn (theo ý kiến của tôi).

A3 = Jan, B3 = 2017, C2: I2 = 3 Tên viết tắt của Ngày Char (tức là CN)

Nhập công thức vào ô C3

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy"))&":"&EOMONTH(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy")),0))),"ddd")=C$2))

Đi săn vui nhé

— Diễn viên Jeremy
nguồn

1

Một biến thể nhỏ của câu trả lời được chấp nhận , nơi bạn không cần ngày đầu tiên của tháng A1.

Điều này đạt được bằng cách thay thế A1bằng:

date(year(today()),month(today()),1)

Điều này là giả sử rằng bạn muốn nó cho tháng hiện tại.

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(date(year(today()),month(today()),1)&":"&EOMONTH(date(year(today()),month(today()),1),0))),"ddd")="Sun"))

— CalvT
nguồn