Vấn đề này có một số lượng lớn các kết hợp có thể:
- khi các cuộc gọi đến liên quan đến tuần làm việc, ngày làm việc và bữa trưa
- có hay không các bộ phận được yêu cầu
- khi yêu cầu bộ phận được đặt tương đối với tuần làm việc, ngày làm việc, bữa trưa và cuộc gọi đến
- cho dù các bộ phận đến kéo dài một ngày cuối tuần hoặc thậm chí vài ngày cuối tuần nếu chúng không có sẵn
- liệu công văn công nghệ so với cuộc gọi đến và / hoặc công nghệ công nghệ so với các bộ phận đến kéo dài một ngày cuối tuần
- tất cả các kết hợp có thể và hoán vị của ở trên.
Tôi không thể thấy một cách để sử dụng một công thức chung để chỉ đếm mọi thứ. Dường như đối với mỗi kịch bản phản hồi, bạn cần lập mô hình chính xác khi mỗi hoạt động xảy ra liên quan đến tuần làm việc, ngày làm việc và bữa trưa, và cộng và trừ thời gian liên quan. Các quy tắc trở nên rất phức tạp, và điều này là không liên quan đến các ngày lễ, mà sẽ thêm một chiều bổ sung.
Về mặt kỹ thuật có thể làm điều này với một "công thức", nhưng nó sẽ dài và phức tạp đến mức bạn sẽ không bao giờ có thể khắc phục sự cố hoặc sửa đổi nó, hoặc có ý nghĩa của nó sau thực tế. Vì vậy, câu trả lời này sẽ sử dụng một loạt các cột khối xây dựng (một số trong đó có một số công thức dài), và các cột này được trộn lẫn và khớp và sử dụng lại. Nó sẽ cung cấp một cơ sở để sửa đổi mọi thứ.
Tôi đã tạo ra một kịch bản cực đoan, phức tạp nhất mà tôi có thể nghĩ ra để kiểm tra nó. Có thể giải pháp này quá phức tạp vì có một số tình huống không xảy ra trong cuộc sống thực. Bạn được chào đón để đơn giản hóa nó.
Các cột khối xây dựng
Ngày & amp; Thời đại
Excel lưu trữ ngày / lần dưới dạng một số. Toàn bộ phần số là một số ngày và phần phân số là thời gian dưới dạng phân số thập phân của một ngày. Các phần khác nhau của công thức cần sử dụng chỉ vài ngày hoặc chỉ vài lần, vì vậy tám khối xây dựng đầu tiên tách chúng ra. Cột K xuyên qua N là những ngày cho các cột C xuyên qua F và cột O xuyên qua R là thời đại Nó không tạo ra nhiều khác biệt như thế nào bạn định dạng các cột này. Các công thức sẽ mang lại số (ngày sẽ là số chỉ khoảng 42000, thời gian sẽ là phân số thập phân - buổi trưa hoặc 12 giờ sẽ là 0,5). Giả sử dữ liệu của bạn bắt đầu ở hàng 2:
K2: =INT(C2)
L2: =INT(D2)
M2: =INT(E2)
N2: =INT(F2)
O2: =MOD(C2,1)
P2: =MOD(D2,1)
Q2: =MOD(E2,1)
R2: =MOD(F2,1)
Thời gian đặt hàng thô và thời gian đặt hàng
Có một số cách để xử lý thời gian đặt hàng các bộ phận. Một là tính toán thời lượng và trừ nó ra. Trong vấn đề này, điều đó thêm một sự phức tạp khác bởi vì bạn không muốn tính hai lần loại trừ cho bữa trưa hoặc cuối tuần. Tôi đã sử dụng một cách tiếp cận khác nhau, chia vấn đề thành hai phần trong trường hợp các bộ phận được đặt hàng - điều gì xảy ra để đặt hàng các bộ phận và điều gì xảy ra sau khi các bộ phận được nhận; tất cả thời gian ở giữa bị bỏ qua.
Điều này đòi hỏi ba thời lượng:
- nhận cuộc gọi đến bộ phận đặt hàng
- bộ phận tiếp nhận công văn
- nhận cuộc gọi đến công văn cho các trường hợp không có bộ phận được yêu cầu
Một số công thức yêu cầu thời gian trôi qua thực tế, một số công thức khác yêu cầu đếm ngày bất kể thời gian trong ngày, do đó, có sáu cột khối xây dựng. Những thời lượng trừ đi bất kỳ cuối tuần. Tôi giả định rằng một ngày cuối tuần có thể có thể xảy ra giữa nhận cuộc gọi và đặt hàng bộ phận (cuộc gọi đến vào cuối ngày thứ Sáu) hoặc giữa các bộ phận nhận vào cuối ngày thứ Sáu và công văn vào thứ Hai. Cột S xuyên qua U là thời gian trôi qua thực tế. Cột V xuyên qua X là số ngày.
S2: =D2-C2-IF(WEEKDAY(C2,2)+L2-K2>5,2,0)
T2: =F2-E2-IF(N2-M2+WEEKDAY(E2,2)>5,2,0)
U2: =F2-C2-INT((N2-K2+WEEKDAY(C2,2))/7)*2
V2: =L2-K2-IF(WEEKDAY(C2,2)+L2-K2>5,2,0)
W2: =N2-M2-IF(N2-M2+WEEKDAY(E2,2)>5,2,0)
X2: =N2-K2-INT((N2-K2+WEEKDAY(C2,2))/7)*2
Lưu ý rằng một điều chỉnh khác nhau cho cuối tuần được sử dụng cho trường hợp "không có bộ phận". Điều này là do trường hợp thử nghiệm cực đoan của tôi bao gồm một ngày cuối tuần giữa khi đến cuộc gọi và đặt hàng bộ phận, một sự chậm trễ lâu cho các bộ phận đến và một cuối tuần khác giữa các bộ phận đến và công nghệ. Đối với kịch bản "không có phần", tôi chỉ sử dụng toàn bộ thời gian, bao gồm hai ngày cuối tuần, vì vậy công thức cần thiết để xử lý điều đó. Nếu bạn thực hiện bất kỳ công nghệ nào cần hai tuần để trả lời cuộc gọi, bạn có thể thay đổi điều đó thành cùng loại điều chỉnh một ngày cuối tuần được sử dụng trong các công thức khác nếu bạn muốn thống nhất.
Thời gian đủ điều kiện
Bước tiếp theo là đối phó với các khung thời gian trong ngày làm việc. Tôi đã phá vỡ vấn đề thành ba khoảng.
- Ngày đầu tiên (thời gian thích hợp bắt đầu khi có cuộc gọi đến và có thể có nhiều điểm kết thúc khác nhau)
- Ngày cuối cùng (thời gian thích hợp có thể có nhiều điểm bắt đầu và kết thúc với công văn
- Ngày giữa (đây là tất cả các ngày và cần điều chỉnh cho cuối tuần)
Tất cả các hoạt động có thể xảy ra trong một hoặc hai ngày, vì vậy các công thức cần kiểm tra xem liệu khoảng thời gian cụ thể có tồn tại và chưa được tính. Các công thức là khác nhau tùy thuộc vào việc yêu cầu đặt hàng các bộ phận, do đó, có hai công thức cho mỗi khoảng (yêu cầu các bộ phận là đầu tiên trong mỗi bộ).
First Day
Y2: =IF(L2=K2,IF(M2=K2,IF(N2=K2,R2-Q2+P2,$J$3-Q2+P2),P2),$J$3)-O2
Z2: =IF(N2=K2,R2,$J$3)-O2
Last Day
AA2: =IF(M2=N2,IF(L2=N2,IF(K2=N2,0,P2-$J$2+R2-Q2),R2-Q2),R2-$J$2)
AB2: =IF(K2=N2,0,R2-$J$2)
Days Between
AC2: =IF(L2=K2,0,IF(M2=L2,IF(N2=L2,0,$J$3-Q2+P2-$J$2+(L2-K2-1-INT((L2-K2+WEEKDAY(C2,2))/7)*2)*
($J$3-$J$2)),P2-$J$2+(L2-K2-1-INT((L2-K2+WEEKDAY(C2,2))/7)*2)*($J$3-$J$2)))+
IF(M2=L2,0,IF(N2=M2,0,$J$3-Q2+(N2-M2-1-INT((N2-M2+WEEKDAY(E2,2))/7)*2)*($J$3-$J$2)))
AD2: =IF(N2-K2>1,N2-K2-1-INT((N2-K2+WEEKDAY(C2,2))/7)*2,0)*($J$3-$J$2)
Lưu ý rằng tôi chia công thức dài cho dễ đọc. Nếu bạn muốn sao chép và dán, bạn sẽ cần xóa trả lại vận chuyển và khoảng trắng thừa.
Nghỉ trưa
Các điều chỉnh giờ nghỉ trưa xác định ngày nào có giờ nghỉ trưa áp dụng, đếm chúng và nhân số đếm với thông số giờ nghỉ trưa được lưu trữ. Một lần nữa, trường hợp cần thiết là đầu tiên:
AE2: =(IF(S2>$J$5-O2,1,0)+IF(S2>P2-$J$6,1,0)+IF(V2>=2,V2-1,0)+IF(T2>$J$5-Q2,1,0)+IF(T2>R2-$J$6,1,0)+IF(W2>=2,W2-1,0))*($J$6-$J$5)
AF2: =(IF(U2>$J$5-O2,1,0)+IF(U2>R2-$J$6,1,0)+IF(X2>=2,X2-1,0))*($J$6-$J$5)
Thời gian đáp ứng công nghệ
Sau đó, thời gian đáp ứng là chọn bộ số thích hợp để kết hợp (có hoặc không cần các bộ phận) và kết hợp các phần. Ô G2:
G2: =IF(ISBLANK(D2),Z2+AB2+AD2-AF2,Y2+AA2+AC2-AE2)
Sử dụng một định dạng tùy chỉnh. Trong các định dạng, chọn định dạng thời gian gần và sau đó tùy chỉnh nó trong cửa sổ tùy chỉnh. Bạn có thể sử dụng một cái gì đó như hh:mm hoặc là hh"h "mm"m", sẽ tạo ra một kết quả như 03h 47m.
Trong Cột H, bạn muốn giờ và số thập phân. Tôi không thực hiện nhiều định dạng thời gian trong Excel, nhưng có vẻ như các định dạng tích hợp muốn xử lý chỉ trong cả giờ. Nếu tôi sai, có lẽ người khác có thể chỉnh sửa câu trả lời này bằng cách tiếp cận định dạng tốt hơn. Tôi sẽ chỉ chuyển đổi số được lưu trữ thành giờ và sau đó định dạng nó thành một số có số thập phân mong muốn:
H2: =G2*24
Điều này chuyển đổi phần thập phân của một ngày thành giờ.
Bạn có thể sao chép hàng công thức này xuống trang nếu cần. Nếu bạn không muốn xem các cột của khối xây dựng, hãy ẩn các cột đó.