Làm cách nào để chuyển đổi giữa nhiều cửa sổ toàn màn hình của cùng một ứng dụng trong OS X? [bản sao]

Khi tôi đang chạy một số phiên bản của cùng một ứng dụng (có thể là các cửa sổ riêng biệt của Chrome hoặc một số dự án IntelliJ) ở chế độ toàn màn hình, tôi không thể điều hướng đến ứng dụng cụ thể bằng cách sử dụng ⌘-Tab, nó sẽ chỉ hiển thị một biểu tượng của ứng dụng nhưng có một số biểu tượng của ứng dụng chạy trong nền.

Ngoài ra không có phím tắt cụ thể cho ứng dụng để làm như vậy.

Có cách nào để tạo các ⌘-Tabphiên bản hiển thị thay vì biểu tượng ứng dụng toàn cầu không?

Thật không may, không có phím tắt để chuyển giữa các cửa sổ toàn màn hình của cùng một ứng dụng.

Bạn có hai lựa chọn không lý tưởng nhưng đủ:

1. Các phím tắt để chuyển giữa các không gian / máy tính để bàn hoặc chuyển đến một không gian cụ thể

2. Cử chỉ để chuyển giữa các không gian / máy tính để bàn

Để làm cho công việc này hoạt động tốt, chỉ cần đặt các cửa sổ toàn màn hình của bạn cạnh nhau .

Ngoài Mission Control, còn có Dock.

Khi bạn nhấp liên tục, nó sẽ quay vòng qua các không gian toàn màn hình của ứng dụng.

Nếu bạn biết cách liên kết một applescript với cử chỉ bàn phím / trackpad, đây là câu trả lời cho bạn.

Kịch bản có nghĩa là phổ quát. Nó sử dụng các thuật ngữ tổng quát nhất để bao gồm càng nhiều kịch bản càng tốt. Tôi đã thử nghiệm trên Finder, Script Editor và Firefox. Không có lỗi.

Tuy nhiên, nó có cảnh báo:

1. Kịch bản chỉ hoạt động khi chỉ có một phiên bản của ứng dụng. (BTW, nó vẫn nói "một vài trường hợp" trong văn bản của OP.) Có thể thực hiện nhiều trường hợp trong đó, nhưng đó là một cuộc chiến cho một ngày khác.

2. Kịch bản này cuộn xuống danh sách các cửa sổ trong Windowmenu. Về bản chất, nó nhấp vào mục ngay bên dưới mục có dấu ("✓"). Nếu mục có "✓" là mục cuối cùng, tập lệnh sẽ thay vào đó nhấp vào mục đầu tiên bên dưới dòng phân cách cuối cùng. Một tập lệnh đi ngược theo hướng ngược lại có thể thu được là sửa đổi tập lệnh này. Tuy nhiên, tôi không thấy làm thế nào hai có thể được kết hợp thành một tập lệnh.

3. Câu trylệnh tạo ra một errorMessagecách hiệu quả nhất về CPU mà tôi biết để tạo ra chỉ mục của separator. Nếu bạn biết một cách tốt hơn, xin vui lòng khai sáng cho tôi.

Kịch bản:

tell application "System Events" to tell (first application process whose frontmost is true) to tell menu bar 1 to tell menu "Window"

    set cellingSeperator to last menu item whose value of attribute "AXEnabled" is false
    set checkedItem to first menu item whose value of attribute "AXMenuItemMarkChar" is "✓"

    try
        set intentionalError to cellingSeperator as Unicode text
    on error errorMessage
        set firstItemIndex to (characters ((offset of "«class menI» " in errorMessage) + 13) through ((offset of " of" in errorMessage) - 1) of errorMessage as string as integer) + 1
    end try

    repeat with iterator from firstItemIndex to number of menu items
        if value of attribute "AXFrame" of menu item iterator is equal to value of attribute "AXFrame" of checkedItem then
            set clickItemIndex to iterator + 1
            exit repeat
        end if
    end repeat

    if clickItemIndex is greater than number of menu items then set clickItemIndex to firstItemIndex

    tell menu item clickItemIndex to perform action "AXPress"

end tell