Script để lưu (pin) trang web vào thanh tác vụ

Tôi điên cuồng tìm kiếm một số tài liệu tham khảo có thể giúp tôi lưu một lối tắt đến một trang web (giả sử msn.com) vào thanh tác vụ. Tôi đã tìm kiếm trong bốn ngày qua và chỉ tìm thấy tài liệu tham khảo về cách lưu shorcut vào các ứng dụng (notepad.exe hoặc Iexplorer.exe).

Theo hiểu biết của tôi, lưu bất kỳ trang web nào bao gồm hai bước

1. Tạo đường cắt ngắn
2. Lưu phím tắt (.lnk) vào thanh tác vụ.

Nhưng làm cách nào tôi có thể lưu lối tắt vào một tệp cụ thể (readme.txt / msn.com) vào thanh tác vụ? Nếu bạn có bất kỳ ý tưởng, xin vui lòng, chia sẻ với tôi.

HÃY NHỚ - Windows được thiết kế để ngăn chặn các chương trình làm phiền người dùng. Thanh tác vụ và menu bắt đầu giúp người dùng.

Kịch bản lệnh này liệt kê và chạy các động từ đối với một đối tượng shell (chỉ các tệp trên phiên bản này). Chạy mà không có tham số để nhận trợ giúp (hoặc đọc ba dòng đầu tiên).

Tôi gọi nó là ShVerb.vbs - bạn có thể điều chỉnh nó thành phím tắt r / ca và chọn Thêm vào thanh tác vụ (có thể - Tôi có Vista là hệ điều hành UI phù hợp cuối cùng).

HelpMsg = vbcrlf & "  ShVerb" & vbcrlf & vbcrlf & "  David Candy 2014" & vbcrlf & vbcrlf & "  Lists or runs an explorer verb (right click menu) on a file or folder" & vbcrlf  & vbcrlf & "    ShVerb <filename> [verb]" & vbcrlf & vbcrlf & "  Used without a verb it lists the verbs available for the file or folder" & vbcrlf & vbcrlf
HelpMsg = HelpMsg & "  The program lists most verbs but only ones above the first separator" & vbcrlf & "  of the menu work when used this way" & vbcrlf & vbcrlf 
HelpMsg = HelpMsg & "  The Properties verb can be used. However the program has to keep running" & vbcrlf & "  to hold the properties dialog open. It keeps running by displaying" & vbcrlf & "  a message box." 
Set objShell = CreateObject("Shell.Application")
Set Ag = WScript.Arguments 
set WshShell = WScript.CreateObject("WScript.Shell") 
Set fso = CreateObject("Scripting.FileSystemObject")

    If Ag.count = 0 then 
        wscript.echo "  ShVerb - No file specified"
        wscript.echo HelpMsg 
        wscript.quit
    Else If Ag.count = 1 then 
        If LCase(Replace(Ag(0),"-", "/")) = "/h" or Replace(Ag(0),"-", "/") = "/?" then 
            wscript.echo HelpMsg 
            wscript.quit
        End If
    ElseIf Ag.count > 2 then 
        wscript.echo vbcrlf & "  ShVerb - To many parameters" & vbcrlf & "  Use quotes around filenames and verbs containing spaces"  & vbcrlf
        wscript.echo HelpMsg 
        wscript.quit
    End If

    If fso.DriveExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetFileName(Ag(0)))
'       Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
        Set objFolderItem = objFolder.self
        msgbox ag(0)
    ElseIf fso.FolderExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
        Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
    ElseIf fso.fileExists(Ag(0)) = True then
        Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
        Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
    Else
        wscript.echo "  ShVerb - " & Ag(0) & " not found"
        wscript.echo HelpMsg 
        wscript.quit
    End If

    Set objVerbs = objFolderItem.Verbs

    'If only one argument list verbs for that item

    If Ag.count = 1 then
        For Each cmd in objFolderItem.Verbs
            If len(cmd) <> 0 then CmdList = CmdList & vbcrlf & replace(cmd.name, "&", "") 
        Next
        wscript.echo mid(CmdList, 2)

    'If two arguments do verbs for that item

    ElseIf Ag.count = 2 then
        For Each cmd in objFolderItem.Verbs
            If lcase(replace(cmd, "&", "")) = LCase(Ag(1)) then 
                wscript.echo(Cmd.doit)
                Exit For
            End If
        Next
    'Properties is special cased. Script has to stay running for Properties dialog to show.
        If Lcase(Ag(1)) = "properties" then
            WSHShell.AppActivate(ObjFolderItem.Name & " Properties")
            msgbox "This message box has to stay open to keep the " & ObjFolderItem.Name & " Properties dialog open."
        End If  
    End If
End If

Đây là một đoạn trích của một chương trình làm một phím tắt

                Set SC = Sh.CreateShortcut(FolderMRUPath & "\" & CurrentDirName & ".lnk")
                SC.TargetPath = CurrentDirPath
                SC.Save
                SH.RegWrite MenuOrderKey, 0 , "REG_BINARY"
                wshshell.refreshmenu