Một chức năng có thể được gọi tự động khi một đầu vào thay đổi?

Hiện tại, bản phác thảo của tôi đang kiểm tra một pin đầu vào mỗi lần vòng quanh vòng lặp chính. Nếu nó phát hiện ra một sự thay đổi, nó sẽ gọi một chức năng tùy chỉnh để đáp ứng nó. Đây là mã (được cắt bớt các yếu tố cần thiết):

int pinValue = LOW;

void pinChanged()
{
    //...
}

void setup()
{
    pinMode(2, INPUT);
}

void loop()
{
    // Read current input
    int newValue = digitalRead(2);

    // Has the input changed?
    if (newValue != pinValue) {
        pinValue = newValue;
        pinChanged();
    }
}

Thật không may, điều này không phải lúc nào cũng hoạt động chính xác cho những thay đổi rất ngắn trên đầu vào (ví dụ: xung ngắn), đặc biệt là nếu loop()chạy chậm một chút.

Có cách nào để làm cho Arduino phát hiện thay đổi đầu vào và tự động gọi chức năng của tôi không?

Bạn có thể làm điều này bằng cách sử dụng các ngắt bên ngoài. Hầu hết Arduinos chỉ hỗ trợ điều này trên một số chân hạn chế. Để biết chi tiết đầy đủ, xem tài liệu trên attachInterrupt().

Giả sử bạn đang sử dụng Uno, bạn có thể làm như thế này:

void pinChanged()
{
    //...
}

void setup()
{
    pinMode(2, INPUT);
    attachInterrupt(0, pinChanged, CHANGE);
}

void loop()
{
}

Điều này sẽ gọi pinChanged()bất cứ khi nào thay đổi được phát hiện trên ngắt ngoài 0. Trên Uno, tương ứng với chân GPIO 2. Việc đánh số ngắt ngoài là khác nhau trên các bảng khác, vì vậy điều quan trọng là phải kiểm tra tài liệu liên quan.

Có những hạn chế đối với phương pháp này mặc dù. pinChanged()Chức năng tùy chỉnh đang được sử dụng như một thói quen dịch vụ ngắt (ISR). Điều đó có nghĩa là phần còn lại của mã (mọi thứ trong loop()) tạm thời bị dừng trong khi cuộc gọi đang thực hiện. Để tránh làm gián đoạn bất kỳ thời điểm quan trọng nào, bạn nên đặt mục tiêu tạo ra ISR càng nhanh càng tốt.

Cũng cần lưu ý rằng không có ngắt nào khác sẽ chạy trong ISR của bạn. Điều đó có nghĩa là bất cứ điều gì dựa vào các ngắt (như lõi delay()và millis()chức năng) có thể không hoạt động đúng bên trong nó.

Cuối cùng, nếu ISR của bạn cần thay đổi bất kỳ biến toàn cục nào trong bản phác thảo, chúng thường được khai báo là volatile, ví dụ:

volatile int someNumber;

Điều đó quan trọng bởi vì nó báo cho trình biên dịch rằng giá trị có thể thay đổi bất ngờ, do đó, nên cẩn thận không sử dụng bất kỳ bản sao / bộ nhớ lỗi thời nào của nó.

Bất kỳ trạng thái thay đổi nào trên bất kỳ mã pin nào được định cấu hình là đầu vào kỹ thuật số đều có thể tạo ra một ngắt. Không giống như các vectơ duy nhất cho các ngắt gây ra bởi INT1 hoặc INT2, tính năng PinChangeInt sử dụng một vectơ phổ biến và sau đó Interrupt Service Routine (còn gọi là ISR) cho vectơ này cần xác định xem pin nào đã thay đổi.

May mắn thay Thư viện PinChangeInt làm cho điều này dễ dàng.

PCintPort::attachInterrupt(PIN, burpcount,RISING); // attach a PinChange Interrupt to our pin on the rising edge
// (RISING, FALLING and CHANGE all work with this library)
// and execute the function burpcount when that pin changes

Trong trường hợp bạn muốn phát hiện điện áp vượt qua ngưỡng , thay vì chỉ đơn thuần là CAO hoặc THẤP, bạn có thể sử dụng bộ so sánh tương tự. Ví dụ phác thảo:

volatile boolean triggered;

ISR (ANALOG_COMP_vect)
  {
  triggered = true;
  }

void setup ()
  {
  Serial.begin (115200);
  Serial.println ("Started.");
  ADCSRB = 0;           // (Disable) ACME: Analog Comparator Multiplexer Enable
  ACSR =  bit (ACI)     // (Clear) Analog Comparator Interrupt Flag
        | bit (ACIE)    // Analog Comparator Interrupt Enable
        | bit (ACIS1);  // ACIS1, ACIS0: Analog Comparator Interrupt Mode Select (trigger on falling edge)
   }  // end of setup

void loop ()
  {
  if (triggered)
    {
    Serial.println ("Triggered!"); 
    triggered = false;
    }

  }  // end of loop

Điều này có thể hữu ích cho những thứ như máy dò ánh sáng, trong đó bạn có thể cần phát hiện sự thay đổi từ (giả sử) 1V sang 2V trên đầu vào.

Mạch ví dụ:

Bạn cũng có thể sử dụng Bộ thu hình đầu vào trên bộ xử lý, sẽ nhớ thời gian chính xác của một số đầu vào nhất định, bằng cách lưu số lượng Timer / Counter hiện tại 1. Điều này cho phép bạn lưu trữ thời điểm chính xác (gần như chính xác) mà sự kiện sự quan tâm đã xảy ra, thay vì đưa ra độ trễ (có thể là vài micro giây) trước khi ISR ​​có thể được sử dụng để nắm bắt thời gian hiện tại.

Đối với các ứng dụng quan trọng về thời gian, điều này có thể giúp tăng độ chính xác.

Ứng dụng ví dụ: Biến Arduino của bạn thành máy kiểm tra tụ điện