Làm thế nào để bạn chỉ hiển thị album hoàn chỉnh trong iTunes 11?

iTunes 11 dường như xoay quanh màn hình hiển thị cho bạn tất cả các album khác nhau mà bạn sở hữu. Tuy nhiên, phần lớn các album iTunes đang hiển thị cho tôi là những album mà tôi chỉ sở hữu một bài hát và điều đó gây khó khăn cho việc tìm những album thực sự hoàn chỉnh.

Trong iTunes 11, làm cách nào để lọc các album được hiển thị trong ngăn Album?

Không có cách nào để làm điều đó, than ôi. Gợi ý này hiển thị một AppleScript có thể tạo danh sách phát từ tất cả các album hoàn chỉnh, nhưng nếu bạn có nhiều album, nó có thể quá tải.

Tạo danh sách phát thông minh với bộ lọc sau - Nhận xét chứa Album đầy đủ. Đối với mỗi album tôi muốn thêm, tôi nhấp vào Nhận thông tin và thêm Album đầy đủ vào trường nhận xét

Bạn không thể. Viết đề xuất cho Apple tại: http://www.apple.com/feedback/itunesapp.html

Bạn có thể tạo danh sách phát chứa tất cả các album đầy đủ trong thư viện của mình bằng AppleScript. Mã dưới đây chỉ là một sửa đổi nhỏ cho tập lệnh được liên kết trong câu trả lời của Kirk để nó tạo một danh sách phát thay vì một danh sách cho mỗi album. Nó chậm (có thể mất 5 phút để chạy qua thư viện của tôi) và rất nhạy cảm với bất kỳ sự thiếu chính xác siêu dữ liệu nào, nhưng nó hoạt động với tôi.

-- Creates one playlist of all full albums you have in iTunes
-- Set the playlistPrefix and playlistSuffix as desired before running

-- Original script by duozmo on Ask Different
-- http://hints.macworld.com/article.php?story=20130201061128257
-- http://apple.stackexchange.com/a/77626

-- Based on code by Brad Campbell
-- http://www.bradcampbell.com/2009/05/26/make-a-whole-album-playlist-in-itunes/

tell application "iTunes"
    set albumPlaylistName to "Full Albums"
    -- Create playlist
    if user playlist albumPlaylistName exists then
        try
            delete tracks of user playlist albumPlaylistName
        end try
    else
        make new user playlist with properties {name:albumPlaylistName}
    end if

    set albumBuckets to {} as list
    set allSongs to (every track of library playlist 1 whose enabled is true and podcast is false and kind contains "audio") as list

    -- Find all partial albums in iTunes
    repeat with currentTrack in allSongs
        set albumName to album of currentTrack as text
        set artistName to artist of currentTrack as text

        -- First check for missing values, then perform integer comparison
        -- Zero is on the left to force interger type coercion, just in case
        if album of currentTrack is not missing value and 0 is less than length of albumName then
            if artist of currentTrack is not missing value and 0 is less than length of artistName then
                if track number of currentTrack is not missing value and 0 is less than track number of currentTrack then
                    if track count of currentTrack is not missing value and 0 is less than track count of currentTrack then
                        if albumBuckets does not contain album of currentTrack then
                            copy album of currentTrack to the end of albumBuckets
                        end if
                    end if
                end if
            end if
        end if

    end repeat

    repeat with currentAlbum in albumBuckets
        set albumSongs to (every track of library playlist 1 whose album is currentAlbum)
        set firstTrack to first item of albumSongs

        -- Filter album list to act only on full albums
        if (count of albumSongs) is equal to track count of first item of albumSongs and 1 is less than (count of albumSongs) then
            -- This is a full album, construct the playlist

            -- Sort tracks by track number
            set albumSongsSorted to {} as list
            repeat with i from 1 to (count of albumSongs)
                repeat with trk in albumSongs
                    if track number of trk is i then
                        set nextSong to trk
                        copy nextSong to the end of albumSongsSorted
                    end if
                end repeat
            end repeat

            try
                repeat with trk in albumSongsSorted
                    duplicate trk to user playlist albumPlaylistName
                end repeat
            end try
        end if
    end repeat

    display dialog albumPlaylistName & " playlist created!"
end tell

Một lựa chọn khác là sử dụng Album đầy đủ ngẫu nhiên của Doug kịch bản nếu bạn chỉ muốn iTunes hoạt động như một bộ đổi CD ở chế độ phát album.