Lật trục x và y trong biểu đồ Excel

Điều này không phải là rất khó khăn, nhưng tôi không thể tìm ra cách để làm điều đó.

Tôi có một bảng tương tự như thế này

   %low %high
 0   0   12
 1  13   26
 ...
19  90   94
20  95  100

Khi tôi vẽ biểu đồ, excel mặc định có cột đầu tiên trên trục x và vẽ cột thứ hai và thứ ba dưới dạng giá trị y. Tôi muốn cột đầu tiên nằm trên trục y thay thế. Tôi cho rằng có một cách dễ dàng để làm điều này, nhưng tôi không thể tìm ra nó. Hầu hết những điều tôi tìm thấy từ tìm kiếm đã đề xuất nút "Chuyển hàng / Cột", nhưng điều đó lại làm một việc khác.

Cảm ơn đã giúp đỡ.

Bạn có thể tự chọn những gì bạn muốn vẽ biểu đồ.

Đây là dữ liệu mẫu của tôi:

Tôi chọn để tạo một biểu đồ phân tán. Khi chỉnh sửa nguồn dữ liệu, tôi nhấp vào nút Thêm.

Bạn có thể chọn bất cứ điều gì bạn muốn cho tên loạt nhưng tôi chọn tiêu đề cột. Tất nhiên các giá trị X là các giá trị trong cột X của bạn. Giá trị Y là một trong các cột Y.

Lặp lại quy trình cho bộ dữ liệu thứ hai.

Đây là một thói quen VBA đơn giản tạo biểu đồ phân tán XY từ dữ liệu được sắp xếp với Y trong cột đầu tiên và một hoặc nhiều bộ X trong dữ liệu tiếp theo. Chọn phạm vi dữ liệu hoặc chọn một ô trong phạm vi đó và chạy mã.

Sub ChartFromInput_YXX()
    ' assumes first column of input range has Y values
    ' assumes subsequent columns have X values
    ' assumes first row of input range has series

    Dim rngDataSource As Range
    Dim iDataRowsCt As Long
    Dim iDataColsCt As Integer
    Dim iSrsIx As Integer
    Dim chtChart As Chart
    Dim srsNew As Series

    If Not TypeName(Selection) = "Range" Then
        '' Doesn't work if no range is selected
        MsgBox "Please select a data range and try again.", _
            vbExclamation, "No Range Selected"
    Else
        Set rngDataSource = Selection
        If rngDataSource.Cells.Count = 1 Then
            ' expand to data range including active cell
            Set rngDataSource = rngDataSource.CurrentRegion
        End If
        With rngDataSource
            iDataRowsCt = .Rows.Count
            iDataColsCt = .Columns.Count
        End With

        '' Create the chart
        Set chtChart = ActiveSheet.Shapes.AddChart.Chart

        With chtChart
            .ChartType = xlXYScatterLines

            '' Remove any series created with the chart
            Do Until .SeriesCollection.Count = 0
                .SeriesCollection(1).Delete
            Loop

            For iSrsIx = 1 To iDataColsCt - 1
                '' Add each series
                Set srsNew = .SeriesCollection.NewSeries
                With srsNew
                    .Name = rngDataSource.Cells(1, 1 + iSrsIx)
                    .Values = rngDataSource.Cells(2, 1) _
                        .Resize(iDataRowsCt - 1, 1)
                    .XValues = rngDataSource.Cells(2, 1 + iSrsIx) _
                        .Resize(iDataRowsCt - 1, 1)
                End With
            Next
        End With
    End If
End Sub

Nếu bạn cần một nhiệm vụ lặp đi lặp lại, giải pháp được chấp nhận có thể tốn thời gian. Jon Peltier vĩ đại có một bổ trợ đơn giản cho điều này Xem trang của anh ấy .

Như đã nói ở cái khác trang tài liệu :

Chuyển trục XY

Đây là một trình giữ chỗ cho trang tài liệu cho Switch XY Axes.

Tức là, không có tài liệu có sẵn. Tuy nhiên, nó thực sự đáng để thử nó. Nó thực sự dễ học.