Có ai biết cách tạo danh sách Liên hệ với số lượng liên hệ xác định không? Chúng có thể là các mục giả, nhưng tôi chỉ cần tạo một sổ địa chỉ với> 2000 mục. Một kịch bản Automator là những gì tôi có trong tâm trí, nhưng tôi không chắc chắn làm thế nào để đi về điều này.
Tôi xin lỗi nếu điều này ở sai vị trí. Đã xem xét SU hoặc SE, nhưng hình dung tôi bắt đầu ở đây.
Câu trả lời:
Một Applescript có thể tạo hàng loạt các mục trong sổ địa chỉ OS X, sau đó bạn có thể nhập vào iPhone của mình. Tôi đã tạo ra một cơ bản cho bạn:
-- Change these to your desired data
set firstName to "Test"
set lastName to "User"
set numberOfEntries to "5" as integer
set counter to "1" as integer
tell application "Address Book"
repeat numberOfEntries times
set thePerson to make new person with properties {first name:firstName, last name:lastName & " " & counter}
make new email at end of emails of thePerson with properties {label:"Work", value:"test" & counter & "@example.com"}
make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
set counter to counter + 1
end repeat
save
end tell
Mở AppleScript Editor (trong Applications/Utilities/thư mục của bạn ) và dán nó vào một tập lệnh mới. Như vậy, nó sẽ làm cho bạn 5 số liên lạc được đánh số như vậy:
Bạn có thể thay đổi số trong set numberOfEntries to "5" as integerdòng thành nhiều số bạn cần và thay đổi dữ liệu nếu bạn muốn. Nếu bạn cần các lĩnh vực khác (như số điện thoại), hãy hỏi và tôi có thể chỉ cho bạn cách.
Tôi đã hơi quá nhiệt tình và tạo ra một phiên bản có tên đẹp hơn. Tôi đã lấy 20 tên nam và nữ phổ biến nhất, 40 tên cuối cùng phổ biến nhất và thêm chữ cái đầu vào giữa, vì vậy bạn có cơ hội trùng lặp khá thấp (một chút dưới 5% trong bộ 2000, theo toán học của tôi) mà không cần ngớ ngẩn tìm kiếm số liên lạc.
Nó cũng thêm tất cả các liên hệ vào một nhóm ("Nhóm thử nghiệm") để bạn có thể dễ dàng chọn ra tất cả các hình nộm nếu bạn thêm vào sổ địa chỉ hiện có và muốn làm sạch nó sau.
Chỉnh sửa: Tôi cũng đã thay đổi nó để nhắc có bao nhiêu mục cần tạo, do đó không cần chỉnh sửa mã.
-- name lists: 20 most popular (US) male and female first names, 40 most popular last names
set firstNameList to {"Mary", "Patricia", "Linda", "Barbara", "Elizabeth", "Jennifer", "Maria", "Susan", "Margaret", "Dorothy", "Lisa", "Nancy", "Karen", "Betty", "Helen", "Sandra", "Donna", "Carol", "Ruth", "Sharon", "James", "John", "Robert", "Michael", "William", "David", "Richard", "Charles", "Joseph", "Thomas", "Christopher", "Daniel", "Paul", "Mark", "Donald", "George", "Kenneth", "Steven", "Edward", "Brian"}
set lastNameList to {"Smith", "Johnson", "Williams", "Jones", "Brown", "Davis", "Miller", "Wilson", "Moore", "Taylor", "Anderson", "Thomas", "Jackson", "White", "Harris", "Martin", "Thompson", "Garcia", "Martinez", "Robinson", "Clark", "Rodriguez", "Lewis", "Lee", "Walker", "Hall", "Allen", "Young", "Hernandez", "King", "Wright", "Lopez", "Hill", "Scott", "Green", "Adams", "Baker", "Gonzalez", "Nelson", "Carter"}
set initialList to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set counter to "1" as integer
-- prompt for how many contacts to create
set dialogText to "Number of contacts to create?"
repeat
display dialog dialogText default answer ""
set numberOfEntries to text returned of result
try
if numberOfEntries = "" then error
set numberOfEntries to numberOfEntries as number
exit repeat
on error
end try
end repeat
-- populate the address book
tell application "Address Book"
set theGroup to make new group with properties {name:"Test Group"}
repeat numberOfEntries times
set firstName to some item of firstNameList
set lastName to some item of lastNameList
set middleInitial to some item of initialList & "."
set thePerson to make new person with properties {first name:firstName, middle name:middleInitial, last name:lastName}
make new email at end of emails of thePerson with properties {label:"Work", value:firstName & middleInitial & lastName & "@example.com"}
make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
add thePerson to theGroup
set counter to counter + 1
end repeat
save
end tell
Đây là những gì nó tạo ra:
