Khi mở tệp DMG, làm cách nào để mở tệp trước cửa sổ?

Bất cứ khi nào tôi tải xuống một .dmgtệp và sau đó mở tệp (thường là từ thanh tải xuống trong Chrome), nó sẽ mở ra trong nền. Có cách nào để làm cho nó mở ra trước cửa sổ của tôi không?

Chỉnh sửa

Để làm rõ: Tôi muốn cửa sổ DMG bật lên như cửa sổ hoạt động.

Tôi đã tạo một tập lệnh Hành động thư mục trong Applescript, có thể làm những gì bạn muốn. Sao chép và dán nó vào một Applescript mới và lưu nó dưới dạng một Ứng dụng (không có đoạn hội thoại bắt đầu!) Vào "/ Library / Sc scripts / Directory Action Script /". Sau đó, bạn có thể đính kèm nó vào bất kỳ thư mục nào (rất có thể là ~ / Tải xuống / thư mục) bằng cách nhấp chuột phải vào thư mục và chọn "cấu hình hành động thư mục" từ menu thả ra của dịch vụ. Kích hoạt Tác vụ thư mục và để tập lệnh xem thư mục.

Về cơ bản, kịch bản sẽ phản ứng với các mục được thả vào thư mục mà nó gắn vào và nếu mục bị rơi là Loại: "Hình ảnh" thì nó sẽ gắn Hình ảnh dưới dạng Tập thông qua công cụ dòng lệnh "hdiutil".

Bạn có thể định cấu hình hành vi của nó bằng cách đặt các thuộc tính openWindow và makeFrontest trong Script; điều này cũng có thể được thực hiện bằng cách nhấp đúp vào Tập lệnh sau khi bạn đã lưu nó dưới dạng một ứng dụng - sau đó nó sẽ hỏi trong hai cuộc đối thoại về hành vi tiêu chuẩn của nó.

Tôi hi vọng cái này giúp được,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

Applescript thứ hai để xác định loại tập tin được thả vào một thư mục

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Cần chỉnh sửa thành "Hình ảnh đĩa" thay vì "Hình ảnh"

Từ những gì tôi có thể nói, OS X sẽ chỉ tự động hiển thị nội dung của ảnh đĩa nếu nó chỉ đọc. Điều này được biểu thị bằng một cây bút chì với một dấu gạch chéo ở dưới cùng bên trái của cửa sổ Finder khi xem nội dung của hình ảnh.

Nếu bạn muốn thay đổi hình ảnh đĩa để nó thực hiện điều này, bạn có thể tạo hình ảnh đĩa hiện tại chỉ đọc bằng cách sử dụng Disk Utility. Thật không may, điều này sẽ không thay đổi hành vi đối với các hình ảnh được sản xuất không chính xác mà bạn có thể tải xuống từ Internet.

1. Gắn hình ảnh đĩa bạn muốn tự động mở.
2. Mở Disk Utility bằng cách tìm kiếm nó với Spotlight.
3. Chọn biểu tượng "Hình ảnh mới" trên thanh công cụ.
4. Đặt tên cho tệp và chọn "chỉ đọc" trong "Định dạng hình ảnh."
5. Nhấp vào để lưu." Khi bạn gắn hình ảnh mới này, nó sẽ tự động bật mở cửa sổ Finder.

Điều này có lẽ cũng không trả lời đủ câu hỏi, nhưng ...

Nếu bạn nhấn lệnh và nhấp vào mục trong thanh tải xuống, nó sẽ hiển thị mục đó trong công cụ tìm. Tại thời điểm đó, chỉ cần nhấn lệnh-O (hoặc nhấp đúp vào tệp dmg) sẽ gắn kết nó và mở nó trong một cửa sổ mới ở nền trước.