Làm thế nào để các chức năng bên ngoài void loop hoạt động?

Tôi đã quen với các bản phác thảo Arduino với một void setup()phần chạy một lần và một void loop()phần cứ lặp đi lặp lại. Điều gì xảy ra khi bạn có các chức năng void bên ngoài chính void loop()? Tất cả những thứ này sẽ tiếp tục lặp song song hay chúng chạy lần lượt? Hoặc các hàm void nhất định chỉ chạy khi các tiêu chí nhất định đã được đáp ứng (như vòng lặp while)?

Ví dụ trong đoạn mã dưới đây, khi nào void receiveData(int byteCount)và các void sendData()hàm sẽ chạy?

//I2C_test

//This code demonstrates communication via an I2C bus between a raspberry pi and an arduino.
//When the Raspberry pi (master) sends data to the Arduino (slave), the Arduino uses this
//data to control a motor. After the Arduino has recieved data from the master, it then collects
//data from the external environment via a sensor and sends this data back to the Raspberry pi.

#include <Wire.h>
int number = 0; //Declare variables
int val = 0;

void setup() {
  //Anything between the curly brackets runs once when the arduino is turned on or reset
  pinMode(0, INPUT);
  //Set pin 0 as input and 3 as output
  pinMode(3, OUTPUT);
  Serial.begin(9600);
  //Set the data rate for serial transmission at 9600bps
  Wire.begin(0x04);
  //Initiate the Wire library, join the Arduino as a slave, and specify its 7 bit slave address
  Wire.onReceive(receiveData);
  //Define callbacks for i2c communication
  Wire.onRequest(sendData);
}

void loop() {
  //The code between the curly brackets keeps repeating
  delay(100);
}

void receiveData(int byteCount) {
  while(Wire.available()) {
    number = Wire.read();
    //Set the variable "number" to the data sent by the master
    analogWrite(3, number);
    //Write this number to pin 3 (PWM). This controls the motor speed
  }
  val = analogRead(0);
  //Read the voltage on pin 0 (connected to the sensor). Map input voltages between 0 and 5 volts into integer values between 0 and 1023
}

void sendData() {
  Wire.write(val);
  //Send the data read from the sensor to the master.
}

Các chức năng setup()và loop()không bình thường bởi vì chúng được gọi tự động cho bạn bởi mã Arduino. Không có chức năng khác hành xử theo cách này.

Nói chung, một chức năng sẽ không bao giờ chạy trừ khi bạn tự gọi nó một cách rõ ràng (ví dụ từ bên trong setup()hoặc loop()), hoặc hướng dẫn một phần khác của chương trình gọi nó. (Có nhiều cách khác để thực thi các chức năng, nhưng điều đó thường liên quan đến một số sửa đổi rất tiên tiến mà tốt nhất nên tránh.)

Ví dụ, pinMode()là một chức năng giống như bất kỳ khác. Nó chỉ chạy khi bạn thực sự đặt một cái gì đó giống như pinMode(3, INPUT)trong mã của bạn. Tại thời điểm đó, nó chạy một lần, kết thúc và sau đó chức năng gọi tiếp tục từ nơi nó rời đi (chúng không bao giờ chạy song song).

Mã ví dụ bạn đã đăng khá thú vị. Nhìn vào những dòng này trong setup():

Wire.onReceive(receiveData);
Wire.onRequest(sendData);

Những dòng này đang nói cho Wiređối tượng gọi receiveData()và sendData()phản ứng với các sự kiện I2C. Nó thực hiện điều này bằng cách chuyển các con trỏ hàm được lưu trữ và sử dụng bởi Wire.

Tôi khuyên bạn nên tìm kiếm thông tin về con trỏ hàm C / C ++ trực tuyến nếu bạn muốn tìm hiểu thêm về điều này. Bạn cũng có thể quan tâm để khám phá attachInterrupt()chức năng của Arduino .

Có phải đó không phải là trường hợp setup()được gọi một lần và loop()được gọi nhiều lần? tức là có một thứ không nhìn thấy main() như thế này:

void main(){
  setup();
  while(True){
    loop();
  }
}

Xin lỗi vì tôi chỉ nhìn vào Arduino và gần như không có kinh nghiệm về C / C ++; Tôi đang cố gắng tự xử lý loop()tình huống này .

Tôi không thể nhận xét về phản ứng của Dee. Mã thực tế được thực thi trong vòng lặp chính ở đây :

    int main(void) {
    init();
    initVariant();

    setup();

    for (;;) {
        loop();
        if (serialEventRun) serialEventRun();
    }   
    return 0;
}

Và vâng, setup()được gọi một lần và loop()được gọi liên tục (cùng với một số nội dung nối tiếp).

Nó hoạt động như chức năng bình thường, nó phải được gọi để có ý nghĩa. loop () / setup () được gọi từ hàm main () được biên dịch từ thư mục Arduino và được liên kết trong. receiveData / sendData được gọi từ chương trình của bạn, hàm nằm trong hàm loop / setup.