Cách cập nhật biến trong ISR bằng Bộ hẹn giờ

Tôi đang cố kiểm tra tần số của Timer3 bằng bộ đếm. Giá trị của bộ đếm, được khai báo là không ổn định, được tăng lên trong ISR và cứ sau mỗi giây, tổng được hiển thị trong vòng lặp chính và đặt lại giá trị về 0.

Bộ hẹn giờ đã được thiết lập chính xác. (Nếu tôi chọn bộ hẹn giờ 3Hz, tôi có thể thấy đèn led nhấp nháy)

Vấn đề

Số lượt truy cập không tăng. Đây là đầu ra:

Setup Completed
tick: 1
tick: 0
tick: 0
tick: 0

MÃ

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);

  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3B = 20; // 800Hz 5; // 3 Hz
  // turn on CTC mode:
  TCCR3B |= (1 << WGM12);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();

  Serial.println("Setup completed");
}

void loop()
{
  if (millis() % 1000 == 0)
  {
    Serial.print(" tick: ");
    Serial.println(cont);
    cont = 0;
  }
}

ISR(TIMER3_COMPB_vect)
{
  //digitalWrite(13, digitalRead(13) ^ 1);
  cont++;
}

EDIT Bộ hẹn giờ này được sử dụng để đọc giá trị anlog từ gia tốc kế và lưu trữ nó trong một mảng nổi. Nhưng tại thời điểm này tôi bị mắc kẹt trong vấn đề cập nhật này.

GIẢI PHÁP 1 Cảm ơn Gerben

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);
  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3A = 20; // 20; //800Hz 5; // 3 Hz
  // turn on CTC mode:
  TCCR3B |= (1 << WGM32);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();
  Serial.println("Setup completed");
}

void loop()
{
  delay(1000);
  Serial.println(cont);
  cont = 0;
}

ISR(TIMER3_COMPB_vect)
{
  cont++;
}

GIẢI PHÁP 2 Nhờ BrettM

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);
  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3B =  20; //800Hz 5; // 3 Hz
  // turn on CTC mode:
  //TCCR3B |= (1 << WGM32);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();
  Serial.println("Setup completed");
}

void loop()
{
  Serial.println(cont); 
  cont = 0;
  delay(1000);

}

ISR(TIMER3_COMPB_vect)
{
  TCNT3 = 0;
  cont++;
}

Trong chế độ CTC, đỉnh là OCR3A, không OCR3B!

Sau đó TIMSK3 |= (1 << OCIE3B);cũng nên được thay đổi để TIMSK3 |= (1 << OCIE3A);, và ISR(TIMER3_COMPB_vect)đểISR(TIMER3_COMPA_vect)

Đối với 3Hz, OCR3Anên là 5208, không phải 20.

Về mặt kỹ thuật TCCR3B |= (1 << WGM12);nênTCCR3B |= (1 << WGM32);

Có vẻ như câu trả lời của tôi cho câu hỏi này trước đây chưa đầy đủ, cảm ơn vì đã chỉ ra rằng chế độ CTC chỉ hoạt động với OCR3A Gerben. Tôi xin lỗi vì đã không kiểm tra câu trả lời trước khi tôi đăng nó.

Chỉ cung cấp thông tin trong câu hỏi này, câu trả lời của Gerben đã hoàn tất, nhưng vì câu hỏi khác của bạn ngụ ý rằng bạn không thể sử dụng OCR3A do thư viện Servo tôi sẽ thêm một chút. (Tôi cũng đã chỉnh sửa câu trả lời đó)

bạn có thể mô phỏng hành vi của chế độ CTC bằng cách đặt TCNT3 thành 0 trong thói quen ngắt của bạn. Nhớ xóa dòng bật chế độ CTC trong mã của bạn.

Tôi đã kiểm tra mã của bạn với ISR ​​này:

ISR(TIMER3_COMPB_vect)
{
  TCNT3 = 0;
  cont++;
}

và cấu hình này của các thanh ghi hẹn giờ

OCR3B = 5208; // 800Hz 5; // 3 Hz
// Set CS10 and CS12 bits for 1024 prescaler:
TCCR3B |= (1 << CS30) | (1 << CS32);
// enable timer compare interrupt:
TIMSK3 |= (1 << OCIE3B);

Điều này có thể kém chính xác hơn một chút ở tần số cao so với CTC, tôi không chắc, nhưng ở tần số 3Hz, nó hoạt động hoàn hảo. Lưu ý rằng 5208 là giá trị OCR chính xác, không phải 20 (một lần nữa nhờ Gerben).