Kiểm tra xem người dùng có tồn tại trong cơ sở dữ liệu SQL Server không

Tôi đang làm việc với SQL Server 2012. Tôi muốn kiểm tra xem người dùng có tồn tại hay không trước khi thêm nó vào cơ sở dữ liệu.

Đây là những gì tôi đã thử nghiệm:

USE [MyDatabase]
GO

IF NOT EXISTS (SELECT name 
                FROM [sys].[server_principals]
                WHERE name = N'IIS APPPOOL\MyWebApi AppPool')
Begin
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
end
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

Nhưng, mã SELECT name FROM [sys].[server_principals]này không trả về nếu người dùng đó tồn tại MyDatabase.

Làm cách nào để kiểm tra xem người dùng có tồn tại MyDatabasekhông?

Sử dụng sys.database_principalsthay vì sys.server_principals.

Vì vậy, truy vấn cuối cùng sẽ trông như thế này (chiếm bộ lọc người dùng):

USE [MyDatabase]
GO

IF NOT EXISTS (SELECT [name]
                FROM [sys].[database_principals]
                WHERE [type] = N'S' AND [name] = N'IIS APPPOOL\MyWebApi AppPool')
Begin
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
end
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

Tôi sử dụng SUSER_ID () và USER_ID () cho những thứ này:

-- Check SQL Server Login
IF SUSER_ID('SomeLogin') IS NULL
    CREATE LOGIN SomeLogin WITH PASSWORD = 'SomePassword';

-- Check database user
IF USER_ID('SomeUser') IS NULL
    CREATE USER SomeUser FOR LOGIN SomeLogin;

Tinh chỉnh thêm vì điều này sẽ làm cho việc đọc tối ưu hơn

USE [MyDatabase]
GO

IF DATABASE_PRINCIPAL_ID('IIS APPPOOL\MyWebApi AppPool') IS NULL
BEGIN
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
END
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

Nếu bạn đang sử dụng máy chủ điện trở, bạn có thể kiểm tra nhiều máy chủ cùng một lúc và trả về giá trị true / false bằng:

SELECT @@servername,    
    CASE 
        WHEN EXISTS(SELECT name FROM sys.database_principals WHERE name = 'LoginName') THEN 1 
        ELSE 0 
    END AS YesNo