Safari Safari Tìm kiếm Tab Bàn phím tắt

Tính năng "Tìm kiếm tab" mới của Safari 8 khá hay. Khi "hiển thị tất cả các tab" được kích hoạt, bạn có thể nhập một số văn bản để lọc các tab theo ý muốn. Tuy nhiên, một khi tôi có một tab duy nhất hiển thị, sẽ rất tuyệt nếu có thể kích hoạt tab đó. Điều này sẽ cho phép chức năng loại "spotlight" cho các tab.

Tuy nhiên, dường như không có phím tắt để kích hoạt tab sau khi tôi đã tìm kiếm nó, vì vậy tôi buộc phải nhấp vào tab bằng chuột! Điều này có vẻ như là một sự giám sát, tôi không thể tin rằng Apple sẽ thêm một cách hay để lọc các tab, nhưng không có cách nào để chọn một tab!

Ảnh chụp màn hình:

Tôi đã thử các tổ hợp phím sau để thử làm điều này, nhưng không có kết quả:

• Lệnh + Trở về ... + Dung lượng
• Tùy chọn + Trả về ... + Dung lượng
• Kiểm soát + Trả lại ... + Dung lượng
• Lệnh + Shift + \ (Lệnh "Hiển thị tất cả các tab" trên Macbook của tôi)

Điều này khiến tôi tin rằng nó thực sự là một sự giám sát về phần của Apple.

Loại bỏ: Tạo một lệnh tự động hóa để mô phỏng nhấp chuột

Tôi đã sử dụng mã mà tôi tìm thấy tại https://discussions.apple.com/thread/3708948 để kết hợp các AppleScripts sau:

Nỗ lực 1: Không hoạt động Tôi đã chạy mã này trong một Applescript được bọc trong Dịch vụ tự động được ánh xạ thành "Command + Shift + Option + Control + Space", sử dụng các số tôi nhận được từ việc nhấn "Command + Control + Shift + 4" để lấy địa chỉ cho khu vực (600 pixel ngang từ trái, 300 pixel dọc từ trên xuống) và nó sẽ hoạt động trong Safari bình thường (nhấn tổ hợp phím sẽ khiến chuột nhấp vào địa chỉ pixel đó), nhưng nó không có tác dụng khi lệnh cùng khóa đã được chạy trong chế độ "Hiển thị tất cả các tab" trong Safari!

on run {input, parameters}
    tell application "System Events"
            tell process "Safari"
                click at {600, 300}
            end tell
        end tell

        return input
    end run

Nỗ lực số 2: Đã hoạt động, nhưng không khả thi

Tôi đã nhận được một lệnh chính làm việc với Applescript sau được gói trong Dịch vụ tự động, nhưng phải mất 5.125 giây để hoàn thành :(

    on run {input, parameters}

    set x to 600
    set y to 150

    do shell script "
/usr/bin/python <<END
import sys
import time
from Quartz.CoreGraphics import *
def mouseEvent(type, posx, posy):
          theEvent = CGEventCreateMouseEvent(None, type, (posx,posy), kCGMouseButtonLeft)
          CGEventPost(kCGHIDEventTap, theEvent)
def mousemove(posx,posy):
          mouseEvent(kCGEventMouseMoved, posx,posy);
def mouseclick(posx,posy):
          mouseEvent(kCGEventLeftMouseDown, posx,posy);
          mouseEvent(kCGEventLeftMouseUp, posx,posy);
ourEvent = CGEventCreate(None);
currentpos=CGEventGetLocation(ourEvent);             # Save current mouse position
mouseclick(" & x & "," & y & ");
mousemove(int(currentpos.x),int(currentpos.y));      # Restore mouse position
END"
    return input
end run

Tôi nghĩ rằng tôi đã có câu trả lời của bạn. Tôi đã dành cả ngày để tìm kiếm này. Tôi sử dụng một ứng dụng miễn phí tuyệt vời có tên BetterTouchTool (sử dụng OS X 10.10) để thêm các cử chỉ và lối tắt quảng cáo cho tất cả các thiết bị của apple và nó hoạt động ngay lập tức! Không chậm trễ!

Tôi sẽ tạo ảnh chụp màn hình với mỗi bước bạn cần cấu hình. LƯU Ý: Nó sẽ liên kết vị trí chuột dưới dạng phím tắt bạn chọn khi bạn sử dụng safari. Nhược điểm: Bạn không thể thay đổi vị trí cửa sổ của safari và vị trí của chuột sẽ khác với màn hình từ sổ ghi chép của bạn. Giải pháp: Tôi khuyên bạn nên ánh xạ vị trí chuột bằng cách sử dụng nó ở chế độ toàn màn hình với màn hình bạn sử dụng nhiều nhất (hoặc chỉ ánh xạ hai phím tắt cho mỗi màn hình)

• 1 Tải xuống ứng dụng http://www.bettertouchtool.net

• 2 Mở ứng dụng, chọn bàn phím, thêm ứng dụng vào danh sách các phím tắt bạn sẽ thêm (trong trường hợp này là Safari), chọn lối tắt của bạn (Tôi đang ánh xạ "Tùy chọn + 1" trong ảnh chụp màn hình này), sau đó, bên trong chọn Kích hoạt menu, chọn " Di chuyển chuột đến vị trí " trong "Các hành động khác của người khác". Tôi đã đánh dấu tùy chọn sai trong ảnh chụp màn hình, đó là tùy chọn ở trên. Đó không phải là "Lưu vị trí chuột". Xin lỗi tôi quá mệt, đã 3 giờ sáng và tôi phải làm việc vào ngày mai

• 3 Chọn nơi bạn muốn con trỏ đi (Vị trí trong hộp nhập sẽ kiểm tra kết quả đầu tiên khi UI hiển thị ~ 3 kết quả)

• 4 Thêm một sự kiện sau: Một sự kiện nhấp chuột trái. Và đó là nó!

Làm tương tự với một vị trí chuột khác nhau để có kết quả thứ 2, thứ 3 .. nhưng hãy nhớ rằng ui sẽ thay đổi nếu kết quả lớn hơn, đôi khi thậm chí ẩn kết quả đầu tiên.

Tôi đã sử dụng Applescript để làm điều này từ trước khi họ thêm tính năng này:

http://apse-www.harvard.edu/~fine/OSX/safari-tabs.html

Nó bật lên một hộp thoại tìm kiếm, bạn nhập tìm kiếm của mình và ngay lập tức kích hoạt một tab phù hợp hoặc cung cấp cho bạn một hộp thoại để chọn từ danh sách các tab phù hợp. Nó đưa cửa sổ ra phía trước và làm cho đây là tab hoạt động trong cửa sổ.

(Tôi có một kịch bản tương tự để tìm các cửa sổ Terminal.)

Tôi đến bữa tiệc muộn một chút, nhưng tôi nghĩ Shortcat sẽ thực hiện các chức năng cần thiết.

Với phần thưởng được thêm vào như vậy nó có thể được sử dụng với Mail, v.v.

Sử dụng Automator và dán AppleScript gắn nó vào phím tắt như được mô tả trong:

Làm cách nào để gán phím tắt cho AppleScript mà tôi đã viết?

set question to display dialog ("Find Safari tab:") default answer ""
set searchpat to text returned of question

tell application "Safari"
    set winlist to every window
    set winmatchlist to {}
    set tabmatchlist to {}
    set tabnamematchlist to {}
    repeat with win in winlist
        set ok to true
        try
            set tablist to every tab of win
        on error errmsg
            --display dialog name of win as string
            set ok to false
        end try
        if ok then
            repeat with t in tablist
                if searchpat is in (name of t as string) then
                    set end of winmatchlist to win
                    set end of tabmatchlist to t
                    set end of tabnamematchlist to (id of win as string) & "." & (index of t as string) & ".  " & (name of t as string)
                    --display dialog name of t as string
                else if searchpat is in (URL of t as string) then
                    set end of winmatchlist to win
                    set end of tabmatchlist to t
                    set end of tabnamematchlist to (id of win as string) & "." & (index of t as string) & ".  " & (name of t as string)
                    --display dialog name of t as string
                end if
            end repeat
        end if
    end repeat
    if (count of tabmatchlist) = 1 then
        --display dialog "one!"
        set w to item 1 of winmatchlist
        set t to item 1 of tabmatchlist
        set current tab of w to t
        set index of w to 1
    else if (count of tabmatchlist) = 0 then
        display dialog "No matches"
    else
        set whichtab to choose from list of tabnamematchlist with prompt "The following tabs match, please select one:"
        set AppleScript's text item delimiters to "."
        if whichtab is not equal to false then
            set tmp to text items of (whichtab as string)
            set w to (item 1 of tmp) as integer
            set t to (item 2 of tmp) as integer
            set current tab of window id w to tab t of window id w
            set index of window id w to 1
        end if
    end if
end tell